contrib/dialog/configure.in

   1 dnl $Id: configure.in,v 1.65 2011/06/27 10:42:27 tom Exp $
   2 dnl Process this file with autoconf to produce a configure script.
   3 dnl ---------------------------------------------------------------------------
   4 dnl Copyright 1999-2010,2011 -- Thomas E. Dickey
   5 dnl
   6 dnl Permission is hereby granted, free of charge, to any person obtaining a
   7 dnl copy of this software and associated documentation files (the
   8 dnl "Software"), to deal in the Software without restriction, including
   9 dnl without limitation the rights to use, copy, modify, merge, publish,
  10 dnl distribute, distribute with modifications, sublicense, and/or sell
  11 dnl copies of the Software, and to permit persons to whom the Software is
  12 dnl furnished to do so, subject to the following conditions:
  13 dnl
  14 dnl The above copyright notice and this permission notice shall be included
  15 dnl in all copies or portions of the Software.
  16 dnl
  17 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  18 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  19 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  20 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,
  21 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR
  22 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR
  23 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  24 dnl
  25 dnl Except as contained in this notice, the name(s) of the above copyright
  26 dnl holders shall not be used in advertising or otherwise to promote the
  27 dnl sale, use or other dealings in this Software without prior written
  28 dnl authorization.
  29 dnl ---------------------------------------------------------------------------
  30 AC_PREREQ(2.13.20020210)
  31 AC_INIT(dialog.h)
  32 AC_CONFIG_HEADER(dlg_config.h:config.hin)
  33
  34 AC_ARG_PROGRAM
  35
  36 DESTDIR=
  37 AC_SUBST(DESTDIR)
  38
  39 dnl
  40 dnl Checks for programs.
  41 dnl
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_GCC_TRADITIONAL
  45 AC_PROG_MAKE_SET
  46 AC_PROG_RANLIB
  47 AC_PROG_INSTALL
  48
  49 dnl needed for CF_WITH_LIBTOOL
  50 AC_CHECK_TOOL(AR, ar, ar)
  51
  52 AC_ISC_POSIX
  53 AC_C_CONST
  54
  55 CF_MAKEFLAGS
  56 CF_MAKE_TAGS
  57 CF_DISABLE_ECHO
  58 CF_PROG_EXT
  59 CF_PATHSEP
  60 CF_LIB_PREFIX
  61 CF_XOPEN_SOURCE
  62 CF_LARGEFILE
  63
  64 CF_WITH_WARNINGS
  65
  66 dnl
  67 dnl Allow dialog program and library to be renamed.
  68 AC_ARG_WITH(package,
  69         [  --with-package=XXX      rename dialog to XXX, library to libXXX.a, etc],
  70         [PACKAGE=$withval],
  71         [PACKAGE=dialog])
  72 CF_VERSION_INFO(dialog,$PACKAGE)
  73
  74 dnl
  75 dnl If package is renamed, it is useful to have the dlg_XXX headers in a
  76 dnl subdirectory (using the package name) so that multiple versions of the
  77 dnl headers can coexist.
  78 AC_ARG_ENABLE(header-subdir,
  79         [  --enable-header-subdir  install dlg_XXX headers to subdirectory],
  80         [SUB_INC=$enableval],
  81         [SUB_INC=no])
  82 AC_SUBST(SUB_INC)
  83
  84 dnl
  85 dnl Checks for libraries.
  86 dnl
  87 EXTRAOBJS=""
  88 CF_BUNDLED_INTL(makefile,enable)
  89 CF_MATH_LIB(,sqrt(x))
  90
  91 CF_WITH_NO_LEAKS
  92
  93 CF_ARG_MSG_ENABLE([if you want --trace option],
  94         trace,
  95         [  --disable-trace         do not support --trace option],
  96         [EXTRAOBJS="$EXTRAOBJS trace\$o"
  97          AC_DEFINE(HAVE_DLG_TRACE)],,yes)
  98
  99 LIBTOOL_MAKE="#"
 100 CF_WITH_LIBTOOL
 101 if test "$with_libtool" = "yes" ; then
 102         OBJEXT="lo"
 103         LIBTOOL_MAKE=
 104         CF_WITH_LIBTOOL_OPTS
 105 fi
 106 AC_SUBST(LIBTOOL_MAKE)
 107
 108 CF_WITH_CURSES_DIR
 109
 110 use_ncurses=no
 111 AC_ARG_WITH(ncurses,
 112         [  --with-ncurses          compile/link with ncurses library],
 113         [use_ncurses=ncurses])
 114 AC_ARG_WITH(ncursesw,
 115         [  --with-ncursesw         compile/link with wide-char ncurses library],
 116         [use_ncurses=ncursesw])
 117 if test $use_ncurses != no ; then
 118         cf_wide_curses=yes
 119         if test $use_ncurses = ncursesw ; then
 120                 CF_UTF8_LIB
 121         fi
 122         CF_NCURSES_CONFIG($use_ncurses)
 123 else
 124         cf_wide_curses=no
 125         CF_CURSES_CONFIG
 126 fi
 127
 128 cf_all_widgets=yes
 129 CF_ARG_MSG_ENABLE([if you want extra dialogs],
 130         extras,
 131         [  --disable-extras        do not include extra dialogs],
 132         [cf_all_widgets=yes],[cf_all_widgets=no],yes)
 133
 134 CF_ARG_MSG_ENABLE([if you want config-file support],
 135         rc-file,
 136         [  --disable-rc-file       do not include config-file support],
 137         [EXTRAOBJS="$EXTRAOBJS rc\$o"
 138          AC_DEFINE(HAVE_RC_FILE)],,$cf_all_widgets)
 139
 140 CF_ARG_MSG_ENABLE([if you want Xdialog-style dialogs],
 141         Xdialog,
 142         [  --disable-Xdialog       do not include Xdialog-style dialogs],
 143         [EXTRAOBJS="$EXTRAOBJS calendar\$o fselect\$o timebox\$o"
 144          AC_DEFINE(HAVE_XDIALOG)],,$cf_all_widgets)
 145
 146 CF_ARG_MSG_ENABLE([if you want the form dialog],
 147         form,
 148         [  --disable-form          do not include the form dialog],
 149         [EXTRAOBJS="$EXTRAOBJS formbox\$o"
 150          AC_DEFINE(HAVE_DLG_FORMBOX)],,$cf_all_widgets)
 151
 152 CF_ARG_MSG_ENABLE([if you want the gauge dialog],
 153         gauge,
 154         [  --disable-gauge         do not include the gauge dialogs],
 155         [EXTRAOBJS="$EXTRAOBJS guage\$o pause\$o prgbox\$o progressbox\$o"
 156          AC_DEFINE(HAVE_DLG_GAUGE)],,$cf_all_widgets)
 157
 158 CF_ARG_MSG_ENABLE([if you want the tailbox dialog],
 159         tailbox,
 160         [  --disable-tailbox       do not include the tailbox dialog],
 161         [EXTRAOBJS="$EXTRAOBJS tailbox\$o"
 162          AC_DEFINE(HAVE_DLG_TAILBOX)],,$cf_all_widgets)
 163
 164 CF_ARG_MSG_ENABLE([if you want the mixedform dialog],
 165         mixedform,
 166         [  --disable-mixedform     do not include the mixedform dialog],
 167         [EXTRAOBJS="$EXTRAOBJS mixedform\$o"
 168          AC_DEFINE(HAVE_DLG_MIXEDFORM)],,$cf_all_widgets)
 169
 170 CF_ARG_MSG_ENABLE([if you want the mixedgauge dialog],
 171         mixedgauge,
 172         [  --disable-mixedgauge    do not include the mixedgauge dialog],
 173         [EXTRAOBJS="$EXTRAOBJS mixedgauge\$o"
 174          AC_DEFINE(HAVE_MIXEDGAUGE)],,$cf_all_widgets)
 175
 176 CF_ARG_MSG_ENABLE([if you want the wide-curses features],
 177         widec,
 178         [  --enable-widec          enable wide-curses features],
 179         [AC_DEFINE(USE_WIDE_CURSES)],,$cf_wide_curses)
 180
 181 AC_SUBST(EXTRAOBJS)
 182
 183 dnl
 184 dnl Checks for header files.
 185 dnl
 186 AC_HEADER_STDC
 187 AC_HEADER_TIME
 188 AC_HEADER_DIRENT
 189 AC_CHECK_HEADERS(search.h unctrl.h unistd.h)
 190 CF_CURSES_TERM_H
 191
 192 dnl
 193 dnl Checks for library functions.
 194 dnl
 195 AC_TYPE_SIGNAL
 196 AC_CHECK_FUNCS(\
 197 _nc_free_and_exit \
 198 btowc \
 199 mblen \
 200 mbrlen \
 201 mbrtowc \
 202 mbtowc \
 203 strcasecmp \
 204 strftime \
 205 tsearch \
 206 waitpid \
 207 wcsrtombs \
 208 wcstombs \
 209 wctob \
 210 wctomb \
 211 )
 212
 213 CF_CURSES_FUNCS(\
 214 flushinp \
 215 getattrs \
 216 getbegx \
 217 getbegy \
 218 getbegyx \
 219 getcurx \
 220 getcury \
 221 getmaxx \
 222 getmaxy \
 223 getmaxyx \
 224 getparx \
 225 getpary \
 226 getparyx \
 227 use_default_colors \
 228 wchgat \
 229 wget_wch \
 230 )
 231
 232 AC_CHECK_FUNC(start_color,[AC_DEFINE(HAVE_COLOR)])
 233 CF_CURSES_CHTYPE
 234 CF_CURSES_WACS_SYMBOLS
 235 CF_FUNC_WAIT
 236 CF_MBSTATE_T
 237
 238 CF_HEADERS_SH(DLG,dlg_config.h)
 239
 240 AC_TRY_LINK([#include <locale.h>],[setlocale(LC_ALL, "")],[AC_DEFINE(HAVE_SETLOCALE)])
 241
 242 CF_DISABLE_RPATH_HACK
 243
 244 AC_OUTPUT(dialog-config makefile $EXTRA_OUTPUT $SUB_MAKEFILE samples/install/makefile,,,sort -u)