contrib/llvm/lib/Target/Sparc/SparcInstr64Bit.td

   1 //===-- SparcInstr64Bit.td - 64-bit instructions for Sparc Target ---------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file contains instruction definitions and patterns needed for 64-bit
  11 // code generation on SPARC v9.
  12 //
  13 // Some SPARC v9 instructions are defined in SparcInstrInfo.td because they can
  14 // also be used in 32-bit code running on a SPARC v9 CPU.
  15 //
  16 //===----------------------------------------------------------------------===//
  17
  18 let Predicates = [Is64Bit] in {
  19 // The same integer registers are used for i32 and i64 values.
  20 // When registers hold i32 values, the high bits are don't care.
  21 // This give us free trunc and anyext.
  22 def : Pat<(i64 (anyext i32:$val)), (COPY_TO_REGCLASS $val, I64Regs)>;
  23 def : Pat<(i32 (trunc i64:$val)), (COPY_TO_REGCLASS $val, IntRegs)>;
  24
  25 } // Predicates = [Is64Bit]
  26
  27
  28 //===----------------------------------------------------------------------===//
  29 // 64-bit Shift Instructions.
  30 //===----------------------------------------------------------------------===//
  31 //
  32 // The 32-bit shift instructions are still available. The left shift srl
  33 // instructions shift all 64 bits, but it only accepts a 5-bit shift amount.
  34 //
  35 // The srl instructions only shift the low 32 bits and clear the high 32 bits.
  36 // Finally, sra shifts the low 32 bits and sign-extends to 64 bits.
  37
  38 let Predicates = [Is64Bit] in {
  39
  40 def : Pat<(i64 (zext i32:$val)), (SRLri $val, 0)>;
  41 def : Pat<(i64 (sext i32:$val)), (SRAri $val, 0)>;
  42
  43 def : Pat<(i64 (and i64:$val, 0xffffffff)), (SRLri $val, 0)>;
  44 def : Pat<(i64 (sext_inreg i64:$val, i32)), (SRAri $val, 0)>;
  45
  46 defm SLLX : F3_S<"sllx", 0b100101, 1, shl, i64, I64Regs>;
  47 defm SRLX : F3_S<"srlx", 0b100110, 1, srl, i64, I64Regs>;
  48 defm SRAX : F3_S<"srax", 0b100111, 1, sra, i64, I64Regs>;
  49
  50 } // Predicates = [Is64Bit]
  51
  52
  53 //===----------------------------------------------------------------------===//
  54 // 64-bit Immediates.
  55 //===----------------------------------------------------------------------===//
  56 //
  57 // All 32-bit immediates can be materialized with sethi+or, but 64-bit
  58 // immediates may require more code. There may be a point where it is
  59 // preferable to use a constant pool load instead, depending on the
  60 // microarchitecture.
  61
  62 // The %g0 register is constant 0.
  63 // This is useful for stx %g0, [...], for example.
  64 def : Pat<(i64 0), (i64 G0)>, Requires<[Is64Bit]>;
  65
  66 // Single-instruction patterns.
  67
  68 // The ALU instructions want their simm13 operands as i32 immediates.
  69 def as_i32imm : SDNodeXForm<imm, [{
  70   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i32);
  71 }]>;
  72 def : Pat<(i64 simm13:$val), (ORri (i64 G0), (as_i32imm $val))>;
  73 def : Pat<(i64 SETHIimm:$val), (SETHIi (HI22 $val))>;
  74
  75 // Double-instruction patterns.
  76
  77 // All unsigned i32 immediates can be handled by sethi+or.
  78 def uimm32 : PatLeaf<(imm), [{ return isUInt<32>(N->getZExtValue()); }]>;
  79 def : Pat<(i64 uimm32:$val), (ORri (SETHIi (HI22 $val)), (LO10 $val))>,
  80       Requires<[Is64Bit]>;
  81
  82 // All negative i33 immediates can be handled by sethi+xor.
  83 def nimm33 : PatLeaf<(imm), [{
  84   int64_t Imm = N->getSExtValue();
  85   return Imm < 0 && isInt<33>(Imm);
  86 }]>;
  87 // Bits 10-31 inverted. Same as assembler's %hix.
  88 def HIX22 : SDNodeXForm<imm, [{
  89   uint64_t Val = (~N->getZExtValue() >> 10) & ((1u << 22) - 1);
  90   return CurDAG->getTargetConstant(Val, MVT::i32);
  91 }]>;
  92 // Bits 0-9 with ones in bits 10-31. Same as assembler's %lox.
  93 def LOX10 : SDNodeXForm<imm, [{
  94   return CurDAG->getTargetConstant(~(~N->getZExtValue() & 0x3ff), MVT::i32);
  95 }]>;
  96 def : Pat<(i64 nimm33:$val), (XORri (SETHIi (HIX22 $val)), (LOX10 $val))>,
  97       Requires<[Is64Bit]>;
  98
  99 // More possible patterns:
 100 //
 101 //   (sllx sethi, n)
 102 //   (sllx simm13, n)
 103 //
 104 // 3 instrs:
 105 //
 106 //   (xor (sllx sethi), simm13)
 107 //   (sllx (xor sethi, simm13))
 108 //
 109 // 4 instrs:
 110 //
 111 //   (or sethi, (sllx sethi))
 112 //   (xnor sethi, (sllx sethi))
 113 //
 114 // 5 instrs:
 115 //
 116 //   (or (sllx sethi), (or sethi, simm13))
 117 //   (xnor (sllx sethi), (or sethi, simm13))
 118 //   (or (sllx sethi), (sllx sethi))
 119 //   (xnor (sllx sethi), (sllx sethi))
 120 //
 121 // Worst case is 6 instrs:
 122 //
 123 //   (or (sllx (or sethi, simmm13)), (or sethi, simm13))
 124
 125 // Bits 42-63, same as assembler's %hh.
 126 def HH22 : SDNodeXForm<imm, [{
 127   uint64_t Val = (N->getZExtValue() >> 42) & ((1u << 22) - 1);
 128   return CurDAG->getTargetConstant(Val, MVT::i32);
 129 }]>;
 130 // Bits 32-41, same as assembler's %hm.
 131 def HM10 : SDNodeXForm<imm, [{
 132   uint64_t Val = (N->getZExtValue() >> 32) & ((1u << 10) - 1);
 133   return CurDAG->getTargetConstant(Val, MVT::i32);
 134 }]>;
 135 def : Pat<(i64 imm:$val),
 136           (ORrr (SLLXri (ORri (SETHIi (HH22 $val)), (HM10 $val)), (i32 32)),
 137                 (ORri (SETHIi (HI22 $val)), (LO10 $val)))>,
 138       Requires<[Is64Bit]>;
 139
 140
 141 //===----------------------------------------------------------------------===//
 142 // 64-bit Integer Arithmetic and Logic.
 143 //===----------------------------------------------------------------------===//
 144
 145 let Predicates = [Is64Bit] in {
 146
 147 // Register-register instructions.
 148
 149 def : Pat<(and i64:$a, i64:$b), (ANDrr $a, $b)>;
 150 def : Pat<(or  i64:$a, i64:$b), (ORrr  $a, $b)>;
 151 def : Pat<(xor i64:$a, i64:$b), (XORrr $a, $b)>;
 152
 153 def : Pat<(and i64:$a, (not i64:$b)), (ANDNrr $a, $b)>;
 154 def : Pat<(or  i64:$a, (not i64:$b)), (ORNrr  $a, $b)>;
 155 def : Pat<(xor i64:$a, (not i64:$b)), (XNORrr $a, $b)>;
 156
 157 def : Pat<(add i64:$a, i64:$b), (ADDrr $a, $b)>;
 158 def : Pat<(sub i64:$a, i64:$b), (SUBrr $a, $b)>;
 159
 160 // Add/sub with carry were renamed to addc/subc in SPARC v9.
 161 def : Pat<(adde i64:$a, i64:$b), (ADDXrr $a, $b)>;
 162 def : Pat<(sube i64:$a, i64:$b), (SUBXrr $a, $b)>;
 163
 164 def : Pat<(addc i64:$a, i64:$b), (ADDCCrr $a, $b)>;
 165 def : Pat<(subc i64:$a, i64:$b), (SUBCCrr $a, $b)>;
 166
 167 def : Pat<(SPcmpicc i64:$a, i64:$b), (SUBCCrr $a, $b)>;
 168
 169 // Register-immediate instructions.
 170
 171 def : Pat<(and i64:$a, (i64 simm13:$b)), (ANDri $a, (as_i32imm $b))>;
 172 def : Pat<(or  i64:$a, (i64 simm13:$b)), (ORri  $a, (as_i32imm $b))>;
 173 def : Pat<(xor i64:$a, (i64 simm13:$b)), (XORri $a, (as_i32imm $b))>;
 174
 175 def : Pat<(add i64:$a, (i64 simm13:$b)), (ADDri $a, (as_i32imm $b))>;
 176 def : Pat<(sub i64:$a, (i64 simm13:$b)), (SUBri $a, (as_i32imm $b))>;
 177
 178 def : Pat<(SPcmpicc i64:$a, (i64 simm13:$b)), (SUBCCri $a, (as_i32imm $b))>;
 179
 180 } // Predicates = [Is64Bit]
 181
 182
 183 //===----------------------------------------------------------------------===//
 184 // 64-bit Integer Multiply and Divide.
 185 //===----------------------------------------------------------------------===//
 186
 187 let Predicates = [Is64Bit] in {
 188
 189 def MULXrr : F3_1<2, 0b001001,
 190                   (outs I64Regs:$rd), (ins I64Regs:$rs1, I64Regs:$rs2),
 191                   "mulx $rs1, $rs2, $rd",
 192                   [(set i64:$rd, (mul i64:$rs1, i64:$rs2))]>;
 193 def MULXri : F3_2<2, 0b001001,
 194                   (outs IntRegs:$rd), (ins IntRegs:$rs1, i64imm:$i),
 195                   "mulx $rs1, $i, $rd",
 196                   [(set i64:$rd, (mul i64:$rs1, (i64 simm13:$i)))]>;
 197
 198 // Division can trap.
 199 let hasSideEffects = 1 in {
 200 def SDIVXrr : F3_1<2, 0b101101,
 201                    (outs I64Regs:$rd), (ins I64Regs:$rs1, I64Regs:$rs2),
 202                    "sdivx $rs1, $rs2, $rd",
 203                    [(set i64:$rd, (sdiv i64:$rs1, i64:$rs2))]>;
 204 def SDIVXri : F3_2<2, 0b101101,
 205                    (outs IntRegs:$rd), (ins IntRegs:$rs1, i64imm:$i),
 206                    "sdivx $rs1, $i, $rd",
 207                    [(set i64:$rd, (sdiv i64:$rs1, (i64 simm13:$i)))]>;
 208
 209 def UDIVXrr : F3_1<2, 0b001101,
 210                    (outs I64Regs:$rd), (ins I64Regs:$rs1, I64Regs:$rs2),
 211                    "udivx $rs1, $rs2, $rd",
 212                    [(set i64:$rd, (udiv i64:$rs1, i64:$rs2))]>;
 213 def UDIVXri : F3_2<2, 0b001101,
 214                    (outs IntRegs:$rd), (ins IntRegs:$rs1, i64imm:$i),
 215                    "udivx $rs1, $i, $rd",
 216                    [(set i64:$rd, (udiv i64:$rs1, (i64 simm13:$i)))]>;
 217 } // hasSideEffects = 1
 218
 219 } // Predicates = [Is64Bit]
 220
 221
 222 //===----------------------------------------------------------------------===//
 223 // 64-bit Loads and Stores.
 224 //===----------------------------------------------------------------------===//
 225 //
 226 // All the 32-bit loads and stores are available. The extending loads are sign
 227 // or zero-extending to 64 bits. The LDrr and LDri instructions load 32 bits
 228 // zero-extended to i64. Their mnemonic is lduw in SPARC v9 (Load Unsigned
 229 // Word).
 230 //
 231 // SPARC v9 adds 64-bit loads as well as a sign-extending ldsw i32 loads.
 232
 233 let Predicates = [Is64Bit] in {
 234
 235 // 64-bit loads.
 236 def LDXrr  : F3_1<3, 0b001011,
 237                   (outs I64Regs:$dst), (ins MEMrr:$addr),
 238                   "ldx [$addr], $dst",
 239                   [(set i64:$dst, (load ADDRrr:$addr))]>;
 240 def LDXri  : F3_2<3, 0b001011,
 241                   (outs I64Regs:$dst), (ins MEMri:$addr),
 242                   "ldx [$addr], $dst",
 243                   [(set i64:$dst, (load ADDRri:$addr))]>;
 244
 245 // Extending loads to i64.
 246 def : Pat<(i64 (zextloadi8 ADDRrr:$addr)), (LDUBrr ADDRrr:$addr)>;
 247 def : Pat<(i64 (zextloadi8 ADDRri:$addr)), (LDUBri ADDRri:$addr)>;
 248 def : Pat<(i64 (extloadi8 ADDRrr:$addr)),  (LDUBrr ADDRrr:$addr)>;
 249 def : Pat<(i64 (extloadi8 ADDRri:$addr)),  (LDUBri ADDRri:$addr)>;
 250 def : Pat<(i64 (sextloadi8 ADDRrr:$addr)), (LDSBrr ADDRrr:$addr)>;
 251 def : Pat<(i64 (sextloadi8 ADDRri:$addr)), (LDSBri ADDRri:$addr)>;
 252
 253 def : Pat<(i64 (zextloadi16 ADDRrr:$addr)), (LDUHrr ADDRrr:$addr)>;
 254 def : Pat<(i64 (zextloadi16 ADDRri:$addr)), (LDUHri ADDRri:$addr)>;
 255 def : Pat<(i64 (extloadi16 ADDRrr:$addr)),  (LDUHrr ADDRrr:$addr)>;
 256 def : Pat<(i64 (extloadi16 ADDRri:$addr)),  (LDUHri ADDRri:$addr)>;
 257 def : Pat<(i64 (sextloadi16 ADDRrr:$addr)), (LDSHrr ADDRrr:$addr)>;
 258 def : Pat<(i64 (sextloadi16 ADDRri:$addr)), (LDSHri ADDRri:$addr)>;
 259
 260 def : Pat<(i64 (zextloadi32 ADDRrr:$addr)), (LDrr ADDRrr:$addr)>;
 261 def : Pat<(i64 (zextloadi32 ADDRri:$addr)), (LDri ADDRri:$addr)>;
 262 def : Pat<(i64 (extloadi32 ADDRrr:$addr)),  (LDrr ADDRrr:$addr)>;
 263 def : Pat<(i64 (extloadi32 ADDRri:$addr)),  (LDri ADDRri:$addr)>;
 264
 265 // Sign-extending load of i32 into i64 is a new SPARC v9 instruction.
 266 def LDSWrr : F3_1<3, 0b001011,
 267                  (outs I64Regs:$dst), (ins MEMrr:$addr),
 268                  "ldsw [$addr], $dst",
 269                  [(set i64:$dst, (sextloadi32 ADDRrr:$addr))]>;
 270 def LDSWri : F3_2<3, 0b001011,
 271                  (outs I64Regs:$dst), (ins MEMri:$addr),
 272                  "ldsw [$addr], $dst",
 273                  [(set i64:$dst, (sextloadi32 ADDRri:$addr))]>;
 274
 275 // 64-bit stores.
 276 def STXrr  : F3_1<3, 0b001110,
 277                  (outs), (ins MEMrr:$addr, I64Regs:$src),
 278                  "stx $src, [$addr]",
 279                  [(store i64:$src, ADDRrr:$addr)]>;
 280 def STXri  : F3_2<3, 0b001110,
 281                  (outs), (ins MEMri:$addr, I64Regs:$src),
 282                  "stx $src, [$addr]",
 283                  [(store i64:$src, ADDRri:$addr)]>;
 284
 285 // Truncating stores from i64 are identical to the i32 stores.
 286 def : Pat<(truncstorei8  i64:$src, ADDRrr:$addr), (STBrr ADDRrr:$addr, $src)>;
 287 def : Pat<(truncstorei8  i64:$src, ADDRri:$addr), (STBri ADDRri:$addr, $src)>;
 288 def : Pat<(truncstorei16 i64:$src, ADDRrr:$addr), (STHrr ADDRrr:$addr, $src)>;
 289 def : Pat<(truncstorei16 i64:$src, ADDRri:$addr), (STHri ADDRri:$addr, $src)>;
 290 def : Pat<(truncstorei32 i64:$src, ADDRrr:$addr), (STrr  ADDRrr:$addr, $src)>;
 291 def : Pat<(truncstorei32 i64:$src, ADDRri:$addr), (STri  ADDRri:$addr, $src)>;
 292
 293 } // Predicates = [Is64Bit]
 294
 295
 296 //===----------------------------------------------------------------------===//
 297 // 64-bit Conditionals.
 298 //===----------------------------------------------------------------------===//
 299 //
 300 // Flag-setting instructions like subcc and addcc set both icc and xcc flags.
 301 // The icc flags correspond to the 32-bit result, and the xcc are for the
 302 // full 64-bit result.
 303 //
 304 // We reuse CMPICC SDNodes for compares, but use new BRXCC branch nodes for
 305 // 64-bit compares. See LowerBR_CC.
 306
 307 let Predicates = [Is64Bit] in {
 308
 309 let Uses = [ICC] in
 310 def BPXCC : BranchSP<0, (ins brtarget:$dst, CCOp:$cc),
 311                      "bp$cc %xcc, $dst",
 312                      [(SPbrxcc bb:$dst, imm:$cc)]>;
 313
 314 // Conditional moves on %xcc.
 315 let Uses = [ICC], Constraints = "$f = $rd" in {
 316 def MOVXCCrr : Pseudo<(outs IntRegs:$rd),
 317                       (ins IntRegs:$rs2, IntRegs:$f, CCOp:$cond),
 318                       "mov$cond %xcc, $rs2, $rd",
 319                       [(set i32:$rd,
 320                        (SPselectxcc i32:$rs2, i32:$f, imm:$cond))]>;
 321 def MOVXCCri : Pseudo<(outs IntRegs:$rd),
 322                       (ins i32imm:$i, IntRegs:$f, CCOp:$cond),
 323                       "mov$cond %xcc, $i, $rd",
 324                       [(set i32:$rd,
 325                        (SPselecticc simm11:$i, i32:$f, imm:$cond))]>;
 326 } // Uses, Constraints
 327
 328 def : Pat<(SPselectxcc i64:$t, i64:$f, imm:$cond),
 329           (MOVXCCrr $t, $f, imm:$cond)>;
 330 def : Pat<(SPselectxcc (i64 simm11:$t), i64:$f, imm:$cond),
 331           (MOVXCCri (as_i32imm $t), $f, imm:$cond)>;
 332
 333 } // Predicates = [Is64Bit]