contrib/openpam/configure.ac

   1 dnl $Id: configure.ac 610 2012-05-26 14:03:45Z des $
   2
   3 AC_PREREQ([2.62])
   4 AC_REVISION([$Id: configure.ac 610 2012-05-26 14:03:45Z des $])
   5 AC_INIT([OpenPAM], [20120526], [des@des.no])
   6 AC_CONFIG_SRCDIR([lib/pam_start.c])
   7 AC_CONFIG_MACRO_DIR([m4])
   8 AM_INIT_AUTOMAKE([foreign])
   9 AM_CONFIG_HEADER([config.h])
  10
  11 # C compiler and features
  12 AC_LANG(C)
  13 AC_PROG_CC
  14 AC_PROG_CC_STDC
  15 AC_PROG_CPP
  16 AC_GNU_SOURCE
  17 AC_C_CONST
  18 AC_C_RESTRICT
  19 AC_C_VOLATILE
  20
  21 # libtool
  22 LT_PREREQ([2.2.6])
  23 LT_INIT([disable-static dlopen])
  24
  25 # other programs
  26 AC_PROG_INSTALL
  27
  28 LIB_MAJ=2
  29 AC_SUBST(LIB_MAJ)
  30 AC_DEFINE_UNQUOTED(LIB_MAJ, $LIB_MAJ, [OpenPAM library major number])
  31
  32 AC_ARG_ENABLE([debug],
  33     AC_HELP_STRING([--enable-debug],
  34         [turn debugging on by default]),
  35     AC_DEFINE(OPENPAM_DEBUG, 1, [Turn debugging on by default]))
  36
  37 AC_ARG_ENABLE([unversioned-modules],
  38     AC_HELP_STRING([--disable-unversioned-modules],
  39         [support loading of unversioned modules]),
  40     [AS_IF([test x"$enableval" = x"no"], [
  41         AC_DEFINE(DISABLE_UNVERSIONED_MODULES,
  42             1,
  43             [Whether loading unversioned modules support is disabled])
  44     ])])
  45
  46 AC_ARG_WITH([modules-dir],
  47     AC_HELP_STRING([--with-modules-dir=DIR],
  48         [OpenPAM modules directory]),
  49     [AS_IF([test x"$withval" != x"no"], [
  50         OPENPAM_MODULES_DIR="$withval"
  51     ], [
  52         OPENPAM_MODULES_DIR="$libdir"
  53     ])],
  54     [OPENPAM_MODULES_DIR="$libdir"])
  55 AC_DEFINE_UNQUOTED(OPENPAM_MODULES_DIR,
  56     "${OPENPAM_MODULES_DIR%/}/",
  57     [OpenPAM modules directory])
  58 AC_SUBST(OPENPAM_MODULES_DIR)
  59
  60 AC_ARG_WITH([doc],
  61     AC_HELP_STRING([--without-doc], [do not build documentation]),
  62     [],
  63     [with_doc=yes])
  64 AM_CONDITIONAL([WITH_DOC], [test x"$with_doc" = x"yes"])
  65
  66 AC_ARG_WITH([pam-unix],
  67     AC_HELP_STRING([--with-pam-unix], [compile sample pam_unix(8) implementation]),
  68     [],
  69     [with_pam_unix=no])
  70 AM_CONDITIONAL([WITH_PAM_UNIX], [test x"$with_pam_unix" = x"yes"])
  71
  72 AC_ARG_WITH(pamtest,
  73     AC_HELP_STRING([--with-pamtest], [compile test application]),
  74     [],
  75     [with_pamtest=no])
  76 AM_CONDITIONAL([WITH_PAMTEST], [test x"$with_pamtest" = x"yes"])
  77
  78 AC_ARG_WITH(su,
  79     AC_HELP_STRING([--with-su], [compile sample su(1) implementation]),
  80     [],
  81     [with_su=no])
  82 AM_CONDITIONAL([WITH_SU], [test x"$with_su" = x"yes"])
  83
  84 AC_CHECK_HEADERS([crypt.h])
  85
  86 AC_CHECK_FUNCS([fdlopen fpurge strlcat strlcmp strlcpy])
  87
  88 saved_LIBS="${LIBS}"
  89 LIBS=""
  90 AC_CHECK_LIB([dl], [dlopen])
  91 DL_LIBS="${LIBS}"
  92 LIBS="${saved_LIBS}"
  93 AC_SUBST(DL_LIBS)
  94
  95 saved_LIBS="${LIBS}"
  96 LIBS=""
  97 AC_CHECK_LIB([crypt], [crypt])
  98 CRYPT_LIBS="${LIBS}"
  99 LIBS="${saved_LIBS}"
 100 AC_SUBST(CRYPT_LIBS)
 101
 102 AC_ARG_ENABLE([developer-warnings],
 103     AS_HELP_STRING([--enable-developer-warnings], [enable strict warnings (default is NO)]),
 104     [CFLAGS="${CFLAGS} -Wall -Wextra"])
 105 AC_ARG_ENABLE([debugging-symbols],
 106     AS_HELP_STRING([--enable-debugging-symbols], [enable debugging symbols (default is NO)]),
 107     [CFLAGS="${CFLAGS} -O0 -g -fno-inline"])
 108 AC_ARG_ENABLE([werror],
 109     AS_HELP_STRING([--enable-werror], [use -Werror (default is NO)]),
 110     [CFLAGS="${CFLAGS} -Werror"])
 111
 112 AC_CONFIG_FILES([
 113     Makefile
 114     bin/Makefile
 115     bin/openpam_dump_policy/Makefile
 116     bin/pamtest/Makefile
 117     bin/su/Makefile
 118     doc/Makefile
 119     doc/man/Makefile
 120     include/Makefile
 121     include/security/Makefile
 122     lib/Makefile
 123     modules/Makefile
 124     modules/pam_deny/Makefile
 125     modules/pam_permit/Makefile
 126     modules/pam_unix/Makefile
 127     t/Makefile
 128 ])
 129 AC_CONFIG_FILES([pamgdb],[chmod +x pamgdb])
 130 AC_OUTPUT