lib/libc/amd64/string/bcopy.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from locore.s.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. Neither the name of the University nor the names of its contributors
  16  *    may be used to endorse or promote products derived from this software
  17  *    without specific prior written permission.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  20  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  21  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  22  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  23  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  24  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  25  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  26  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  27  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  28  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  29  * SUCH DAMAGE.
  30  */
  31
  32 #include <machine/asm.h>
  33 __FBSDID("$FreeBSD$");
  34
  35 #if 0
  36         RCSID("$NetBSD: bcopy.S,v 1.2 2003/08/07 16:42:36 agc Exp $")
  37 #endif
  38
  39         /*
  40          * (ov)bcopy (src,dst,cnt)
  41          *  ws@tools.de     (Wolfgang Solfrank, TooLs GmbH) +49-228-985800
  42          */
  43
  44 #ifdef MEMCOPY
  45 ENTRY(memcpy)
  46 #else
  47 #ifdef MEMMOVE
  48 ENTRY(memmove)
  49 #else
  50 ENTRY(bcopy)
  51 #endif
  52 #endif
  53 #if defined(MEMCOPY) || defined(MEMMOVE)
  54         movq    %rdi,%rax       /* return dst */
  55 #else
  56         xchgq   %rdi,%rsi
  57 #endif
  58         movq    %rdx,%rcx
  59         movq    %rdi,%r8
  60         subq    %rsi,%r8
  61         cmpq    %rcx,%r8        /* overlapping? */
  62         jb      1f
  63         cld                     /* nope, copy forwards. */
  64         shrq    $3,%rcx         /* copy by words */
  65         rep
  66         movsq
  67         movq    %rdx,%rcx
  68         andq    $7,%rcx         /* any bytes left? */
  69         rep
  70         movsb
  71         ret
  72 1:
  73         addq    %rcx,%rdi       /* copy backwards. */
  74         addq    %rcx,%rsi
  75         std
  76         andq    $7,%rcx         /* any fractional bytes? */
  77         decq    %rdi
  78         decq    %rsi
  79         rep
  80         movsb
  81         movq    %rdx,%rcx       /* copy remainder by words */
  82         shrq    $3,%rcx
  83         subq    $7,%rsi
  84         subq    $7,%rdi
  85         rep
  86         movsq
  87         cld
  88         ret
  89 #ifdef MEMCOPY
  90 END(memcpy)
  91 #else
  92 #ifdef MEMMOVE
  93 END(memmove)
  94 #else
  95 END(bcopy)
  96 #endif
  97 #endif
  98
  99         .section .note.GNU-stack,"",%progbits