lib/libc/arm/gen/_setjmp.S

   1 /*      $NetBSD: _setjmp.S,v 1.5 2003/04/05 23:08:51 bjh21 Exp $        */
   2
   3 /*
   4  * Copyright (c) 1997 Mark Brinicombe
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. All advertising materials mentioning features or use of this software
  16  *    must display the following acknowledgement:
  17  *      This product includes software developed by Mark Brinicombe
  18  * 4. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/asm.h>
  36 __FBSDID("$FreeBSD$");
  37
  38 /*
  39  * C library -- _setjmp, _longjmp
  40  *
  41  *      _longjmp(a,v)
  42  * will generate a "return(v)" from the last call to
  43  *      _setjmp(a)
  44  * by restoring registers from the stack.
  45  * The previous signal state is NOT restored.
  46  *
  47  * Note: r0 is the return value
  48  *       r1-r3 are scratch registers in functions
  49  */
  50
  51 ENTRY(_setjmp)
  52         ldr     r1, .L_setjmp_magic
  53         str     r1, [r0], #4
  54 #ifdef __SOFTFP__
  55         add     r0, r0, #52
  56 #else
  57         /* Store fp registers */
  58         sfm     f4, 4, [r0], #48
  59         /* Store fpsr */
  60         rfs     r1
  61         str     r1, [r0], #0x0004
  62 #endif  /* __SOFTFP__ */
  63         /* Store integer registers */
  64         stmia   r0, {r4-r14}
  65
  66         mov     r0, #0x00000000
  67         RET
  68
  69 .L_setjmp_magic:
  70         .word   _JB_MAGIC__SETJMP
  71
  72 WEAK_ALIAS(___longjmp, _longjmp)
  73 ENTRY(_longjmp)
  74         ldr     r2, .L_setjmp_magic
  75         ldr     r3, [r0], #4
  76         teq     r2, r3
  77         bne     botch
  78
  79 #ifdef __SOFTFP__
  80         add     r0, r0, #52
  81 #else
  82         /* Restore fp registers */
  83         lfm     f4, 4, [r0], #48
  84         /* Restore fpsr */
  85         ldr     r4, [r0], #0x0004
  86         wfs     r4
  87 #endif  /* __SOFTFP__ */
  88         /* Restore integer registers */
  89         ldmia   r0, {r4-r14}
  90
  91         /* Validate sp and r14 */
  92         teq     sp, #0
  93         teqne   r14, #0
  94         beq     botch
  95
  96         /* Set return value */
  97         mov     r0, r1
  98         teq     r0, #0x00000000
  99         moveq   r0, #0x00000001
 100         RET
 101
 102         /* validation failed, die die die. */
 103 botch:
 104 #if !defined(_STANDALONE)
 105         bl      PIC_SYM(_C_LABEL(longjmperror), PLT)
 106         bl      PIC_SYM(_C_LABEL(abort), PLT)
 107         b       . - 8           /* Cannot get here */
 108 #else
 109         b       .
 110 #endif