lib/libc/arm/gen/setjmp.S

   1 /*      $NetBSD: setjmp.S,v 1.5 2003/04/05 23:08:51 bjh21 Exp $ */
   2
   3 /*
   4  * Copyright (c) 1997 Mark Brinicombe
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. All advertising materials mentioning features or use of this software
  16  *    must display the following acknowledgement:
  17  *      This product includes software developed by Mark Brinicombe
  18  * 4. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/asm.h>
  36 __FBSDID("$FreeBSD$");
  37 /*
  38  * C library -- setjmp, longjmp
  39  *
  40  *      longjmp(a,v)
  41  * will generate a "return(v)" from the last call to
  42  *      setjmp(a)
  43  * by restoring registers from the stack.
  44  * The previous signal state is restored.
  45  */
  46
  47 ENTRY(setjmp)
  48         /* Block all signals and retrieve the old signal mask */
  49         stmfd   sp!, {r0, r14}
  50         add     r2, r0, #(25 * 4) /* oset */
  51         mov     r0, #0x00000001 /* SIG_BLOCK */
  52         mov     r1, #0 /* set */
  53
  54         bl      PIC_SYM(_C_LABEL(sigprocmask), PLT)
  55
  56         ldmfd   sp!, {r0, r14}
  57
  58         ldr     r1, .Lsetjmp_magic
  59         str     r1, [r0], #4
  60
  61 #ifdef __SOFTFP__
  62         add     r0, r0, #52
  63 #else
  64         /* Store fp registers */
  65         sfm     f4, 4, [r0], #48
  66         /* Store fpsr */
  67         rfs     r1
  68         str     r1, [r0], #0x0004
  69 #endif  /* __SOFTFP__ */
  70         /* Store integer registers */
  71         stmia   r0, {r4-r14}
  72         mov     r0, #0x00000000
  73         RET
  74
  75 .Lsetjmp_magic:
  76         .word   _JB_MAGIC_SETJMP
  77
  78
  79 .weak _C_LABEL(longjmp)
  80 .set _C_LABEL(longjmp), _C_LABEL(__longjmp)
  81 ENTRY(__longjmp)
  82         ldr     r2, .Lsetjmp_magic
  83         ldr     r3, [r0]
  84         teq     r2, r3
  85         bne     botch
  86
  87
  88         /* Set signal mask */
  89         stmfd   sp!, {r0, r1, r14}
  90         sub     sp, sp, #4      /* align the stack */
  91
  92         add     r1, r0, #(25 * 4) /* Signal mask */
  93         mov     r0, #3 /* SIG_SETMASK */
  94         mov     r2, #0
  95         bl      PIC_SYM(_C_LABEL(sigprocmask), PLT)
  96
  97         add     sp, sp, #4      /* unalign the stack */
  98         ldmfd   sp!, {r0, r1, r14}
  99
 100         add     r0, r0, #4
 101 #ifdef __SOFTFP__
 102         add     r0, r0, #52
 103 #else
 104         /* Restore fp registers */
 105         lfm     f4, 4, [r0], #48
 106         /* Restore FPSR */
 107         ldr     r4, [r0], #0x0004
 108         wfs     r4
 109 #endif  /* __SOFTFP__ */
 110         /* Restore integer registers */
 111         ldmia   r0, {r4-r14}
 112
 113         /* Validate sp and r14 */
 114         teq     sp, #0
 115         teqne   r14, #0
 116         beq     botch
 117
 118         /* Set return value */
 119
 120         mov     r0, r1
 121         teq     r0, #0x00000000
 122         moveq   r0, #0x00000001
 123         RET
 124
 125         /* validation failed, die die die. */
 126 botch:
 127         bl      PIC_SYM(_C_LABEL(longjmperror), PLT)
 128         bl      PIC_SYM(_C_LABEL(abort), PLT)
 129         b       . - 8           /* Cannot get here */