lib/libc/i386/gen/modf.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * Sean Eric Fagan.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 4. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  */
  32
  33 #if defined(LIBC_SCCS) && !defined(lint)
  34         .asciz "@(#)modf.s      5.5 (Berkeley) 3/18/91"
  35 #endif /* LIBC_SCCS and not lint */
  36 #include <machine/asm.h>
  37 __FBSDID("$FreeBSD$");
  38
  39 /*
  40  * modf(value, iptr): return fractional part of value, and stores the
  41  * integral part into iptr (a pointer to double).
  42  *
  43  * Written by Sean Eric Fagan (sef@kithrup.COM)
  44  * Sun Mar 11 20:27:30 PST 1990
  45  */
  46
  47 /* With CHOP mode on, frndint behaves as TRUNC does.  Useful. */
  48
  49 ENTRY(modf)
  50         pushl %ebp
  51         movl %esp,%ebp
  52         /* Check for Inf/NaN */
  53         movl 12(%ebp),%eax
  54         andl $0x7fffffff,%eax
  55         cmpl $0x7ff00000,%eax
  56         jae 1f
  57         /* Finite value */
  58         subl $16,%esp
  59         fnstcw -12(%ebp)
  60         movw -12(%ebp),%dx
  61         orw $3072,%dx
  62         movw %dx,-16(%ebp)
  63         fldcw -16(%ebp)
  64         fldl 8(%ebp)
  65         frndint
  66         fstpl -8(%ebp)
  67         fldcw -12(%ebp)
  68         movl 16(%ebp),%eax
  69         movl -8(%ebp),%edx
  70         movl -4(%ebp),%ecx
  71         movl %edx,(%eax)
  72         movl %ecx,4(%eax)
  73         fldl 8(%ebp)
  74         fsubl -8(%ebp)
  75         leave
  76         ret
  77         /* Inf/NaN handling */
  78 1:      fldl 8(%ebp)
  79         movl 16(%ebp),%edx
  80         fstl (%edx)
  81         fldz
  82         fdivp   /* return +/- 0 for +/- Inf, NaN for NaN */
  83         leave
  84         ret
  85 END(modf)
  86
  87         .section .note.GNU-stack,"",%progbits