lib/libc/ia64/gen/__moddi3.S

   1 .file "__moddi3.s"
   2
   3 //
   4 // Copyright (c) 2000, Intel Corporation
   5 // All rights reserved.
   6 //
   7 // Contributed 2/15/2000 by Marius Cornea, John Harrison, Cristina Iordache,
   8 // Ted Kubaska, Bob Norin, and Shane Story of the Computational Software Lab,
   9 // Intel Corporation.
  10 //
  11 // WARRANTY DISCLAIMER
  12 //
  13 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  14 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  15 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  16 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  17 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  18 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  19 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  20 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  21 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  22 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  23 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  24 //
  25 // Intel Corporation is the author of this code, and requests that all
  26 // problem reports or change requests be submitted to it directly at
  27 // http://developer.intel.com/opensource.
  28 //
  29
  30 #include <machine/asm.h>
  31 __FBSDID("$FreeBSD$");
  32
  33 .section .text
  34
  35 // 64-bit signed integer remainder
  36
  37 .proc __moddi3#
  38 .align 32
  39 .global __moddi3#
  40 .align 32
  41
  42 __moddi3:
  43
  44 { .mii
  45   alloc r31=ar.pfs,3,0,0,0
  46   nop.i 0
  47   nop.i 0
  48 } { .mmb
  49
  50   // 64-BIT SIGNED INTEGER REMAINDER BEGINS HERE
  51
  52   // general register used:
  53   //    r32 - 64-bit signed integer dividend
  54   //    r33 - 64-bit signed integer divisor
  55   //    r8 - 64-bit signed integer result
  56   //    r2 - scratch register
  57   // floating-point registers used: f6, f7, f8, f9, f10, f11, f12
  58   // predicate registers used: p6
  59
  60   setf.sig f12=r32  // holds an in integer form
  61   setf.sig f7=r33
  62   nop.b 0
  63 } { .mlx
  64   nop.m 0
  65   //movl r2=0x8000000000000000;;
  66   movl r2=0xffffffffffffffff;;
  67 } { .mfi
  68   // get the 2's complement of b
  69   sub r33=r0,r33
  70   fcvt.xf f6=f12
  71   nop.i 0
  72 } { .mfi
  73   nop.m 0
  74   fcvt.xf f7=f7
  75   nop.i 0;;
  76 } { .mfi
  77   nop.m 0
  78   // Step (1)
  79   // y0 = 1 / b in f8
  80   frcpa.s1 f8,p6=f6,f7
  81   nop.i 0;;
  82 } { .mfi
  83   nop.m 0
  84   // Step (2)
  85   // q0 = a * y0 in f10
  86   (p6) fma.s1 f10=f6,f8,f0
  87   nop.i 0
  88 } { .mfi
  89   nop.m 0
  90   // Step (3)
  91   // e0 = 1 - b * y0 in f9
  92   (p6) fnma.s1 f9=f7,f8,f1
  93   nop.i 0;;
  94 } { .mfi
  95   nop.m 0
  96   // Step (4)
  97   // q1 = q0 + e0 * q0 in f10
  98   (p6) fma.s1 f10=f9,f10,f10
  99   nop.i 0
 100 } { .mfi
 101   nop.m 0
 102   // Step (5)
 103   // e1 = e0 * e0 in f11
 104   (p6) fma.s1 f11=f9,f9,f0
 105   nop.i 0;;
 106 } { .mfi
 107   nop.m 0
 108   // Step (6)
 109   // y1 = y0 + e0 * y0 in f8
 110   (p6) fma.s1 f8=f9,f8,f8
 111   nop.i 0;;
 112 } { .mfi
 113   nop.m 0
 114   // Step (7)
 115   // q2 = q1 + e1 * q1 in f9
 116   (p6) fma.s1 f9=f11,f10,f10
 117   nop.i 0;;
 118 } { .mfi
 119   nop.m 0
 120   // Step (8)
 121   // y2 = y1 + e1 * y1 in f8
 122   (p6) fma.s1 f8=f11,f8,f8
 123   nop.i 0;;
 124 } { .mfi
 125   nop.m 0
 126   // Step (9)
 127   // r2 = a - b * q2 in f10
 128   (p6) fnma.s1 f10=f7,f9,f6
 129   nop.i 0;;
 130 } { .mfi
 131   setf.sig f7=r33
 132   // Step (10)
 133   // q3 = q2 + r2 * y2 in f8
 134   (p6) fma.s1 f8=f10,f8,f9
 135   nop.i 0;;
 136 } { .mfi
 137   nop.m 0
 138   // (11) q = trunc(q3)
 139   fcvt.fx.trunc.s1 f8=f8
 140   nop.i 0;;
 141 } { .mfi
 142   nop.m 0
 143   // (12) r = a + (-b) * q
 144   xma.l f8=f8,f7,f12
 145   nop.i 0;;
 146 }  { .mib
 147   getf.sig r8=f8
 148   nop.i 0
 149   nop.b 0
 150 }
 151
 152   // 64-BIT SIGNED INTEGER REMAINDER ENDS HERE
 153
 154 { .mib
 155   nop.m 0
 156   nop.i 0
 157   br.ret.sptk b0;;
 158 }
 159
 160 .endp __moddi3