lib/libc/ia64/gen/__udivdi3.S

   1 .file "__udivdi3.s"
   2
   3 //
   4 // Copyright (c) 2000, Intel Corporation
   5 // All rights reserved.
   6 //
   7 // Contributed 2/15/2000 by Marius Cornea, John Harrison, Cristina Iordache,
   8 // Ted Kubaska, Bob Norin, and Shane Story of the Computational Software Lab,
   9 // Intel Corporation.
  10 //
  11 // WARRANTY DISCLAIMER
  12 //
  13 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  14 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  15 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  16 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  17 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  18 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  19 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  20 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  21 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  22 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  23 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  24 //
  25 // Intel Corporation is the author of this code, and requests that all
  26 // problem reports or change requests be submitted to it directly at
  27 // http://developer.intel.com/opensource.
  28 //
  29
  30 #include <machine/asm.h>
  31 __FBSDID("$FreeBSD$");
  32
  33 .section .text
  34 .proc __udivdi3#
  35 .align 32
  36 .global __udivdi3#
  37 .align 32
  38
  39 // 64-bit unsigned integer divide
  40
  41 __udivdi3:
  42
  43 { .mii
  44   alloc r31=ar.pfs,2,0,0,0
  45   nop.i 0
  46   nop.i 0;;
  47 }
  48
  49 { .mmi
  50
  51   // 64-BIT UNSIGNED INTEGER DIVIDE BEGINS HERE
  52
  53   setf.sig f8=r32
  54   setf.sig f9=r33
  55   nop.i 0;;
  56 } { .mfb
  57   nop.m 0
  58   fma.s1 f6=f8,f1,f0
  59   nop.b 0
  60 } { .mfb
  61   nop.m 0
  62   fma.s1 f7=f9,f1,f0
  63   nop.b 0;;
  64 } { .mfi
  65   nop.m 0
  66   // Step (1)
  67   // y0 = 1 / b in f8
  68   frcpa.s1 f8,p6=f6,f7
  69   nop.i 0;;
  70 } { .mfi
  71   nop.m 0
  72   // Step (2)
  73   // e0 = 1 - b * y0 in f9
  74   (p6) fnma.s1 f9=f7,f8,f1
  75   nop.i 0
  76 } { .mfi
  77   nop.m 0
  78   // Step (3)
  79   // q0 = a * y0 in f10
  80   (p6) fma.s1 f10=f6,f8,f0
  81   nop.i 0;;
  82 } { .mfi
  83   nop.m 0
  84   // Step (4)
  85   // e1 = e0 * e0 in f11
  86   (p6) fma.s1 f11=f9,f9,f0
  87   nop.i 0
  88 } { .mfi
  89   nop.m 0
  90   // Step (5)
  91   // q1 = q0 + e0 * q0 in f10
  92   (p6) fma.s1 f10=f9,f10,f10
  93   nop.i 0;;
  94 } { .mfi
  95   nop.m 0
  96   // Step (6)
  97   // y1 = y0 + e0 * y0 in f8
  98   (p6) fma.s1 f8=f9,f8,f8
  99   nop.i 0;;
 100 } { .mfi
 101   nop.m 0
 102   // Step (7)
 103   // q2 = q1 + e1 * q1 in f9
 104   (p6) fma.s1 f9=f11,f10,f10
 105   nop.i 0;;
 106 } { .mfi
 107   nop.m 0
 108   // Step (8)
 109   // y2 = y1 + e1 * y1 in f8
 110   (p6) fma.s1 f8=f11,f8,f8
 111   nop.i 0;;
 112 } { .mfi
 113   nop.m 0
 114   // Step (9)
 115   // r2 = a - b * q2 in f10
 116   (p6) fnma.s1 f10=f7,f9,f6
 117   nop.i 0;;
 118 } { .mfi
 119   nop.m 0
 120   // Step (10)
 121   // q3 = q2 + r2 * y2 in f8
 122   (p6) fma.s1 f8=f10,f8,f9
 123   nop.i 0;;
 124 } { .mfb
 125   nop.m 0
 126   // (11) q = trunc(q3)
 127   fcvt.fxu.trunc.s1 f8=f8
 128   nop.b 0;;
 129 } { .mmi
 130   // quotient will be in r8 (if b != 0)
 131   getf.sig r8=f8
 132   nop.m 0
 133   nop.i 0;;
 134 }
 135
 136   // 64-BIT UNSIGNED INTEGER DIVIDE ENDS HERE
 137
 138 { .mmb
 139   nop.m 0
 140   nop.m 0
 141   br.ret.sptk b0;;
 142 }
 143
 144 .endp __udivdi3