lib/libc/ia64/string/bzero.S

   1 /*-
   2  * Copyright (c) 2000 Doug Rabson
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  */
  26
  27 #include <machine/asm.h>
  28 __FBSDID("$FreeBSD$");
  29
  30 ENTRY(bzero, 2)
  31
  32         cmp.le  p6,p0=in1,r0                    // bail if len <= 0
  33 (p6)    br.ret.spnt.few rp
  34         ;;
  35         mov     r14=ar.lc                       // save ar.lc
  36
  37         cmp.ltu p6,p0=17,in1                    // check for small
  38 (p6)    br.dptk.few 3f
  39
  40 1:      add     r15=-1,in1 ;;
  41         mov     ar.lc=r15 ;;
  42 2:      st1     [in0]=r0,1                      // zero one byte
  43         br.cloop.sptk.few 2b                    // loop
  44
  45         ;;
  46         mov     ar.lc=r14                       // done
  47         br.ret.sptk.few rp
  48
  49         // Zero up to 8byte alignment
  50
  51 3:      tbit.nz p6,p0=in0,0 ;;
  52 (p6)    st1     [in0]=r0,1
  53 (p6)    add     in1=-1,in1 ;;
  54
  55         tbit.nz p6,p0=in0,1 ;;
  56 (p6)    st2     [in0]=r0,2
  57 (p6)    add     in1=-2,in1 ;;
  58
  59         tbit.nz p6,p0=in0,2 ;;
  60 (p6)    st4     [in0]=r0,4
  61 (p6)    add     in1=-4,in1
  62
  63         ;;
  64         shr.u   r15=in1,3                       // word count
  65         extr.u  in1=in1,0,3 ;;                  // trailing bytes
  66         cmp.eq  p6,p0=r15,r0                    // check for zero
  67         cmp.ne  p7,p0=in1,r0
  68 (p6)    br.dpnt.few 1b                          // zero last bytes
  69
  70         add     r15=-1,r15 ;;
  71         mov     ar.lc=r15 ;;
  72 4:      st8     [in0]=r0,8
  73         br.cloop.sptk.few 4b
  74
  75 (p7)    br.dpnt.few 1b                          // zero last bytes
  76
  77         ;;
  78         mov     ar.lc=r14                       // done
  79         br.ret.sptk.few rp
  80
  81 END(bzero)