lib/libc/mips/gen/modf.S

   1 /*      $NetBSD: modf.S,v 1.10 2003/08/07 16:42:15 agc Exp $    */
   2
   3 /*-
   4  * Copyright (c) 1991, 1993, 1995
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * Ralph Campbell.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/asm.h>
  36 __FBSDID("$FreeBSD$");
  37
  38 #if defined(LIBC_SCCS) && !defined(lint)
  39         ASMSTR("from: @(#)modf.s        8.1 (Berkeley) 6/4/93")
  40         ASMSTR("$NetBSD: modf.S,v 1.10 2003/08/07 16:42:15 agc Exp $")
  41 #endif /* LIBC_SCCS and not lint */
  42
  43 #ifdef __ABICALLS__
  44         .abicalls
  45 #endif
  46
  47 /*
  48  * double modf(val, iptr)
  49  *      double val, *iptr;
  50  * returns: xxx and n (in *iptr) where val == n.xxx
  51  */
  52 LEAF(modf)
  53 #ifdef __ABICALLS__
  54         .set    noreorder
  55         .cpload t9
  56         .set    reorder
  57 #endif
  58         cfc1    t0, $31                 # get the control register
  59         li.d    $f2, 4503599627370496e0 # f2 <- 2^52
  60
  61         or      t1, t0, 0x3             # set rounding mode to round to zero
  62         xor     t1, t1, 0x2             #  (i.e., 01)
  63         ctc1    t1, $31
  64
  65         mov.d   $f0, $f12               # f0 <- f12
  66         abs.d   $f4, $f12               # f4 <- |f12|
  67         c.olt.d $f4, $f2                # f4 ? < f2
  68         bc1f    1f                      # leave f0 alone if Nan, infinity
  69                                         # or >=2^52
  70         c.eq.d  $f12,$f4                # was f12 positive ?
  71         add.d   $f4,$f2,$f4             # round off to integer
  72         bc1f    2f                      # No -> will have to negate result
  73         sub.d   $f0,$f4,$f2             # Remove fudge factor
  74         j       1f                      # integer fraction got
  75 2:
  76         sub.d   $f0,$f2,$f4             # Remove fudge factor and negate
  77 1:
  78         ctc1    t0, $31                 # restore old rounding mode
  79         s.d     $f0, 0(a2)              # save the integer part
  80         sub.d   $f0, $f12, $f0          # subtract val - integer part
  81         j       ra
  82 END(modf)