lib/libc/sparc64/gen/setjmp.S

   1 /*
   2  * Copyright (c) 1992, 1993
   3  *      The Regents of the University of California.  All rights reserved.
   4  *
   5  * This software was developed by the Computer Systems Engineering group
   6  * at Lawrence Berkeley Laboratory under DARPA contract BG 91-66 and
   7  * contributed to Berkeley.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 4. Neither the name of the University nor the names of its contributors
  18  *    may be used to endorse or promote products derived from this software
  19  *    without specific prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  31  * SUCH DAMAGE.
  32  *
  33  *      from: Header: _setjmp.s,v 1.1 91/07/06 16:45:53 torek Exp
  34  */
  35
  36 #if defined(LIBC_SCCS) && !defined(lint)
  37         .asciz "@(#)_setjmp.s   8.1 (Berkeley) 6/4/93"
  38 #if 0
  39         RCSID("$NetBSD: _setjmp.S,v 1.4 1998/10/08 02:27:59 eeh Exp $")
  40 #endif
  41 #endif /* LIBC_SCCS and not lint */
  42 #include <machine/asm.h>
  43 __FBSDID("$FreeBSD$");
  44
  45 #include "assym.s"
  46
  47         .register %g2,#ignore
  48         .register %g3,#ignore
  49
  50 /*
  51  * C library -- setjmp, longjmp
  52  *
  53  *      longjmp(a,v)
  54  * will generate a "return(v?v:1)" from
  55  * the last call to
  56  *      setjmp(a)
  57  * by restoring the previous context.
  58  */
  59
  60 ENTRY(setjmp)
  61         save    %sp, -CCFSZ, %sp
  62         mov     SIG_BLOCK, %o0
  63         clr     %o1
  64         call    CNAME(sigprocmask)
  65          add    %i0, _JB_SIGMASK, %o2
  66         restore
  67         stx     %sp, [%o0 + _JB_SP]
  68         stx     %o7, [%o0 + _JB_PC]
  69         retl
  70          clr    %o0
  71 END(setjmp)
  72
  73         .weak   CNAME(longjmp)
  74         .set    CNAME(longjmp),CNAME(__longjmp)
  75 ENTRY(__longjmp)
  76         save    %sp, -CCFSZ, %sp
  77         flushw
  78         mov     SIG_SETMASK, %o0
  79         add     %i0, _JB_SIGMASK, %o1
  80         call    CNAME(sigprocmask)
  81          clr    %o2
  82         ldx     [%i0 + _JB_SP], %fp
  83         ldx     [%i0 + _JB_PC], %i7
  84         mov     1, %i0
  85         movrnz  %i1, %i1, %i0
  86         ret
  87          restore
  88 END(__longjmp)