lib/libstand/arm/_setjmp.S

   1 /*      $NetBSD: _setjmp.S,v 1.5 2003/04/05 23:08:51 bjh21 Exp $        */
   2
   3 /*
   4  * Copyright (c) 1997 Mark Brinicombe
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. All advertising materials mentioning features or use of this software
  16  *    must display the following acknowledgement:
  17  *      This product includes software developed by Mark Brinicombe
  18  * 4. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/asm.h>
  36 __FBSDID("$FreeBSD$");
  37
  38 #define SOFTFLOAT /* XXX */
  39 /*
  40  * C library -- _setjmp, _longjmp
  41  *
  42  *      _longjmp(a,v)
  43  * will generate a "return(v)" from the last call to
  44  *      _setjmp(a)
  45  * by restoring registers from the stack.
  46  * The previous signal state is NOT restored.
  47  *
  48  * Note: r0 is the return value
  49  *       r1-r3 are scratch registers in functions
  50  */
  51
  52 ENTRY(_setjmp)
  53         ldr     r1, .L_setjmp_magic
  54         str     r1, [r0], #4
  55 #ifdef SOFTFLOAT
  56         add     r0, r0, #52
  57 #else
  58         /* Store fp registers */
  59         sfm     f4, 4, [r0], #48
  60         /* Store fpsr */
  61         rfs     r1
  62         str     r1, [r0], #0x0004
  63 #endif  /* SOFTFLOAT */
  64         /* Store integer registers */
  65         stmia   r0, {r4-r14}
  66
  67         mov     r0, #0x00000000
  68         mov     r15, r14
  69
  70 .L_setjmp_magic:
  71         .word   _JB_MAGIC__SETJMP
  72
  73 ENTRY(_longjmp)
  74         ldr     r2, .L_setjmp_magic
  75         ldr     r3, [r0], #4
  76         teq     r2, r3
  77         bne     botch
  78
  79 #ifdef SOFTFLOAT
  80         add     r0, r0, #52
  81 #else
  82         /* Restore fp registers */
  83         lfm     f4, 4, [r0], #48
  84         /* Restore fpsr */
  85         ldr     r4, [r0], #0x0004
  86         wfs     r4
  87 #endif  /* SOFTFLOAT */
  88         /* Restore integer registers */
  89         ldmia   r0, {r4-r14}
  90
  91         /* Validate sp and r14 */
  92         teq     sp, #0
  93         teqne   r14, #0
  94         beq     botch
  95
  96         /* Set return value */
  97         mov     r0, r1
  98         teq     r0, #0x00000000
  99         moveq   r0, #0x00000001
 100         mov     r15, r14
 101
 102         /* validation failed, die die die. */
 103 botch:
 104         bl      PIC_SYM(_C_LABEL(longjmperror), PLT)
 105         bl      PIC_SYM(_C_LABEL(abort), PLT)
 106         b       . - 8           /* Cannot get here */