lib/libstand/mips/_setjmp.S

   1 /*-
   2  * Copyright (c) 1991, 1993
   3  *      The Regents of the University of California.  All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * Ralph Campbell.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  * $FreeBSD$
  37  */
  38
  39 #include <machine/regnum.h>
  40 #include <machine/asm.h>
  41
  42 #if 0
  43 #if defined(LIBC_SCCS)
  44         .text
  45         .asciz "$OpenBSD: _setjmp.S,v 1.6 1996/09/23 21:27:53 imp Exp $"
  46 #endif /* LIBC_SCCS */
  47 #endif
  48
  49 /*
  50  * C library -- _setjmp, _longjmp
  51  *
  52  *      _longjmp(a,v)
  53  * will generate a "return(v)" from
  54  * the last call to
  55  *      _setjmp(a)
  56  * by restoring registers from the stack,
  57  * The previous signal state is NOT restored.
  58  */
  59
  60 LEAF(_setjmp)
  61         .set    noreorder
  62         li      v0, 0xACEDBADE                  # sigcontext magic number
  63         sw      ra, (2 * 4)(a0)                 # sc_pc = return address
  64         sw      v0, (3 * 4)(a0)                 #   saved in sc_regs[0]
  65         sw      s0, ((S0 + 3) * 4)(a0)
  66         sw      s1, ((S1 + 3) * 4)(a0)
  67         sw      s2, ((S2 + 3) * 4)(a0)
  68         sw      s3, ((S3 + 3) * 4)(a0)
  69         sw      s4, ((S4 + 3) * 4)(a0)
  70         sw      s5, ((S5 + 3) * 4)(a0)
  71         sw      s6, ((S6 + 3) * 4)(a0)
  72         sw      s7, ((S7 + 3) * 4)(a0)
  73         sw      sp, ((SP + 3) * 4)(a0)
  74         sw      s8, ((S8 + 3) * 4)(a0)
  75         cfc1    v0, $31                         # too bad cant check if FP used
  76         swc1    $f20, ((20 + 38) * 4)(a0)
  77         swc1    $f21, ((21 + 38) * 4)(a0)
  78         swc1    $f22, ((22 + 38) * 4)(a0)
  79         swc1    $f23, ((23 + 38) * 4)(a0)
  80         swc1    $f24, ((24 + 38) * 4)(a0)
  81         swc1    $f25, ((25 + 38) * 4)(a0)
  82         swc1    $f26, ((26 + 38) * 4)(a0)
  83         swc1    $f27, ((27 + 38) * 4)(a0)
  84         swc1    $f28, ((28 + 38) * 4)(a0)
  85         swc1    $f29, ((29 + 38) * 4)(a0)
  86         swc1    $f30, ((30 + 38) * 4)(a0)
  87         swc1    $f31, ((31 + 38) * 4)(a0)
  88         sw      v0, ((32 + 38) * 4)(a0)
  89         j       ra
  90         move    v0, zero
  91 END(_setjmp)
  92
  93 LEAF(_longjmp)
  94 #ifdef ABICALLS
  95         subu    sp, sp, 32
  96         .cprestore 16
  97 #endif
  98         .set    noreorder
  99         lw      v0, (3 * 4)(a0)                 # get magic number
 100         lw      ra, (2 * 4)(a0)
 101         bne     v0, 0xACEDBADE, botch           # jump if error
 102
 103         addu    sp, sp, 32                      # does not matter, sanity
 104         lw      s0, ((S0 + 3) * 4)(a0)
 105         lw      s1, ((S1 + 3) * 4)(a0)
 106         lw      s2, ((S2 + 3) * 4)(a0)
 107         lw      s3, ((S3 + 3) * 4)(a0)
 108         lw      s4, ((S4 + 3) * 4)(a0)
 109         lw      s5, ((S5 + 3) * 4)(a0)
 110         lw      s6, ((S6 + 3) * 4)(a0)
 111         lw      s7, ((S7 + 3) * 4)(a0)
 112         lw      v0, ((32 + 38) * 4)(a0)         # get fpu status
 113         lw      sp, ((SP + 3) * 4)(a0)
 114         lw      s8, ((S8 + 3) * 4)(a0)
 115 /* Octeon does not have an FPU */
 116 #if !defined(_MIPS_ARCH_OCTEON)
 117         ctc1    v0, $31
 118         lwc1    $f20, ((20 + 38) * 4)(a0)
 119         lwc1    $f21, ((21 + 38) * 4)(a0)
 120         lwc1    $f22, ((22 + 38) * 4)(a0)
 121         lwc1    $f23, ((23 + 38) * 4)(a0)
 122         lwc1    $f24, ((24 + 38) * 4)(a0)
 123         lwc1    $f25, ((25 + 38) * 4)(a0)
 124         lwc1    $f26, ((26 + 38) * 4)(a0)
 125         lwc1    $f27, ((27 + 38) * 4)(a0)
 126         lwc1    $f28, ((28 + 38) * 4)(a0)
 127         lwc1    $f29, ((29 + 38) * 4)(a0)
 128         lwc1    $f30, ((30 + 38) * 4)(a0)
 129         lwc1    $f31, ((31 + 38) * 4)(a0)
 130 #endif /*  _MIPS_ARCH_OCTEON */
 131
 132         j       ra
 133         move    v0, a1
 134 botch:
 135         jal     _C_LABEL(longjmperror)
 136         nop
 137         jal     _C_LABEL(abort)
 138         nop
 139 END(_longjmp)