sys/boot/i386/boot2/boot1.S

   1 /*
   2  * Copyright (c) 1998 Robert Nordier
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms are freely
   6  * permitted provided that the above copyright notice and this
   7  * paragraph and the following disclaimer are duplicated in all
   8  * such forms.
   9  *
  10  * This software is provided "AS IS" and without any express or
  11  * implied warranties, including, without limitation, the implied
  12  * warranties of merchantability and fitness for a particular
  13  * purpose.
  14  *
  15  * $FreeBSD$
  16  */
  17
  18 /* Memory Locations */
  19                 .set MEM_REL,0x700              # Relocation address
  20                 .set MEM_ARG,0x900              # Arguments
  21                 .set MEM_ORG,0x7c00             # Origin
  22                 .set MEM_BUF,0x8c00             # Load area
  23                 .set MEM_BTX,0x9000             # BTX start
  24                 .set MEM_JMP,0x9010             # BTX entry point
  25                 .set MEM_USR,0xa000             # Client start
  26                 .set BDA_BOOT,0x472             # Boot howto flag
  27
  28 /* Partition Constants */
  29                 .set PRT_OFF,0x1be              # Partition offset
  30                 .set PRT_NUM,0x4                # Partitions
  31                 .set PRT_BSD,0xa5               # Partition type
  32
  33 /* Flag Bits */
  34                 .set FL_PACKET,0x80             # Packet mode
  35
  36 /* Misc. Constants */
  37                 .set SIZ_PAG,0x1000             # Page size
  38                 .set SIZ_SEC,0x200              # Sector size
  39
  40                 .set NSECT,0x10
  41                 .globl start
  42                 .globl xread
  43                 .code16
  44
  45 start:          jmp main                        # Start recognizably
  46
  47 /*
  48  * This is the start of a standard BIOS Parameter Block (BPB). Most bootable
  49  * FAT disks have this at the start of their MBR. While normal BIOS's will
  50  * work fine without this section, IBM's El Torito emulation "fixes" up the
  51  * BPB by writing into the memory copy of the MBR. Rather than have data
  52  * written into our xread routine, we'll define a BPB to work around it.
  53  * The data marked with (T) indicates a field required for a ThinkPad to
  54  * recognize the disk and (W) indicates fields written from IBM BIOS code.
  55  * The use of the BPB is based on what OpenBSD and NetBSD implemented in
  56  * their boot code but the required fields were determined by trial and error.
  57  *
  58  * Note: If additional space is needed in boot1, one solution would be to
  59  * move the "prompt" message data (below) to replace the OEM ID.
  60  */
  61                 .org 0x03, 0x00
  62 oemid:          .space 0x08, 0x00       # OEM ID
  63
  64                 .org 0x0b, 0x00
  65 bpb:            .word   512             # sector size (T)
  66                 .byte   0               # sectors/clustor
  67                 .word   0               # reserved sectors
  68                 .byte   0               # number of FATs
  69                 .word   0               # root entries
  70                 .word   0               # small sectors
  71                 .byte   0               # media type (W)
  72                 .word   0               # sectors/fat
  73                 .word   18              # sectors per track (T)
  74                 .word   2               # number of heads (T)
  75                 .long   0               # hidden sectors (W)
  76                 .long   0               # large sectors
  77
  78                 .org 0x24, 0x00
  79 ebpb:           .byte   0               # BIOS physical drive number (W)
  80
  81                 .org 0x25,0x90
  82 /*
  83  * Trampoline used by boot2 to call read to read data from the disk via
  84  * the BIOS.  Call with:
  85  *
  86  * %cx:%ax      - long    - LBA to read in
  87  * %es:(%bx)    - caddr_t - buffer to read data into
  88  * %dl          - byte    - drive to read from
  89  * %dh          - byte    - num sectors to read
  90  */
  91
  92 xread:          push %ss                        # Address
  93                 pop %ds                         #  data
  94 /*
  95  * Setup an EDD disk packet and pass it to read
  96  */
  97 xread.1:                                        # Starting
  98                 pushl $0x0                      #  absolute
  99                 push %cx                        #  block
 100                 push %ax                        #  number
 101                 push %es                        # Address of
 102                 push %bx                        #  transfer buffer
 103                 xor %ax,%ax                     # Number of
 104                 movb %dh,%al                    #  blocks to
 105                 push %ax                        #  transfer
 106                 push $0x10                      # Size of packet
 107                 mov %sp,%bp                     # Packet pointer
 108                 callw read                      # Read from disk
 109                 lea 0x10(%bp),%sp               # Clear stack
 110                 lret                            # To far caller
 111 /*
 112  * Load the rest of boot2 and BTX up, copy the parts to the right locations,
 113  * and start it all up.
 114  */
 115
 116 /*
 117  * Setup the segment registers to flat addressing (segment 0) and setup the
 118  * stack to end just below the start of our code.
 119  */
 120 main:           cld                             # String ops inc
 121                 xor %cx,%cx                     # Zero
 122                 mov %cx,%es                     # Address
 123                 mov %cx,%ds                     #  data
 124                 mov %cx,%ss                     # Set up
 125                 mov $start,%sp                  #  stack
 126 /*
 127  * Relocate ourself to MEM_REL.  Since %cx == 0, the inc %ch sets
 128  * %cx == 0x100.
 129  */
 130                 mov %sp,%si                     # Source
 131                 mov $MEM_REL,%di                # Destination
 132                 incb %ch                        # Word count
 133                 rep                             # Copy
 134                 movsw                           #  code
 135 /*
 136  * If we are on a hard drive, then load the MBR and look for the first
 137  * FreeBSD slice.  We use the fake partition entry below that points to
 138  * the MBR when we call nread.  The first pass looks for the first active
 139  * FreeBSD slice.  The second pass looks for the first non-active FreeBSD
 140  * slice if the first one fails.
 141  */
 142                 mov $part4,%si                  # Partition
 143                 cmpb $0x80,%dl                  # Hard drive?
 144                 jb main.4                       # No
 145                 movb $0x1,%dh                   # Block count
 146                 callw nread                     # Read MBR
 147                 mov $0x1,%cx                    # Two passes
 148 main.1:         mov $MEM_BUF+PRT_OFF,%si        # Partition table
 149                 movb $0x1,%dh                   # Partition
 150 main.2:         cmpb $PRT_BSD,0x4(%si)          # Our partition type?
 151                 jne main.3                      # No
 152                 jcxz main.5                     # If second pass
 153                 testb $0x80,(%si)               # Active?
 154                 jnz main.5                      # Yes
 155 main.3:         add $0x10,%si                   # Next entry
 156                 incb %dh                        # Partition
 157                 cmpb $0x1+PRT_NUM,%dh           # In table?
 158                 jb main.2                       # Yes
 159                 dec %cx                         # Do two
 160                 jcxz main.1                     #  passes
 161 /*
 162  * If we get here, we didn't find any FreeBSD slices at all, so print an
 163  * error message and die.
 164  */
 165                 mov $msg_part,%si               # Message
 166                 jmp error                       # Error
 167 /*
 168  * Floppies use partition 0 of drive 0.
 169  */
 170 main.4:         xor %dx,%dx                     # Partition:drive
 171 /*
 172  * Ok, we have a slice and drive in %dx now, so use that to locate and load
 173  * boot2.  %si references the start of the slice we are looking for, so go
 174  * ahead and load up the first 16 sectors (boot1 + boot2) from that.  When
 175  * we read it in, we conveniently use 0x8c00 as our transfer buffer.  Thus,
 176  * boot1 ends up at 0x8c00, and boot2 starts at 0x8c00 + 0x200 = 0x8e00.
 177  * The first part of boot2 is the disklabel, which is 0x200 bytes long.
 178  * The second part is BTX, which is thus loaded into 0x9000, which is where
 179  * it also runs from.  The boot2.bin binary starts right after the end of
 180  * BTX, so we have to figure out where the start of it is and then move the
 181  * binary to 0xc000.  Normally, BTX clients start at MEM_USR, or 0xa000, but
 182  * when we use btxld to create boot2, we use an entry point of 0x2000.  That
 183  * entry point is relative to MEM_USR; thus boot2.bin starts at 0xc000.
 184  */
 185 main.5:         mov %dx,MEM_ARG                 # Save args
 186                 movb $NSECT,%dh                 # Sector count
 187                 callw nread                     # Read disk
 188                 mov $MEM_BTX,%bx                # BTX
 189                 mov 0xa(%bx),%si                # Get BTX length and set
 190                 add %bx,%si                     #  %si to start of boot2.bin
 191                 mov $MEM_USR+SIZ_PAG*2,%di      # Client page 2
 192                 mov $MEM_BTX+(NSECT-1)*SIZ_SEC,%cx # Byte
 193                 sub %si,%cx                     #  count
 194                 rep                             # Relocate
 195                 movsb                           #  client
 196
 197 /*
 198  * Enable A20 so we can access memory above 1 meg.
 199  * Use the zero-valued %cx as a timeout for embedded hardware which do not
 200  * have a keyboard controller.
 201  */
 202 seta20:         cli                             # Disable interrupts
 203 seta20.1:       dec %cx                         # Timeout?
 204                 jz seta20.3                     # Yes
 205                 inb $0x64,%al                   # Get status
 206                 testb $0x2,%al                  # Busy?
 207                 jnz seta20.1                    # Yes
 208                 movb $0xd1,%al                  # Command: Write
 209                 outb %al,$0x64                  #  output port
 210 seta20.2:       inb $0x64,%al                   # Get status
 211                 testb $0x2,%al                  # Busy?
 212                 jnz seta20.2                    # Yes
 213                 movb $0xdf,%al                  # Enable
 214                 outb %al,$0x60                  #  A20
 215 seta20.3:       sti                             # Enable interrupts
 216
 217                 jmp start+MEM_JMP-MEM_ORG       # Start BTX
 218
 219
 220 /*
 221  * Trampoline used to call read from within boot1.
 222  */
 223 nread:          mov $MEM_BUF,%bx                # Transfer buffer
 224                 mov 0x8(%si),%ax                # Get
 225                 mov 0xa(%si),%cx                #  LBA
 226                 push %cs                        # Read from
 227                 callw xread.1                   #  disk
 228                 jnc return                      # If success, return
 229                 mov $msg_read,%si               # Otherwise, set the error
 230                                                 #  message and fall through to
 231                                                 #  the error routine
 232 /*
 233  * Print out the error message pointed to by %ds:(%si) followed
 234  * by a prompt, wait for a keypress, and then reboot the machine.
 235  */
 236 error:          callw putstr                    # Display message
 237                 mov $prompt,%si                 # Display
 238                 callw putstr                    #  prompt
 239                 xorb %ah,%ah                    # BIOS: Get
 240                 int $0x16                       #  keypress
 241                 movw $0x1234, BDA_BOOT          # Do a warm boot
 242                 ljmp $0xf000,$0xfff0            # reboot the machine
 243 /*
 244  * Display a null-terminated string using the BIOS output.
 245  */
 246 putstr.0:       mov $0x7,%bx                    # Page:attribute
 247                 movb $0xe,%ah                   # BIOS: Display
 248                 int $0x10                       #  character
 249 putstr:         lodsb                           # Get char
 250                 testb %al,%al                   # End of string?
 251                 jne putstr.0                    # No
 252
 253 /*
 254  * Overused return code.  ereturn is used to return an error from the
 255  * read function.  Since we assume putstr succeeds, we (ab)use the
 256  * same code when we return from putstr.
 257  */
 258 ereturn:        movb $0x1,%ah                   # Invalid
 259                 stc                             #  argument
 260 return:         retw                            # To caller
 261 /*
 262  * Reads sectors from the disk.  If EDD is enabled, then check if it is
 263  * installed and use it if it is.  If it is not installed or not enabled, then
 264  * fall back to using CHS.  Since we use a LBA, if we are using CHS, we have to
 265  * fetch the drive parameters from the BIOS and divide it out ourselves.
 266  * Call with:
 267  *
 268  * %dl  - byte     - drive number
 269  * stack - 10 bytes - EDD Packet
 270  */
 271 read:           testb $FL_PACKET,%cs:MEM_REL+flags-start # LBA support enabled?
 272                 jz read.1                       # No, use CHS
 273                 cmpb $0x80,%dl                  # Hard drive?
 274                 jb read.1                       # No, use CHS
 275                 mov $0x55aa,%bx                 # Magic
 276                 push %dx                        # Save
 277                 movb $0x41,%ah                  # BIOS: Check
 278                 int $0x13                       #  extensions present
 279                 pop %dx                         # Restore
 280                 jc read.1                       # If error, use CHS
 281                 cmp $0xaa55,%bx                 # Magic?
 282                 jne read.1                      # No, so use CHS
 283                 testb $0x1,%cl                  # Packet interface?
 284                 jz read.1                       # No, so use CHS
 285                 mov %bp,%si                     # Disk packet
 286                 movb $0x42,%ah                  # BIOS: Extended
 287                 int $0x13                       #  read
 288                 retw                            # To caller
 289 read.1:         push %dx                        # Save
 290                 movb $0x8,%ah                   # BIOS: Get drive
 291                 int $0x13                       #  parameters
 292                 movb %dh,%ch                    # Max head number
 293                 pop %dx                         # Restore
 294                 jc return                       # If error
 295                 andb $0x3f,%cl                  # Sectors per track
 296                 jz ereturn                      # If zero
 297                 cli                             # Disable interrupts
 298                 mov 0x8(%bp),%eax               # Get LBA
 299                 push %dx                        # Save
 300                 movzbl %cl,%ebx                 # Divide by
 301                 xor %edx,%edx                   #  sectors
 302                 div %ebx                        #  per track
 303                 movb %ch,%bl                    # Max head number
 304                 movb %dl,%ch                    # Sector number
 305                 inc %bx                         # Divide by
 306                 xorb %dl,%dl                    #  number
 307                 div %ebx                        #  of heads
 308                 movb %dl,%bh                    # Head number
 309                 pop %dx                         # Restore
 310                 cmpl $0x3ff,%eax                # Cylinder number supportable?
 311                 sti                             # Enable interrupts
 312                 ja ereturn                      # No, return an error
 313                 xchgb %al,%ah                   # Set up cylinder
 314                 rorb $0x2,%al                   #  number
 315                 orb %ch,%al                     # Merge
 316                 inc %ax                         #  sector
 317                 xchg %ax,%cx                    #  number
 318                 movb %bh,%dh                    # Head number
 319                 subb %ah,%al                    # Sectors this track
 320                 mov 0x2(%bp),%ah                # Blocks to read
 321                 cmpb %ah,%al                    # To read
 322                 jb read.2                       #  this
 323 #ifdef  TRACK_AT_A_TIME
 324                 movb %ah,%al                    #  track
 325 #else
 326                 movb $1,%al                     #  one sector
 327 #endif
 328 read.2:         mov $0x5,%di                    # Try count
 329 read.3:         les 0x4(%bp),%bx                # Transfer buffer
 330                 push %ax                        # Save
 331                 movb $0x2,%ah                   # BIOS: Read
 332                 int $0x13                       #  from disk
 333                 pop %bx                         # Restore
 334                 jnc read.4                      # If success
 335                 dec %di                         # Retry?
 336                 jz read.6                       # No
 337                 xorb %ah,%ah                    # BIOS: Reset
 338                 int $0x13                       #  disk system
 339                 xchg %bx,%ax                    # Block count
 340                 jmp read.3                      # Continue
 341 read.4:         movzbw %bl,%ax                  # Sectors read
 342                 add %ax,0x8(%bp)                # Adjust
 343                 jnc read.5                      #  LBA,
 344                 incw 0xa(%bp)                   #  transfer
 345 read.5:         shlb %bl                        #  buffer
 346                 add %bl,0x5(%bp)                #  pointer,
 347                 sub %al,0x2(%bp)                #  block count
 348                 ja read.1                       # If not done
 349 read.6:         retw                            # To caller
 350
 351 /* Messages */
 352
 353 msg_read:       .asciz "Read"
 354 msg_part:       .asciz "Boot"
 355
 356 prompt:         .asciz " error\r\n"
 357
 358 flags:          .byte FLAGS                     # Flags
 359
 360                 .org PRT_OFF,0x90
 361
 362 /* Partition table */
 363
 364                 .fill 0x30,0x1,0x0
 365 part4:          .byte 0x80, 0x00, 0x01, 0x00
 366                 .byte 0xa5, 0xfe, 0xff, 0xff
 367                 .byte 0x00, 0x00, 0x00, 0x00
 368                 .byte 0x50, 0xc3, 0x00, 0x00    # 50000 sectors long, bleh
 369
 370                 .word 0xaa55                    # Magic number