sys/contrib/dev/acpica/compiler/dtparser.y

   1 %{
   2 /******************************************************************************
   3  *
   4  * Module Name: dtparser.y - Bison input file for table compiler parser
   5  *
   6  *****************************************************************************/
   7
   8 /*
   9  * Copyright (C) 2000 - 2011, Intel Corp.
  10  * All rights reserved.
  11  *
  12  * Redistribution and use in source and binary forms, with or without
  13  * modification, are permitted provided that the following conditions
  14  * are met:
  15  * 1. Redistributions of source code must retain the above copyright
  16  *    notice, this list of conditions, and the following disclaimer,
  17  *    without modification.
  18  * 2. Redistributions in binary form must reproduce at minimum a disclaimer
  19  *    substantially similar to the "NO WARRANTY" disclaimer below
  20  *    ("Disclaimer") and any redistribution must be conditioned upon
  21  *    including a substantially similar Disclaimer requirement for further
  22  *    binary redistribution.
  23  * 3. Neither the names of the above-listed copyright holders nor the names
  24  *    of any contributors may be used to endorse or promote products derived
  25  *    from this software without specific prior written permission.
  26  *
  27  * Alternatively, this software may be distributed under the terms of the
  28  * GNU General Public License ("GPL") version 2 as published by the Free
  29  * Software Foundation.
  30  *
  31  * NO WARRANTY
  32  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  33  * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  34  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTIBILITY AND FITNESS FOR
  35  * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  36  * HOLDERS OR CONTRIBUTORS BE LIABLE FOR SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  37  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  38  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  39  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  40  * STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
  41  * IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  42  * POSSIBILITY OF SUCH DAMAGES.
  43  */
  44
  45 #include <contrib/dev/acpica/compiler/aslcompiler.h>
  46 #include <contrib/dev/acpica/compiler/dtcompiler.h>
  47
  48 #define _COMPONENT          DT_COMPILER
  49         ACPI_MODULE_NAME    ("dtparser")
  50
  51 int                         DtParserlex (void);
  52 int                         DtParserparse (void);
  53 void                        DtParsererror (char const *msg);
  54 extern char                 *DtParsertext;
  55 extern DT_FIELD             *Gbl_CurrentField;
  56
  57 UINT64                      DtParserResult; /* Expression return value */
  58
  59 /* Bison/yacc configuration */
  60
  61 #define yytname             DtParsername
  62 #define YYDEBUG             1               /* Enable debug output */
  63 #define YYERROR_VERBOSE     1               /* Verbose error messages */
  64 #define YYFLAG              -32768
  65
  66 %}
  67
  68 %union
  69 {
  70      UINT64                 value;
  71      UINT32                 op;
  72 }
  73
  74 /*! [Begin] no source code translation */
  75
  76 %type  <value>  Expression
  77
  78 %token <op>     EXPOP_EOF
  79 %token <op>     EXPOP_NEW_LINE
  80 %token <op>     EXPOP_NUMBER
  81 %token <op>     EXPOP_HEX_NUMBER
  82 %token <op>     EXPOP_DECIMAL_NUMBER
  83 %token <op>     EXPOP_LABEL
  84 %token <op>     EXPOP_PAREN_OPEN
  85 %token <op>     EXPOP_PAREN_CLOSE
  86
  87 %left <op>      EXPOP_LOGICAL_OR
  88 %left <op>      EXPOP_LOGICAL_AND
  89 %left <op>      EXPOP_OR
  90 %left <op>      EXPOP_XOR
  91 %left <op>      EXPOP_AND
  92 %left <op>      EXPOP_EQUAL EXPOP_NOT_EQUAL
  93 %left <op>      EXPOP_GREATER EXPOP_LESS EXPOP_GREATER_EQUAL EXPOP_LESS_EQUAL
  94 %left <op>      EXPOP_SHIFT_RIGHT EXPOP_SHIFT_LEFT
  95 %left <op>      EXPOP_ADD EXPOP_SUBTRACT
  96 %left <op>      EXPOP_MULTIPLY EXPOP_DIVIDE EXPOP_MODULO
  97 %right <op>     EXPOP_ONES_COMPLIMENT EXPOP_LOGICAL_NOT
  98
  99 %%
 100
 101 /*
 102  *  Operator precedence rules (from K&R)
 103  *
 104  *  1)      ( )
 105  *  2)      ! ~ (unary operators that are supported here)
 106  *  3)      *   /   %
 107  *  4)      +   -
 108  *  5)      >>  <<
 109  *  6)      <   >   <=  >=
 110  *  7)      ==  !=
 111  *  8)      &
 112  *  9)      ^
 113  *  10)     |
 114  *  11)     &&
 115  *  12)     ||
 116  */
 117 Value
 118     : Expression EXPOP_NEW_LINE                     { DtParserResult=$1; return 0; } /* End of line (newline) */
 119     | Expression EXPOP_EOF                          { DtParserResult=$1; return 0; } /* End of string (0) */
 120     ;
 121
 122 Expression
 123
 124       /* Unary operators */
 125
 126     : EXPOP_LOGICAL_NOT         Expression          { $$ = DtDoOperator ($2, EXPOP_LOGICAL_NOT,     $2);}
 127     | EXPOP_ONES_COMPLIMENT     Expression          { $$ = DtDoOperator ($2, EXPOP_ONES_COMPLIMENT, $2);}
 128
 129       /* Binary operators */
 130
 131     | Expression EXPOP_MULTIPLY         Expression  { $$ = DtDoOperator ($1, EXPOP_MULTIPLY,        $3);}
 132     | Expression EXPOP_DIVIDE           Expression  { $$ = DtDoOperator ($1, EXPOP_DIVIDE,          $3);}
 133     | Expression EXPOP_MODULO           Expression  { $$ = DtDoOperator ($1, EXPOP_MODULO,          $3);}
 134     | Expression EXPOP_ADD              Expression  { $$ = DtDoOperator ($1, EXPOP_ADD,             $3);}
 135     | Expression EXPOP_SUBTRACT         Expression  { $$ = DtDoOperator ($1, EXPOP_SUBTRACT,        $3);}
 136     | Expression EXPOP_SHIFT_RIGHT      Expression  { $$ = DtDoOperator ($1, EXPOP_SHIFT_RIGHT,     $3);}
 137     | Expression EXPOP_SHIFT_LEFT       Expression  { $$ = DtDoOperator ($1, EXPOP_SHIFT_LEFT,      $3);}
 138     | Expression EXPOP_GREATER          Expression  { $$ = DtDoOperator ($1, EXPOP_GREATER,         $3);}
 139     | Expression EXPOP_LESS             Expression  { $$ = DtDoOperator ($1, EXPOP_LESS,            $3);}
 140     | Expression EXPOP_GREATER_EQUAL    Expression  { $$ = DtDoOperator ($1, EXPOP_GREATER_EQUAL,   $3);}
 141     | Expression EXPOP_LESS_EQUAL       Expression  { $$ = DtDoOperator ($1, EXPOP_LESS_EQUAL,      $3);}
 142     | Expression EXPOP_EQUAL            Expression  { $$ = DtDoOperator ($1, EXPOP_EQUAL,           $3);}
 143     | Expression EXPOP_NOT_EQUAL        Expression  { $$ = DtDoOperator ($1, EXPOP_NOT_EQUAL,       $3);}
 144     | Expression EXPOP_AND              Expression  { $$ = DtDoOperator ($1, EXPOP_AND,             $3);}
 145     | Expression EXPOP_XOR              Expression  { $$ = DtDoOperator ($1, EXPOP_XOR,             $3);}
 146     | Expression EXPOP_OR               Expression  { $$ = DtDoOperator ($1, EXPOP_OR,              $3);}
 147     | Expression EXPOP_LOGICAL_AND      Expression  { $$ = DtDoOperator ($1, EXPOP_LOGICAL_AND,     $3);}
 148     | Expression EXPOP_LOGICAL_OR       Expression  { $$ = DtDoOperator ($1, EXPOP_LOGICAL_OR,      $3);}
 149
 150       /* Parentheses: '(' Expression ')' */
 151
 152     | EXPOP_PAREN_OPEN          Expression
 153         EXPOP_PAREN_CLOSE                           { $$ = $2;}
 154
 155       /* Label references (prefixed with $) */
 156
 157     | EXPOP_LABEL                                   { $$ = DtResolveLabel (DtParsertext);}
 158
 159       /* Default base for a non-prefixed integer is 16 */
 160
 161     | EXPOP_NUMBER                                  { UtStrtoul64 (DtParsertext, 16, &$$);}
 162
 163       /* Standard hex number (0x1234) */
 164
 165     | EXPOP_HEX_NUMBER                              { UtStrtoul64 (DtParsertext, 16, &$$);}
 166
 167       /* TBD: Decimal number with prefix (0d1234) - Not supported by UtStrtoul64 at this time */
 168
 169     | EXPOP_DECIMAL_NUMBER                          { UtStrtoul64 (DtParsertext, 10, &$$);}
 170     ;
 171 %%
 172
 173 /*! [End] no source code translation !*/
 174
 175 /*
 176  * Local support functions, including parser entry point
 177  */
 178 #define PR_FIRST_PARSE_OPCODE   EXPOP_EOF
 179 #define PR_YYTNAME_START        3
 180
 181
 182 /******************************************************************************
 183  *
 184  * FUNCTION:    DtParsererror
 185  *
 186  * PARAMETERS:  Message             - Parser-generated error message
 187  *
 188  * RETURN:      None
 189  *
 190  * DESCRIPTION: Handler for parser errors
 191  *
 192  *****************************************************************************/
 193
 194 void
 195 DtParsererror (
 196     char const              *Message)
 197 {
 198     DtError (ASL_ERROR, ASL_MSG_SYNTAX,
 199         Gbl_CurrentField, (char *) Message);
 200 }
 201
 202
 203 /******************************************************************************
 204  *
 205  * FUNCTION:    DtGetOpName
 206  *
 207  * PARAMETERS:  ParseOpcode         - Parser token (EXPOP_*)
 208  *
 209  * RETURN:      Pointer to the opcode name
 210  *
 211  * DESCRIPTION: Get the ascii name of the parse opcode for debug output
 212  *
 213  *****************************************************************************/
 214
 215 char *
 216 DtGetOpName (
 217     UINT32                  ParseOpcode)
 218 {
 219 #ifdef ASL_YYTNAME_START
 220     /*
 221      * First entries (PR_YYTNAME_START) in yytname are special reserved names.
 222      * Ignore first 6 characters of name (EXPOP_)
 223      */
 224     return ((char *) yytname
 225         [(ParseOpcode - PR_FIRST_PARSE_OPCODE) + PR_YYTNAME_START] + 6);
 226 #else
 227     return ("[Unknown parser generator]");
 228 #endif
 229 }
 230
 231
 232 /******************************************************************************
 233  *
 234  * FUNCTION:    DtEvaluateExpression
 235  *
 236  * PARAMETERS:  ExprString          - Expression to be evaluated. Must be
 237  *                                    terminated by either a newline or a NUL
 238  *                                    string terminator
 239  *
 240  * RETURN:      64-bit value for the expression
 241  *
 242  * DESCRIPTION: Main entry point for the DT expression parser
 243  *
 244  *****************************************************************************/
 245
 246 UINT64
 247 DtEvaluateExpression (
 248     char                    *ExprString)
 249 {
 250
 251     DbgPrint (ASL_DEBUG_OUTPUT,
 252         "**** Input expression: %s  (Base 16)\n", ExprString);
 253
 254     /* Point lexer to the input string */
 255
 256     if (DtInitLexer (ExprString))
 257     {
 258         DtError (ASL_ERROR, ASL_MSG_COMPILER_INTERNAL,
 259             Gbl_CurrentField, "Could not initialize lexer");
 260         return (0);
 261     }
 262
 263     /* Parse/Evaluate the input string (value returned in DtParserResult) */
 264
 265     DtParserparse ();
 266     DtTerminateLexer ();
 267
 268     DbgPrint (ASL_DEBUG_OUTPUT,
 269         "**** Parser returned value: %u (%8.8X%8.8X)\n",
 270         (UINT32) DtParserResult, ACPI_FORMAT_UINT64 (DtParserResult));
 271
 272     return (DtParserResult);
 273 }