sys/powerpc/aim/locore64.S

   1 /* $FreeBSD$ */
   2 /* $NetBSD: locore.S,v 1.24 2000/05/31 05:09:17 thorpej Exp $ */
   3
   4 /*-
   5  * Copyright (C) 2001 Benno Rice
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY Benno Rice ``AS IS'' AND ANY EXPRESS OR
  18  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  19  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  21  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  22  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  23  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  24  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  25  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  26  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27  */
  28 /*-
  29  * Copyright (C) 1995, 1996 Wolfgang Solfrank.
  30  * Copyright (C) 1995, 1996 TooLs GmbH.
  31  * All rights reserved.
  32  *
  33  * Redistribution and use in source and binary forms, with or without
  34  * modification, are permitted provided that the following conditions
  35  * are met:
  36  * 1. Redistributions of source code must retain the above copyright
  37  *    notice, this list of conditions and the following disclaimer.
  38  * 2. Redistributions in binary form must reproduce the above copyright
  39  *    notice, this list of conditions and the following disclaimer in the
  40  *    documentation and/or other materials provided with the distribution.
  41  * 3. All advertising materials mentioning features or use of this software
  42  *    must display the following acknowledgement:
  43  *      This product includes software developed by TooLs GmbH.
  44  * 4. The name of TooLs GmbH may not be used to endorse or promote products
  45  *    derived from this software without specific prior written permission.
  46  *
  47  * THIS SOFTWARE IS PROVIDED BY TOOLS GMBH ``AS IS'' AND ANY EXPRESS OR
  48  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  49  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  50  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  51  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  52  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  53  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  54  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  55  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  56  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  57  */
  58
  59 #include "assym.s"
  60
  61 #include <sys/syscall.h>
  62
  63 #include <machine/trap.h>
  64 #include <machine/param.h>
  65 #include <machine/spr.h>
  66 #include <machine/asm.h>
  67
  68 /* Locate the per-CPU data structure */
  69 #define GET_CPUINFO(r)  \
  70         mfsprg0  r
  71
  72 /*
  73  * Compiled KERNBASE location and the kernel load address
  74  */
  75         .globl  kernbase
  76         .set    kernbase, KERNBASE
  77
  78 #define TMPSTKSZ        16384           /* 16K temporary stack */
  79
  80 /*
  81  * Globals
  82  */
  83         .data
  84         .align  4
  85 GLOBAL(tmpstk)
  86         .space  TMPSTKSZ
  87 GLOBAL(esym)
  88         .llong  0                       /* end of symbol table */
  89
  90 #define INTRCNT_COUNT   256             /* max(HROWPIC_IRQMAX,OPENPIC_IRQMAX) */
  91 GLOBAL(intrnames)
  92         .space  INTRCNT_COUNT * (MAXCOMLEN + 1) * 2
  93 GLOBAL(sintrnames)
  94         .quad   INTRCNT_COUNT * (MAXCOMLEN + 1) * 2
  95
  96         .align 4
  97 GLOBAL(intrcnt)
  98         .space  INTRCNT_COUNT * 4 * 2
  99 GLOBAL(sintrcnt)
 100         .quad   INTRCNT_COUNT * 4 * 2
 101
 102         .text
 103         .globl  btext
 104 btext:
 105
 106 /*
 107  * This symbol is here for the benefit of kvm_mkdb, and is supposed to
 108  * mark the start of kernel text.
 109  */
 110         .globl  kernel_text
 111 kernel_text:
 112
 113 /*
 114  * Startup entry.  Note, this must be the first thing in the text
 115  * segment!
 116  */
 117         .text
 118 ASENTRY_NOPROF(__start)
 119         li      8,0
 120         li      9,0x100
 121         mtctr   9
 122 1:
 123         dcbf    0,8
 124         icbi    0,8
 125         addi    8,8,0x20
 126         bdnz    1b
 127         sync
 128         isync
 129
 130         /* Save the argument pointer and length */
 131         mr      20,6
 132         mr      21,7
 133
 134         lis     8,openfirmware_entry@ha
 135         std     5,openfirmware_entry@l(8) /* save client interface handler */
 136
 137         /* Set up the stack pointer */
 138         lis     1,(tmpstk+TMPSTKSZ-48)@ha
 139         addi    1,1,(tmpstk+TMPSTKSZ-48)@l
 140
 141         /* Set up the TOC pointer */
 142         lis     2,tocbase@ha
 143         ld      2,tocbase@l(2)
 144
 145         mfmsr   0
 146         lis     9,ofmsr@ha
 147         stdu    0,ofmsr@l(9)
 148
 149         mfsprg0 0                       /* save SPRG0-3 */
 150         std     0,8(9)                  /* ofmsr[1] = sprg0 */
 151         mfsprg1 0
 152         std     0,16(9)                 /* ofmsr[2] = sprg1 */
 153         mfsprg2 0
 154         std     0,24(9)                 /* ofmsr[3] = sprg2 */
 155         mfsprg3 0
 156         std     0,32(9)                 /* ofmsr[4] = sprg3 */
 157
 158         /* Switch to 64-bit mode */
 159         mfmsr   9
 160         li      8,1
 161         insrdi  9,8,1,0
 162         mtmsrd  9
 163
 164         bl      OF_initial_setup
 165         nop
 166
 167         lis     4,end@ha
 168         addi    4,4,end@l
 169         mr      5,4
 170
 171         lis     3,kernbase@ha
 172         addi    3,3,kernbase@l
 173
 174         /* Restore the argument pointer and length */
 175         mr      6,20
 176         mr      7,21
 177
 178         bl      powerpc_init
 179         nop
 180         mr      %r1, %r3
 181         li      %r3, 0
 182         std     %r3, 0(%r1)
 183         bl      mi_startup
 184         nop
 185         b       OF_exit
 186         nop
 187
 188 /*
 189  * PPC64 ABI TOC base
 190  */
 191
 192         .align  3
 193         .globl  tocbase
 194 tocbase:
 195         .llong  .TOC.@tocbase
 196
 197 /*
 198  * int setfault()
 199  *
 200  * Similar to setjmp to setup for handling faults on accesses to user memory.
 201  * Any routine using this may only call bcopy, either the form below,
 202  * or the (currently used) C code optimized, so it doesn't use any non-volatile
 203  * registers.
 204  */
 205 ASENTRY_NOPROF(setfault)
 206         mflr    0
 207         mfcr    12
 208         mfsprg  4,0
 209         ld      4,TD_PCB(13)    /* curthread = r13 */
 210         std     3,PCB_ONFAULT(4)
 211         std     0,0(3)
 212         std     1,8(3)
 213         std     2,16(3)
 214
 215         std     %r12,24(%r3)    /* Save the non-volatile GP regs. */
 216         std     %r13,24+1*8(%r3)
 217         std     %r14,24+2*8(%r3)
 218         std     %r15,24+3*8(%r3)
 219         std     %r16,24+4*8(%r3)
 220         std     %r17,24+5*8(%r3)
 221         std     %r18,24+6*8(%r3)
 222         std     %r19,24+7*8(%r3)
 223         std     %r20,24+8*8(%r3)
 224         std     %r21,24+9*8(%r3)
 225         std     %r22,24+10*8(%r3)
 226         std     %r23,24+11*8(%r3)
 227         std     %r24,24+12*8(%r3)
 228         std     %r25,24+13*8(%r3)
 229         std     %r26,24+14*8(%r3)
 230         std     %r27,24+15*8(%r3)
 231         std     %r28,24+16*8(%r3)
 232         std     %r29,24+17*8(%r3)
 233         std     %r30,24+18*8(%r3)
 234         std     %r31,24+19*8(%r3)
 235
 236         xor     3,3,3
 237         blr
 238
 239 #include <powerpc/aim/trap_subr64.S>