contrib/ntp/sntp/m4/ntp_libevent.m4

   1 # SYNOPSIS                                              -*- Autoconf -*-
   2 #
   3 #  NTP_ENABLE_LOCAL_LIBEVENT
   4 #  NTP_LIBEVENT_CHECK([MINVERSION [, DIR]])
   5 #  NTP_LIBEVENT_CHECK_NOBUILD([MINVERSION [, DIR]])
   6 #
   7 # DESCRIPTION
   8 #
   9 # AUTHOR
  10 #
  11 #  Harlan Stenn
  12 #
  13 # LICENSE
  14 #
  15 #  This file is Copyright (c) 2014 Network Time Foundation
  16 #
  17 #  Copying and distribution of this file, with or without modification, are
  18 #  permitted in any medium without royalty provided the copyright notice,
  19 #  author attribution and this notice are preserved.  This file is offered
  20 #  as-is, without any warranty.
  21
  22 dnl NTP_ENABLE_LOCAL_LIBEVENT
  23 dnl
  24 dnl Provide only the --enable-local-libevent command-line option.
  25 dnl
  26 dnl Used standalone by top-level NTP configure.ac, which should have
  27 dnl --enable-local-libevent in its --help output but which doesn't do
  28 dnl anything differently based upon its presence or value.
  29 dnl
  30 dnl Also AC_REQUIRE'd by NTP_LIBEVENT_CHECK_NOBUILD.
  31 AC_DEFUN([NTP_ENABLE_LOCAL_LIBEVENT], [
  32
  33 AC_ARG_ENABLE(
  34     [local-libevent],
  35     [AC_HELP_STRING(
  36         [--enable-local-libevent],
  37         [Force using the supplied libevent tearoff code]
  38     )],
  39     [ntp_use_local_libevent=$enableval],
  40     [ntp_use_local_libevent=${ntp_use_local_libevent-detect}]
  41 )
  42
  43 ]) dnl NTP_ENABLE_LOCAL_LIBEVENT
  44
  45 dnl NTP_LIBEVENT_CHECK_NOBUILD([MINVERSION [, DIR]])         -*- Autoconf -*-
  46 dnl
  47 dnl Look for libevent, which must be at least MINVERSION.
  48 dnl DIR is the location of our "bundled" copy of libevent.
  49 dnl If NOBUILD is provided as the 3rd argument, do all of the above,
  50 dnl but DO NOT invoke DIR/configure if we are going to use our bundled
  51 dnl version.  This may be the case for nested packages.
  52 dnl
  53 dnl provides: --enable-local-libevent
  54 dnl
  55 dnl Examples:
  56 dnl
  57 dnl    NTP_LIBEVENT_CHECK_NOBUILD([2.0.9], [sntp/libevent])
  58 dnl    NTP_LIBEVENT_CHECK
  59 dnl
  60 AC_DEFUN([NTP_LIBEVENT_CHECK_NOBUILD], [
  61 AC_REQUIRE([NTP_PKG_CONFIG])dnl
  62 AC_REQUIRE([NTP_ENABLE_LOCAL_LIBEVENT])dnl
  63
  64 ntp_libevent_min_version=m4_default([$1], [2.0.9])
  65 ntp_libevent_tearoff=m4_default([$2], [libevent])
  66
  67 AC_SUBST([CFLAGS_LIBEVENT])
  68 AC_SUBST([CPPFLAGS_LIBEVENT])
  69 AC_SUBST([LDADD_LIBEVENT])
  70
  71 case "$ntp_use_local_libevent" in
  72  yes)
  73     ;;
  74  *) # If we have (a good enough) pkg-config, see if it can find libevent
  75     case "$PKG_CONFIG" in
  76      /*)
  77         AC_MSG_CHECKING([if libevent $ntp_libevent_min_version or later is installed])
  78         if $PKG_CONFIG --atleast-version=$ntp_libevent_min_version libevent
  79         then
  80             ntp_use_local_libevent=no
  81             AC_MSG_NOTICE([Using the installed libevent])
  82             CFLAGS_LIBEVENT=`$PKG_CONFIG --cflags libevent_pthreads`
  83             CPPFLAGS_LIBEVENT=`$PKG_CONFIG --cflags-only-I libevent`
  84             # HMS: I hope the following is accurate.
  85             # We don't need -levent, we only need  -levent_core.
  86             # While we could grab only the -L stuff, there *might* be
  87             # other flags there we want.  Originally we just removed -levent
  88             # but then somebody decided to install -levent-2.0
  89             # LDADD_LIBEVENT=`$PKG_CONFIG --libs libevent | sed 's:-levent::'`
  90             # So now we dance...
  91             LDADD_LIBEVENT=
  92             for i in `$PKG_CONFIG --libs libevent` `$PKG_CONFIG --cflags-only-other libevent_pthreads`
  93             do
  94                 case "$i" in
  95                  -D*) ;;
  96                  -levent*) ;;
  97                  *) case "$LDADD_LIBEVENT" in
  98                      '') LDADD_LIBEVENT="$i" ;;
  99                      *) LDADD_LIBEVENT="$LDADD_LIBEVENT $i" ;;
 100                     esac
 101                     ;;
 102                 esac
 103             done
 104             case "$LIBISC_PTHREADS_NOTHREADS" in
 105              pthreads)
 106                 LDADD_LIBEVENT="$LDADD_LIBEVENT -levent_pthreads"
 107             esac
 108             LDADD_LIBEVENT="$LDADD_LIBEVENT -levent_core"
 109             AC_MSG_RESULT([yes])
 110         else
 111             ntp_use_local_libevent=yes
 112             # HMS: do we only need to do this if LIBISC_PTHREADS_NOTHREADS
 113             # is "pthreads"?
 114             CFLAGS_LIBEVENT=`$PKG_CONFIG --cflags libevent_pthreads`
 115             AC_MSG_RESULT([no])
 116         fi
 117         ;;
 118      *)
 119         ntp_use_local_libevent=yes
 120         ;;
 121     esac
 122     ;;
 123 esac
 124
 125 case "$ntp_use_local_libevent" in
 126  yes)
 127     AC_MSG_NOTICE([Using libevent tearoff])
 128     CPPFLAGS_LIBEVENT="-I\$(top_builddir)/$ntp_libevent_tearoff/include -I\$(top_srcdir)/$ntp_libevent_tearoff/include"
 129     case "$LIBISC_PTHREADS_NOTHREADS" in
 130      pthreads)
 131         LDADD_LIBEVENT="\$(top_builddir)/$ntp_libevent_tearoff/libevent_pthreads.la \$(top_builddir)/$ntp_libevent_tearoff/libevent_core.la"
 132         ;;
 133      *)
 134         LDADD_LIBEVENT="\$(top_builddir)/$ntp_libevent_tearoff/libevent_core.la"
 135     esac
 136 esac
 137
 138 dnl AC_ARG_ENABLE(
 139 dnl     [cflags-libevent],
 140 dnl     [AC_HELP_STRING(
 141 dnl     [--enable-cflags-libevent=-pthread],
 142 dnl     [CFLAGS value to build with pthreads]
 143 dnl     )],
 144 dnl     [CFLAGS_LIBEVENT=$enableval],
 145 dnl     [# See above about LIBISC_PTHREADS_NOTHREADS
 146 dnl     case "$CFLAGS_LIBEVENT" in
 147 dnl      '') CFLAGS_LIBEVENT="-pthread" ;;
 148 dnl      *) ;;
 149 dnl     esac]
 150 dnl )
 151 dnl AC_MSG_NOTICE([LIBISC_PTHREADS_NOTHREADS is <$LIBISC_PTHREADS_NOTHREADS>])
 152 dnl AC_MSG_NOTICE([CFLAGS_LIBEVENT is <$CFLAGS_LIBEVENT>])
 153
 154 AM_CONDITIONAL([BUILD_LIBEVENT], [test "x$ntp_use_local_libevent" = "xyes"])
 155
 156 ]) dnl NTP_LIBEVENT_CHECK_NOBUILD
 157
 158 dnl NTP_LIBEVENT_CHECK([MINVERSION [, DIR]])         -*- Autoconf -*-
 159 AC_DEFUN([NTP_LIBEVENT_CHECK], [
 160
 161 AC_SUBST([NTP_FORCE_LIBEVENT_DIST])
 162 NTP_LIBEVENT_CHECK_NOBUILD([$1], [$2])
 163
 164 case "$ntp_libevent_tearoff" in
 165  libevent)
 166     ;;
 167  *)
 168     AC_MSG_ERROR([ntp_libevent.m4 dir must be libevent, not $ntp_libevent_tearoff])
 169     ;;
 170 esac
 171
 172 case "$ntp_use_local_libevent" in
 173  yes)
 174     dnl ac_configure_args is undocumented but widely abused, as here,
 175     dnl to modify the defaults of the libevent subpackage, by prefixing
 176     dnl our changes to the child configure arguments already assembled.
 177     dnl User-supplied contradictory choices should prevail thanks to
 178     dnl "last wins".
 179     ac_configure_args=" --disable-openssl${ac_configure_args}"
 180     ac_configure_args=" --disable-shared${ac_configure_args}"
 181     ac_configure_args=" --disable-libevent-regress${ac_configure_args}"
 182     ac_configure_args=" --disable-libevent-install${ac_configure_args}"
 183     ac_configure_args=" --enable-silent-rules${ac_configure_args}"
 184     ac_configure_args=" --enable-function-sections${ac_configure_args}"
 185     AC_CONFIG_SUBDIRS([libevent])
 186     ;;
 187  *)
 188     NTP_FORCE_LIBEVENT_DIST=libevent
 189     ;;
 190 esac
 191
 192 ]) dnl NTP_LIBEVENT_CHECK
 193