cddl/contrib/dtracetoolkit/Php/php_calltime.d

   1 #!/usr/sbin/dtrace -Zs
   2 /*
   3  * php_calltime.d - measure PHP elapsed times for functions.
   4  *                  Written for the PHP DTrace provider.
   5  *
   6  * $Id: php_calltime.d 53 2007-09-24 04:58:38Z brendan $
   7  *
   8  * This traces PHP activity from all programs running on the system with
   9  * PHP provider support.
  10  *
  11  * USAGE: php_calltime.d        # hit Ctrl-C to end
  12  *
  13  * FIELDS:
  14  *              FILE            Filename of the PHP program
  15  *              TYPE            Type of call (func/total)
  16  *              NAME            Name of call
  17  *              TOTAL           Total elapsed time for calls (us)
  18  *
  19  * Filename and function names are printed if available.
  20  *
  21  * COPYRIGHT: Copyright (c) 2007 Brendan Gregg.
  22  *
  23  * CDDL HEADER START
  24  *
  25  *  The contents of this file are subject to the terms of the
  26  *  Common Development and Distribution License, Version 1.0 only
  27  *  (the "License").  You may not use this file except in compliance
  28  *  with the License.
  29  *
  30  *  You can obtain a copy of the license at Docs/cddl1.txt
  31  *  or http://www.opensolaris.org/os/licensing.
  32  *  See the License for the specific language governing permissions
  33  *  and limitations under the License.
  34  *
  35  * CDDL HEADER END
  36  *
  37  * 09-Sep-2007  Brendan Gregg   Created this.
  38  */
  39
  40 #pragma D option quiet
  41
  42 dtrace:::BEGIN
  43 {
  44         printf("Tracing... Hit Ctrl-C to end.\n");
  45 }
  46
  47 php*:::function-entry
  48 /arg0/
  49 {
  50         self->depth++;
  51         self->exclude[self->depth] = 0;
  52         self->function[self->depth] = timestamp;
  53 }
  54
  55 php*:::function-return
  56 /arg0 && self->function[self->depth]/
  57 {
  58         this->elapsed_incl = timestamp - self->function[self->depth];
  59         this->elapsed_excl = this->elapsed_incl - self->exclude[self->depth];
  60         self->function[self->depth] = 0;
  61         self->exclude[self->depth] = 0;
  62         this->file = basename(copyinstr(arg1));
  63         this->name = copyinstr(arg0);
  64
  65         @num[this->file, "func", this->name] = count();
  66         @num["-", "total", "-"] = count();
  67         @types_incl[this->file, "func", this->name] = sum(this->elapsed_incl);
  68         @types_excl[this->file, "func", this->name] = sum(this->elapsed_excl);
  69         @types_excl["-", "total", "-"] = sum(this->elapsed_excl);
  70
  71         self->depth--;
  72         self->exclude[self->depth] += this->elapsed_incl;
  73 }
  74
  75 dtrace:::END
  76 {
  77         printf("\nCount,\n");
  78         printf("   %-20s %-10s %-32s %8s\n", "FILE", "TYPE", "NAME", "COUNT");
  79         printa("   %-20s %-10s %-32s %@8d\n", @num);
  80
  81         normalize(@types_excl, 1000);
  82         printf("\nExclusive function elapsed times (us),\n");
  83         printf("   %-20s %-10s %-32s %8s\n", "FILE", "TYPE", "NAME", "TOTAL");
  84         printa("   %-20s %-10s %-32s %@8d\n", @types_excl);
  85
  86         normalize(@types_incl, 1000);
  87         printf("\nInclusive function elapsed times (us),\n");
  88         printf("   %-20s %-10s %-32s %8s\n", "FILE", "TYPE", "NAME", "TOTAL");
  89         printa("   %-20s %-10s %-32s %@8d\n", @types_incl);
  90 }