cddl/contrib/dtracetoolkit/Shell/sh_calldist.d

   1 #!/usr/sbin/dtrace -Zs
   2 /*
   3  * sh_calldist.d - measure Bourne shell elapsed times for types of operation.
   4  *                 Written for the sh DTrace provider.
   5  *
   6  * $Id: sh_calldist.d 28 2007-09-13 10:49:37Z brendan $
   7  *
   8  * This traces shell activity from all Bourne shells on the system that are
   9  * running with sh provider support.
  10  *
  11  * USAGE: sh_calldist.d         # hit Ctrl-C to end
  12  *
  13  * This script prints distribution plots of elapsed time for shell
  14  * operations. Use sh_calltime.d for summary reports.
  15  *
  16  * FIELDS:
  17  *              1               Filename of the shell or shellscript
  18  *              2               Type of call (func/builtin/cmd)
  19  *              3               Name of call
  20  *
  21  * Filename and call names are printed if available.
  22  *
  23  * COPYRIGHT: Copyright (c) 2007 Brendan Gregg.
  24  *
  25  * CDDL HEADER START
  26  *
  27  *  The contents of this file are subject to the terms of the
  28  *  Common Development and Distribution License, Version 1.0 only
  29  *  (the "License").  You may not use this file except in compliance
  30  *  with the License.
  31  *
  32  *  You can obtain a copy of the license at Docs/cddl1.txt
  33  *  or http://www.opensolaris.org/os/licensing.
  34  *  See the License for the specific language governing permissions
  35  *  and limitations under the License.
  36  *
  37  * CDDL HEADER END
  38  *
  39  * 09-Sep-2007  Brendan Gregg   Created this.
  40  */
  41
  42 #pragma D option quiet
  43
  44 dtrace:::BEGIN
  45 {
  46         printf("Tracing... Hit Ctrl-C to end.\n");
  47 }
  48
  49 sh*:::function-entry
  50 {
  51         self->depth++;
  52         self->exclude[self->depth] = 0;
  53         self->function[self->depth] = timestamp;
  54 }
  55
  56 sh*:::function-return
  57 /self->function[self->depth]/
  58 {
  59         this->elapsed_incl = timestamp - self->function[self->depth];
  60         this->elapsed_excl = this->elapsed_incl - self->exclude[self->depth];
  61         self->function[self->depth] = 0;
  62         self->exclude[self->depth] = 0;
  63         this->file = basename(copyinstr(arg0));
  64         this->name = copyinstr(arg1);
  65
  66         @types_incl[this->file, "func", this->name] =
  67             quantize(this->elapsed_incl / 1000);
  68         @types_excl[this->file, "func", this->name] =
  69             quantize(this->elapsed_excl / 1000);
  70
  71         self->depth--;
  72         self->exclude[self->depth] += this->elapsed_incl;
  73 }
  74
  75 sh*:::builtin-entry
  76 {
  77         self->builtin = timestamp;
  78 }
  79
  80 sh*:::builtin-return
  81 /self->builtin/
  82 {
  83         this->elapsed = timestamp - self->builtin;
  84         self->builtin = 0;
  85
  86         @types[basename(copyinstr(arg0)), "builtin", copyinstr(arg1)] =
  87             quantize(this->elapsed / 1000);
  88
  89         self->exclude[self->depth] += this->elapsed;
  90 }
  91
  92 sh*:::command-entry
  93 {
  94         self->command = timestamp;
  95 }
  96
  97 sh*:::command-return
  98 /self->command/
  99 {
 100         this->elapsed = timestamp - self->command;
 101         self->command = 0;
 102
 103         @types[basename(copyinstr(arg0)), "cmd", copyinstr(arg1)] =
 104             quantize(this->elapsed / 1000);
 105
 106         self->exclude[self->depth] += this->elapsed;
 107 }
 108
 109 dtrace:::END
 110 {
 111         printf("Elapsed times (us),\n\n");
 112         printa("   %s, %s, %s %@d\n", @types);
 113
 114         printf("Exclusive function elapsed times (us),\n\n");
 115         printa("   %s, %s, %s %@d\n", @types_excl);
 116
 117         printf("Inclusive function elapsed times (us),\n\n");
 118         printa("   %s, %s, %s %@d\n", @types_incl);
 119 }