contrib/expat/configure.ac

   1 dnl   configuration script for expat
   2 dnl   Process this file with autoconf to produce a configure script.
   3 dnl
   4 dnl   Copyright 2000 Clark Cooper
   5 dnl
   6 dnl   This file is part of EXPAT.
   7 dnl
   8 dnl   EXPAT is free software; you can redistribute it and/or modify it
   9 dnl   under the terms of the License (based on the MIT/X license) contained
  10 dnl   in the file COPYING that comes with this distribution.
  11 dnl
  12
  13 dnl Ensure that Expat is configured with autoconf 2.58 or newer
  14 AC_PREREQ(2.58)
  15
  16 dnl Get the version number of Expat, using m4's esyscmd() command to run
  17 dnl the command at m4-generation time. This allows us to create an m4
  18 dnl symbol holding the correct version number. AC_INIT() requires the
  19 dnl version number at m4-time, rather than when ./configure is run, so
  20 dnl all this must happen as part of m4, not as part of the shell code
  21 dnl contained in ./configure.
  22 dnl
  23 dnl NOTE: esyscmd() is a GNU M4 extension. Thus, we wrap it in an appropriate
  24 dnl test. I believe this test will work, but I don't have a place with non-
  25 dnl GNU M4 to test it right now.
  26 define([expat_version], ifdef([__gnu__],
  27                               [esyscmd(conftools/get-version.sh lib/expat.h)],
  28                               [2.2.x]))
  29 AC_INIT(expat, expat_version, expat-bugs@libexpat.org)
  30 undefine([expat_version])
  31
  32 AC_CONFIG_SRCDIR(Makefile.in)
  33 AC_CONFIG_AUX_DIR(conftools)
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36
  37 dnl
  38 dnl Increment LIBREVISION if source code has changed at all
  39 dnl
  40 dnl If the API has changed, increment LIBCURRENT and set LIBREVISION to 0
  41 dnl
  42 dnl If the API changes compatibly (i.e. simply adding a new function
  43 dnl without changing or removing earlier interfaces), then increment LIBAGE.
  44 dnl
  45 dnl If the API changes incompatibly set LIBAGE back to 0
  46 dnl
  47
  48 LIBCURRENT=7   # sync
  49 LIBREVISION=2  # with
  50 LIBAGE=6       # CMakeLists.txt!
  51
  52 AC_CONFIG_HEADER(expat_config.h)
  53
  54 sinclude(conftools/ac_c_bigendian_cross.m4)
  55
  56 AC_LIBTOOL_WIN32_DLL
  57 AC_PROG_LIBTOOL
  58
  59 AC_SUBST(LIBCURRENT)
  60 AC_SUBST(LIBREVISION)
  61 AC_SUBST(LIBAGE)
  62
  63 dnl Checks for programs.
  64 AC_PROG_CC
  65 AC_PROG_CXX
  66 AC_PROG_INSTALL
  67
  68 if test "$GCC" = yes ; then
  69     dnl
  70     dnl Be careful about adding the -fexceptions option; some versions of
  71     dnl GCC don't support it and it causes extra warnings that are only
  72     dnl distracting; avoid.
  73     dnl
  74     OLDCFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wstrict-prototypes"
  75     CFLAGS="$OLDCFLAGS -fexceptions"
  76     AC_MSG_CHECKING(whether $CC accepts -fexceptions)
  77     AC_TRY_LINK( , ,
  78                    AC_MSG_RESULT(yes),
  79                    AC_MSG_RESULT(no); CFLAGS="$OLDCFLAGS")
  80     if test "x$CXXFLAGS" = x ; then
  81     CXXFLAGS=`echo "$CFLAGS" | sed 's/ -Wmissing-prototypes -Wstrict-prototypes//'`
  82     fi
  83 fi
  84
  85 dnl Checks for header files.
  86 AC_HEADER_STDC
  87
  88 dnl Checks for typedefs, structures, and compiler characteristics.
  89
  90 dnl Note: Avoid using AC_C_BIGENDIAN because it does not
  91 dnl work in a cross compile.
  92 AC_C_BIGENDIAN_CROSS
  93
  94 AC_C_CONST
  95 AC_TYPE_SIZE_T
  96 AC_CHECK_FUNCS(memmove bcopy)
  97
  98 dnl Only needed for xmlwf:
  99 AC_CHECK_HEADERS(fcntl.h unistd.h)
 100 AC_TYPE_OFF_T
 101 AC_FUNC_MMAP
 102
 103 if test "$ac_cv_func_mmap_fixed_mapped" = "yes"; then
 104     FILEMAP=unixfilemap
 105 else
 106     FILEMAP=readfilemap
 107 fi
 108 AC_SUBST(FILEMAP)
 109
 110 dnl Needed for the test support code; this was found at
 111 dnl http://lists.gnu.org/archive/html/bug-autoconf/2002-07/msg00028.html
 112
 113 # AC_CPP_FUNC
 114 # ------------------ #
 115 # Checks to see if ANSI C99 CPP variable __func__ works.
 116 # If not, perhaps __FUNCTION__ works instead.
 117 # If not, we'll just define __func__ to "".
 118 AC_DEFUN([AC_CPP_FUNC],
 119 [AC_REQUIRE([AC_PROG_CC_STDC])dnl
 120 AC_CACHE_CHECK([for an ANSI C99-conforming __func__], ac_cv_cpp_func,
 121 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
 122 [[char *foo = __func__;]])],
 123   [ac_cv_cpp_func=yes],
 124   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
 125 [[char *foo = __FUNCTION__;]])],
 126   [ac_cv_cpp_func=__FUNCTION__],
 127   [ac_cv_cpp_func=no])])])
 128 if test $ac_cv_cpp_func = __FUNCTION__; then
 129   AC_DEFINE(__func__,__FUNCTION__,
 130             [Define to __FUNCTION__ or "" if `__func__' does not conform to
 131 ANSI C.])
 132 elif test $ac_cv_cpp_func = no; then
 133   AC_DEFINE(__func__,"",
 134             [Define to __FUNCTION__ or "" if `__func__' does not conform to
 135 ANSI C.])
 136 fi
 137 ])# AC_CPP_FUNC
 138
 139 AC_CPP_FUNC
 140
 141
 142 dnl Some basic configuration:
 143 AC_DEFINE([XML_NS], 1,
 144           [Define to make XML Namespaces functionality available.])
 145 AC_DEFINE([XML_DTD], 1,
 146           [Define to make parameter entity parsing functionality available.])
 147 AC_DEFINE([XML_CONTEXT_BYTES], 1024,
 148           [Define to specify how much context to retain around the current parse point.])
 149
 150 AC_CONFIG_FILES([Makefile expat.pc])
 151 AC_OUTPUT
 152
 153 abs_srcdir="`cd $srcdir && pwd`"
 154 abs_builddir="`pwd`"
 155 if test "$abs_srcdir" != "$abs_builddir"; then
 156   make mkdir-init
 157 fi