contrib/llvm/include/llvm/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand has floating-point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisVec - The specified operand has a vector type.
  40 class SDTCisVec<int OpNum> : SDTypeConstraint<OpNum>;
  41
  42 // SDTCisSameAs - The two specified operands have identical types.
  43 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  44   int OtherOperandNum = OtherOp;
  45 }
  46
  47 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  48 // smaller than the 'Other' operand.
  49 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  50   int OtherOperandNum = OtherOp;
  51 }
  52
  53 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  54   int BigOperandNum = BigOp;
  55 }
  56
  57 /// SDTCisEltOfVec - This indicates that ThisOp is a scalar type of the same
  58 /// type as the element type of OtherOp, which is a vector type.
  59 class SDTCisEltOfVec<int ThisOp, int OtherOp>
  60   : SDTypeConstraint<ThisOp> {
  61   int OtherOpNum = OtherOp;
  62 }
  63
  64 /// SDTCisSubVecOfVec - This indicates that ThisOp is a vector type
  65 /// with length less that of OtherOp, which is a vector type.
  66 class SDTCisSubVecOfVec<int ThisOp, int OtherOp>
  67   : SDTypeConstraint<ThisOp> {
  68   int OtherOpNum = OtherOp;
  69 }
  70
  71 //===----------------------------------------------------------------------===//
  72 // Selection DAG Type Profile definitions.
  73 //
  74 // These use the constraints defined above to describe the type requirements of
  75 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  76 // add their own if needed.
  77 //
  78
  79 // SDTypeProfile - This profile describes the type requirements of a Selection
  80 // DAG node.
  81 class SDTypeProfile<int numresults, int numoperands,
  82                     list<SDTypeConstraint> constraints> {
  83   int NumResults = numresults;
  84   int NumOperands = numoperands;
  85   list<SDTypeConstraint> Constraints = constraints;
  86 }
  87
  88 // Builtin profiles.
  89 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;         // for 'imm'.
  90 def SDTFPLeaf : SDTypeProfile<1, 0, [SDTCisFP<0>]>;          // for 'fpimm'.
  91 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;       // for '&g'.
  92 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  93 def SDTUNDEF  : SDTypeProfile<1, 0, []>;                     // for 'undef'.
  94 def SDTUnaryOp  : SDTypeProfile<1, 1, []>;                   // for bitconvert.
  95
  96 def SDTIntBinOp : SDTypeProfile<1, 2, [     // add, and, or, xor, udiv, etc.
  97   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  98 ]>;
  99 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
 100   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
 101 ]>;
 102 def SDTIntBinHiLoOp : SDTypeProfile<2, 2, [ // mulhi, mullo, sdivrem, udivrem
 103   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>,SDTCisInt<0>
 104 ]>;
 105
 106 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
 107   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
 108 ]>;
 109 def SDTFPSignOp : SDTypeProfile<1, 2, [     // fcopysign.
 110   SDTCisSameAs<0, 1>, SDTCisFP<0>, SDTCisFP<2>
 111 ]>;
 112 def SDTFPTernaryOp : SDTypeProfile<1, 3, [  // fmadd, fnmsub, etc.
 113   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
 114 ]>;
 115 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
 116   SDTCisSameAs<0, 1>, SDTCisInt<0>
 117 ]>;
 118 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
 119   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
 120 ]>;
 121 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
 122   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
 123 ]>;
 124 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
 125   SDTCisSameAs<0, 1>, SDTCisFP<0>
 126 ]>;
 127 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 128   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 129 ]>;
 130 def SDTFPExtendOp  : SDTypeProfile<1, 1, [  // fextend
 131   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 132 ]>;
 133 def SDTIntToFPOp : SDTypeProfile<1, 1, [    // [su]int_to_fp
 134   SDTCisFP<0>, SDTCisInt<1>
 135 ]>;
 136 def SDTFPToIntOp : SDTypeProfile<1, 1, [    // fp_to_[su]int
 137   SDTCisInt<0>, SDTCisFP<1>
 138 ]>;
 139 def SDTExtInreg : SDTypeProfile<1, 2, [     // sext_inreg
 140   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 141   SDTCisVTSmallerThanOp<2, 1>
 142 ]>;
 143
 144 def SDTSetCC : SDTypeProfile<1, 3, [        // setcc
 145   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 146 ]>;
 147
 148 def SDTSelect : SDTypeProfile<1, 3, [       // select
 149   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 150 ]>;
 151
 152 def SDTVSelect : SDTypeProfile<1, 3, [       // vselect
 153   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 154 ]>;
 155
 156 def SDTSelectCC : SDTypeProfile<1, 5, [     // select_cc
 157   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 158   SDTCisVT<5, OtherVT>
 159 ]>;
 160
 161 def SDTBr : SDTypeProfile<0, 1, [           // br
 162   SDTCisVT<0, OtherVT>
 163 ]>;
 164
 165 def SDTBrcond : SDTypeProfile<0, 2, [       // brcond
 166   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 167 ]>;
 168
 169 def SDTBrind : SDTypeProfile<0, 1, [        // brind
 170   SDTCisPtrTy<0>
 171 ]>;
 172
 173 def SDTNone : SDTypeProfile<0, 0, []>;      // ret, trap
 174
 175 def SDTLoad : SDTypeProfile<1, 1, [         // load
 176   SDTCisPtrTy<1>
 177 ]>;
 178
 179 def SDTStore : SDTypeProfile<0, 2, [        // store
 180   SDTCisPtrTy<1>
 181 ]>;
 182
 183 def SDTIStore : SDTypeProfile<1, 3, [       // indexed store
 184   SDTCisSameAs<0, 2>, SDTCisPtrTy<0>, SDTCisPtrTy<3>
 185 ]>;
 186
 187 def SDTVecShuffle : SDTypeProfile<1, 2, [
 188   SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>
 189 ]>;
 190 def SDTVecExtract : SDTypeProfile<1, 2, [   // vector extract
 191   SDTCisEltOfVec<0, 1>, SDTCisPtrTy<2>
 192 ]>;
 193 def SDTVecInsert : SDTypeProfile<1, 3, [    // vector insert
 194   SDTCisEltOfVec<2, 1>, SDTCisSameAs<0, 1>, SDTCisPtrTy<3>
 195 ]>;
 196
 197 def SDTSubVecExtract : SDTypeProfile<1, 2, [// subvector extract
 198   SDTCisSubVecOfVec<0,1>, SDTCisInt<2>
 199 ]>;
 200 def SDTSubVecInsert : SDTypeProfile<1, 3, [ // subvector insert
 201   SDTCisSubVecOfVec<2, 1>, SDTCisSameAs<0,1>, SDTCisInt<3>
 202 ]>;
 203
 204 def SDTPrefetch : SDTypeProfile<0, 4, [     // prefetch
 205   SDTCisPtrTy<0>, SDTCisSameAs<1, 2>, SDTCisSameAs<1, 3>, SDTCisInt<1>
 206 ]>;
 207
 208 def SDTMemBarrier : SDTypeProfile<0, 5, [   // memory barier
 209   SDTCisSameAs<0,1>,  SDTCisSameAs<0,2>,  SDTCisSameAs<0,3>, SDTCisSameAs<0,4>,
 210   SDTCisInt<0>
 211 ]>;
 212 def SDTAtomicFence : SDTypeProfile<0, 2, [
 213   SDTCisSameAs<0,1>, SDTCisPtrTy<0>
 214 ]>;
 215 def SDTAtomic3 : SDTypeProfile<1, 3, [
 216   SDTCisSameAs<0,2>,  SDTCisSameAs<0,3>, SDTCisInt<0>, SDTCisPtrTy<1>
 217 ]>;
 218 def SDTAtomic2 : SDTypeProfile<1, 2, [
 219   SDTCisSameAs<0,2>, SDTCisInt<0>, SDTCisPtrTy<1>
 220 ]>;
 221 def SDTAtomicStore : SDTypeProfile<0, 2, [
 222   SDTCisPtrTy<0>, SDTCisInt<1>
 223 ]>;
 224 def SDTAtomicLoad : SDTypeProfile<1, 1, [
 225   SDTCisInt<0>, SDTCisPtrTy<1>
 226 ]>;
 227
 228 def SDTConvertOp : SDTypeProfile<1, 5, [ //cvtss, su, us, uu, ff, fs, fu, sf, su
 229   SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>, SDTCisPtrTy<4>, SDTCisPtrTy<5>
 230 ]>;
 231
 232 class SDCallSeqStart<list<SDTypeConstraint> constraints> :
 233         SDTypeProfile<0, 1, constraints>;
 234 class SDCallSeqEnd<list<SDTypeConstraint> constraints> :
 235         SDTypeProfile<0, 2, constraints>;
 236
 237 //===----------------------------------------------------------------------===//
 238 // Selection DAG Node Properties.
 239 //
 240 // Note: These are hard coded into tblgen.
 241 //
 242 class SDNodeProperty;
 243 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 244 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 245 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 246 def SDNPOutGlue     : SDNodeProperty;   // Write a flag result
 247 def SDNPInGlue      : SDNodeProperty;   // Read a flag operand
 248 def SDNPOptInGlue   : SDNodeProperty;   // Optionally read a flag operand
 249 def SDNPMayStore    : SDNodeProperty;   // May write to memory, sets 'mayStore'.
 250 def SDNPMayLoad     : SDNodeProperty;   // May read memory, sets 'mayLoad'.
 251 def SDNPSideEffect  : SDNodeProperty;   // Sets 'HasUnmodelledSideEffects'.
 252 def SDNPMemOperand  : SDNodeProperty;   // Touches memory, has assoc MemOperand
 253 def SDNPVariadic    : SDNodeProperty;   // Node has variable arguments.
 254 def SDNPWantRoot    : SDNodeProperty;   // ComplexPattern gets the root of match
 255 def SDNPWantParent  : SDNodeProperty;   // ComplexPattern gets the parent
 256
 257 //===----------------------------------------------------------------------===//
 258 // Selection DAG Pattern Operations
 259 class SDPatternOperator;
 260
 261 //===----------------------------------------------------------------------===//
 262 // Selection DAG Node definitions.
 263 //
 264 class SDNode<string opcode, SDTypeProfile typeprof,
 265              list<SDNodeProperty> props = [], string sdclass = "SDNode">
 266              : SDPatternOperator {
 267   string Opcode  = opcode;
 268   string SDClass = sdclass;
 269   list<SDNodeProperty> Properties = props;
 270   SDTypeProfile TypeProfile = typeprof;
 271 }
 272
 273 // Special TableGen-recognized dag nodes
 274 def set;
 275 def implicit;
 276 def node;
 277 def srcvalue;
 278
 279 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 280 def timm       : SDNode<"ISD::TargetConstant",SDTIntLeaf, [], "ConstantSDNode">;
 281 def fpimm      : SDNode<"ISD::ConstantFP", SDTFPLeaf  , [], "ConstantFPSDNode">;
 282 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 283 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 284 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 285 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 286 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 287                         "GlobalAddressSDNode">;
 288 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 289                          "GlobalAddressSDNode">;
 290 def globaltlsaddr : SDNode<"ISD::GlobalTLSAddress",         SDTPtrLeaf, [],
 291                           "GlobalAddressSDNode">;
 292 def tglobaltlsaddr : SDNode<"ISD::TargetGlobalTLSAddress",  SDTPtrLeaf, [],
 293                            "GlobalAddressSDNode">;
 294 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 295                          "ConstantPoolSDNode">;
 296 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 297                          "ConstantPoolSDNode">;
 298 def jumptable   : SDNode<"ISD::JumpTable",            SDTPtrLeaf, [],
 299                          "JumpTableSDNode">;
 300 def tjumptable  : SDNode<"ISD::TargetJumpTable",      SDTPtrLeaf, [],
 301                          "JumpTableSDNode">;
 302 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 303                          "FrameIndexSDNode">;
 304 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 305                          "FrameIndexSDNode">;
 306 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 307                          "ExternalSymbolSDNode">;
 308 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 309                          "ExternalSymbolSDNode">;
 310 def blockaddress : SDNode<"ISD::BlockAddress",        SDTPtrLeaf, [],
 311                          "BlockAddressSDNode">;
 312 def tblockaddress: SDNode<"ISD::TargetBlockAddress",  SDTPtrLeaf, [],
 313                          "BlockAddressSDNode">;
 314
 315 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 316                         [SDNPCommutative, SDNPAssociative]>;
 317 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 318 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 319                         [SDNPCommutative, SDNPAssociative]>;
 320 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 321 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 322 def smullohi   : SDNode<"ISD::SMUL_LOHI" , SDTIntBinHiLoOp, [SDNPCommutative]>;
 323 def umullohi   : SDNode<"ISD::UMUL_LOHI" , SDTIntBinHiLoOp, [SDNPCommutative]>;
 324 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 325 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 326 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 327 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 328 def sdivrem    : SDNode<"ISD::SDIVREM"   , SDTIntBinHiLoOp>;
 329 def udivrem    : SDNode<"ISD::UDIVREM"   , SDTIntBinHiLoOp>;
 330 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 331 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 332 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 333 def rotl       : SDNode<"ISD::ROTL"      , SDTIntShiftOp>;
 334 def rotr       : SDNode<"ISD::ROTR"      , SDTIntShiftOp>;
 335 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 336                         [SDNPCommutative, SDNPAssociative]>;
 337 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 338                         [SDNPCommutative, SDNPAssociative]>;
 339 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 340                         [SDNPCommutative, SDNPAssociative]>;
 341 def addc       : SDNode<"ISD::ADDC"      , SDTIntBinOp,
 342                         [SDNPCommutative, SDNPOutGlue]>;
 343 def adde       : SDNode<"ISD::ADDE"      , SDTIntBinOp,
 344                         [SDNPCommutative, SDNPOutGlue, SDNPInGlue]>;
 345 def subc       : SDNode<"ISD::SUBC"      , SDTIntBinOp,
 346                         [SDNPOutGlue]>;
 347 def sube       : SDNode<"ISD::SUBE"      , SDTIntBinOp,
 348                         [SDNPOutGlue, SDNPInGlue]>;
 349
 350 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 351 def bswap      : SDNode<"ISD::BSWAP"      , SDTIntUnaryOp>;
 352 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 353 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 354 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 355 def ctlz_zero_undef : SDNode<"ISD::CTLZ_ZERO_UNDEF", SDTIntUnaryOp>;
 356 def cttz_zero_undef : SDNode<"ISD::CTTZ_ZERO_UNDEF", SDTIntUnaryOp>;
 357 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 358 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 359 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 360 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 361 def bitconvert : SDNode<"ISD::BITCAST"    , SDTUnaryOp>;
 362 def extractelt : SDNode<"ISD::EXTRACT_VECTOR_ELT", SDTVecExtract>;
 363 def insertelt  : SDNode<"ISD::INSERT_VECTOR_ELT", SDTVecInsert>;
 364
 365
 366 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 367 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 368 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 369 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 370 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 371 def fma        : SDNode<"ISD::FMA"        , SDTFPTernaryOp>;
 372 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 373 def fgetsign   : SDNode<"ISD::FGETSIGN"   , SDTFPToIntOp>;
 374 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 375 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 376 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 377 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 378 def fexp2      : SDNode<"ISD::FEXP2"      , SDTFPUnaryOp>;
 379 def flog2      : SDNode<"ISD::FLOG2"      , SDTFPUnaryOp>;
 380 def frint      : SDNode<"ISD::FRINT"      , SDTFPUnaryOp>;
 381 def ftrunc     : SDNode<"ISD::FTRUNC"     , SDTFPUnaryOp>;
 382 def fceil      : SDNode<"ISD::FCEIL"      , SDTFPUnaryOp>;
 383 def ffloor     : SDNode<"ISD::FFLOOR"     , SDTFPUnaryOp>;
 384 def fnearbyint : SDNode<"ISD::FNEARBYINT" , SDTFPUnaryOp>;
 385
 386 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 387 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 388 def fcopysign  : SDNode<"ISD::FCOPYSIGN"  , SDTFPSignOp>;
 389
 390 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 391 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 392 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 393 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 394 def f16_to_f32 : SDNode<"ISD::FP16_TO_FP32", SDTIntToFPOp>;
 395 def f32_to_f16 : SDNode<"ISD::FP32_TO_FP16", SDTFPToIntOp>;
 396
 397 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 398 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 399 def vselect    : SDNode<"ISD::VSELECT"    , SDTVSelect>;
 400 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 401
 402 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrcond, [SDNPHasChain]>;
 403 def brind      : SDNode<"ISD::BRIND"      , SDTBrind,  [SDNPHasChain]>;
 404 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 405 def trap       : SDNode<"ISD::TRAP"       , SDTNone,
 406                         [SDNPHasChain, SDNPSideEffect]>;
 407
 408 def prefetch   : SDNode<"ISD::PREFETCH"   , SDTPrefetch,
 409                         [SDNPHasChain, SDNPMayLoad, SDNPMayStore,
 410                          SDNPMemOperand]>;
 411
 412 def membarrier : SDNode<"ISD::MEMBARRIER" , SDTMemBarrier,
 413                         [SDNPHasChain, SDNPSideEffect]>;
 414
 415 def atomic_fence : SDNode<"ISD::ATOMIC_FENCE" , SDTAtomicFence,
 416                           [SDNPHasChain, SDNPSideEffect]>;
 417
 418 def atomic_cmp_swap : SDNode<"ISD::ATOMIC_CMP_SWAP" , SDTAtomic3,
 419                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 420 def atomic_load_add : SDNode<"ISD::ATOMIC_LOAD_ADD" , SDTAtomic2,
 421                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 422 def atomic_swap     : SDNode<"ISD::ATOMIC_SWAP", SDTAtomic2,
 423                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 424 def atomic_load_sub : SDNode<"ISD::ATOMIC_LOAD_SUB" , SDTAtomic2,
 425                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 426 def atomic_load_and : SDNode<"ISD::ATOMIC_LOAD_AND" , SDTAtomic2,
 427                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 428 def atomic_load_or  : SDNode<"ISD::ATOMIC_LOAD_OR" , SDTAtomic2,
 429                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 430 def atomic_load_xor : SDNode<"ISD::ATOMIC_LOAD_XOR" , SDTAtomic2,
 431                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 432 def atomic_load_nand: SDNode<"ISD::ATOMIC_LOAD_NAND", SDTAtomic2,
 433                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 434 def atomic_load_min : SDNode<"ISD::ATOMIC_LOAD_MIN", SDTAtomic2,
 435                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 436 def atomic_load_max : SDNode<"ISD::ATOMIC_LOAD_MAX", SDTAtomic2,
 437                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 438 def atomic_load_umin : SDNode<"ISD::ATOMIC_LOAD_UMIN", SDTAtomic2,
 439                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 440 def atomic_load_umax : SDNode<"ISD::ATOMIC_LOAD_UMAX", SDTAtomic2,
 441                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 442 def atomic_load      : SDNode<"ISD::ATOMIC_LOAD", SDTAtomicLoad,
 443                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 444 def atomic_store     : SDNode<"ISD::ATOMIC_STORE", SDTAtomicStore,
 445                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 446
 447 // Do not use ld, st directly. Use load, extload, sextload, zextload, store,
 448 // and truncst (see below).
 449 def ld         : SDNode<"ISD::LOAD"       , SDTLoad,
 450                         [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 451 def st         : SDNode<"ISD::STORE"      , SDTStore,
 452                         [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 453 def ist        : SDNode<"ISD::STORE"      , SDTIStore,
 454                         [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 455
 456 def vector_shuffle : SDNode<"ISD::VECTOR_SHUFFLE", SDTVecShuffle, []>;
 457 def build_vector : SDNode<"ISD::BUILD_VECTOR", SDTypeProfile<1, -1, []>, []>;
 458 def scalar_to_vector : SDNode<"ISD::SCALAR_TO_VECTOR", SDTypeProfile<1, 1, []>,
 459                               []>;
 460 def vector_extract : SDNode<"ISD::EXTRACT_VECTOR_ELT",
 461     SDTypeProfile<1, 2, [SDTCisPtrTy<2>]>, []>;
 462 def vector_insert : SDNode<"ISD::INSERT_VECTOR_ELT",
 463     SDTypeProfile<1, 3, [SDTCisSameAs<0, 1>, SDTCisPtrTy<3>]>, []>;
 464
 465 // This operator does not do subvector type checking.  The ARM
 466 // backend, at least, needs it.
 467 def vector_extract_subvec : SDNode<"ISD::EXTRACT_SUBVECTOR",
 468     SDTypeProfile<1, 2, [SDTCisInt<2>, SDTCisVec<1>, SDTCisVec<0>]>,
 469     []>;
 470
 471 // This operator does subvector type checking.
 472 def extract_subvector : SDNode<"ISD::EXTRACT_SUBVECTOR", SDTSubVecExtract, []>;
 473 def insert_subvector : SDNode<"ISD::INSERT_SUBVECTOR", SDTSubVecInsert, []>;
 474
 475 // Nodes for intrinsics, you should use the intrinsic itself and let tblgen use
 476 // these internally.  Don't reference these directly.
 477 def intrinsic_void : SDNode<"ISD::INTRINSIC_VOID",
 478                             SDTypeProfile<0, -1, [SDTCisPtrTy<0>]>,
 479                             [SDNPHasChain]>;
 480 def intrinsic_w_chain : SDNode<"ISD::INTRINSIC_W_CHAIN",
 481                                SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>,
 482                                [SDNPHasChain]>;
 483 def intrinsic_wo_chain : SDNode<"ISD::INTRINSIC_WO_CHAIN",
 484                                 SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>, []>;
 485
 486 // Do not use cvt directly. Use cvt forms below
 487 def cvt : SDNode<"ISD::CONVERT_RNDSAT", SDTConvertOp>;
 488
 489 //===----------------------------------------------------------------------===//
 490 // Selection DAG Condition Codes
 491
 492 class CondCode; // ISD::CondCode enums
 493 def SETOEQ : CondCode; def SETOGT : CondCode;
 494 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 495 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 496 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 497 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 498
 499 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 500 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 501
 502
 503 //===----------------------------------------------------------------------===//
 504 // Selection DAG Node Transformation Functions.
 505 //
 506 // This mechanism allows targets to manipulate nodes in the output DAG once a
 507 // match has been formed.  This is typically used to manipulate immediate
 508 // values.
 509 //
 510 class SDNodeXForm<SDNode opc, code xformFunction> {
 511   SDNode Opcode = opc;
 512   code XFormFunction = xformFunction;
 513 }
 514
 515 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 516
 517 //===----------------------------------------------------------------------===//
 518 // PatPred Subclasses.
 519 //
 520 // These allow specifying different sorts of predicates that control whether a
 521 // node is matched.
 522 //
 523 class PatPred;
 524
 525 class CodePatPred<code predicate> : PatPred {
 526   code PredicateCode = predicate;
 527 }
 528
 529
 530 //===----------------------------------------------------------------------===//
 531 // Selection DAG Pattern Fragments.
 532 //
 533 // Pattern fragments are reusable chunks of dags that match specific things.
 534 // They can take arguments and have C++ predicates that control whether they
 535 // match.  They are intended to make the patterns for common instructions more
 536 // compact and readable.
 537 //
 538
 539 /// PatFrag - Represents a pattern fragment.  This can match something on the
 540 /// DAG, from a single node to multiple nested other fragments.
 541 ///
 542 class PatFrag<dag ops, dag frag, code pred = [{}],
 543               SDNodeXForm xform = NOOP_SDNodeXForm> : SDPatternOperator {
 544   dag Operands = ops;
 545   dag Fragment = frag;
 546   code PredicateCode = pred;
 547   code ImmediateCode = [{}];
 548   SDNodeXForm OperandTransform = xform;
 549 }
 550
 551 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 552 // to define immediates and other common things concisely.
 553 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 554  : PatFrag<(ops), frag, pred, xform>;
 555
 556
 557 // ImmLeaf is a pattern fragment with a constraint on the immediate.  The
 558 // constraint is a function that is run on the immediate (always with the value
 559 // sign extended out to an int64_t) as Imm.  For example:
 560 //
 561 //  def immSExt8 : ImmLeaf<i16, [{ return (char)Imm == Imm; }]>;
 562 //
 563 // this is a more convenient form to match 'imm' nodes in than PatLeaf and also
 564 // is preferred over using PatLeaf because it allows the code generator to
 565 // reason more about the constraint.
 566 //
 567 // If FastIsel should ignore all instructions that have an operand of this type,
 568 // the FastIselShouldIgnore flag can be set.  This is an optimization to reduce
 569 // the code size of the generated fast instruction selector.
 570 class ImmLeaf<ValueType vt, code pred, SDNodeXForm xform = NOOP_SDNodeXForm>
 571   : PatFrag<(ops), (vt imm), [{}], xform> {
 572   let ImmediateCode = pred;
 573   bit FastIselShouldIgnore = 0;
 574 }
 575
 576
 577 // Leaf fragments.
 578
 579 def vtInt      : PatLeaf<(vt),  [{ return N->getVT().isInteger(); }]>;
 580 def vtFP       : PatLeaf<(vt),  [{ return N->getVT().isFloatingPoint(); }]>;
 581
 582 def immAllOnesV: PatLeaf<(build_vector), [{
 583   return ISD::isBuildVectorAllOnes(N);
 584 }]>;
 585 def immAllZerosV: PatLeaf<(build_vector), [{
 586   return ISD::isBuildVectorAllZeros(N);
 587 }]>;
 588
 589
 590
 591 // Other helper fragments.
 592 def not  : PatFrag<(ops node:$in), (xor node:$in, -1)>;
 593 def vnot : PatFrag<(ops node:$in), (xor node:$in, immAllOnesV)>;
 594 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 595
 596 // load fragments.
 597 def unindexedload : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 598   return cast<LoadSDNode>(N)->getAddressingMode() == ISD::UNINDEXED;
 599 }]>;
 600 def load : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 601   return cast<LoadSDNode>(N)->getExtensionType() == ISD::NON_EXTLOAD;
 602 }]>;
 603
 604 // extending load fragments.
 605 def extload   : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 606   return cast<LoadSDNode>(N)->getExtensionType() == ISD::EXTLOAD;
 607 }]>;
 608 def sextload  : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 609   return cast<LoadSDNode>(N)->getExtensionType() == ISD::SEXTLOAD;
 610 }]>;
 611 def zextload  : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 612   return cast<LoadSDNode>(N)->getExtensionType() == ISD::ZEXTLOAD;
 613 }]>;
 614
 615 def extloadi1  : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 616   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i1;
 617 }]>;
 618 def extloadi8  : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 619   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
 620 }]>;
 621 def extloadi16 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 622   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
 623 }]>;
 624 def extloadi32 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 625   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
 626 }]>;
 627 def extloadf32 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 628   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::f32;
 629 }]>;
 630 def extloadf64 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 631   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::f64;
 632 }]>;
 633
 634 def sextloadi1  : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 635   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i1;
 636 }]>;
 637 def sextloadi8  : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 638   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
 639 }]>;
 640 def sextloadi16 : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 641   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
 642 }]>;
 643 def sextloadi32 : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 644   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
 645 }]>;
 646
 647 def zextloadi1  : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 648   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i1;
 649 }]>;
 650 def zextloadi8  : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 651   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
 652 }]>;
 653 def zextloadi16 : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 654   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
 655 }]>;
 656 def zextloadi32 : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 657   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
 658 }]>;
 659
 660 def extloadvi1  : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 661   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i1;
 662 }]>;
 663 def extloadvi8  : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 664   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i8;
 665 }]>;
 666 def extloadvi16 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 667   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i16;
 668 }]>;
 669 def extloadvi32 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 670   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i32;
 671 }]>;
 672 def extloadvf32 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 673   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::f32;
 674 }]>;
 675 def extloadvf64 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 676   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::f64;
 677 }]>;
 678
 679 def sextloadvi1  : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 680   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i1;
 681 }]>;
 682 def sextloadvi8  : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 683   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i8;
 684 }]>;
 685 def sextloadvi16 : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 686   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i16;
 687 }]>;
 688 def sextloadvi32 : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 689   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i32;
 690 }]>;
 691
 692 def zextloadvi1  : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 693   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i1;
 694 }]>;
 695 def zextloadvi8  : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 696   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i8;
 697 }]>;
 698 def zextloadvi16 : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 699   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i16;
 700 }]>;
 701 def zextloadvi32 : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 702   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i32;
 703 }]>;
 704
 705 // store fragments.
 706 def unindexedstore : PatFrag<(ops node:$val, node:$ptr),
 707                              (st node:$val, node:$ptr), [{
 708   return cast<StoreSDNode>(N)->getAddressingMode() == ISD::UNINDEXED;
 709 }]>;
 710 def store : PatFrag<(ops node:$val, node:$ptr),
 711                     (unindexedstore node:$val, node:$ptr), [{
 712   return !cast<StoreSDNode>(N)->isTruncatingStore();
 713 }]>;
 714
 715 // truncstore fragments.
 716 def truncstore : PatFrag<(ops node:$val, node:$ptr),
 717                          (unindexedstore node:$val, node:$ptr), [{
 718   return cast<StoreSDNode>(N)->isTruncatingStore();
 719 }]>;
 720 def truncstorei8 : PatFrag<(ops node:$val, node:$ptr),
 721                            (truncstore node:$val, node:$ptr), [{
 722   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i8;
 723 }]>;
 724 def truncstorei16 : PatFrag<(ops node:$val, node:$ptr),
 725                             (truncstore node:$val, node:$ptr), [{
 726   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i16;
 727 }]>;
 728 def truncstorei32 : PatFrag<(ops node:$val, node:$ptr),
 729                             (truncstore node:$val, node:$ptr), [{
 730   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i32;
 731 }]>;
 732 def truncstoref32 : PatFrag<(ops node:$val, node:$ptr),
 733                             (truncstore node:$val, node:$ptr), [{
 734   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::f32;
 735 }]>;
 736 def truncstoref64 : PatFrag<(ops node:$val, node:$ptr),
 737                             (truncstore node:$val, node:$ptr), [{
 738   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::f64;
 739 }]>;
 740
 741 // indexed store fragments.
 742 def istore : PatFrag<(ops node:$val, node:$base, node:$offset),
 743                      (ist node:$val, node:$base, node:$offset), [{
 744   return !cast<StoreSDNode>(N)->isTruncatingStore();
 745 }]>;
 746
 747 def pre_store : PatFrag<(ops node:$val, node:$base, node:$offset),
 748                         (istore node:$val, node:$base, node:$offset), [{
 749   ISD::MemIndexedMode AM = cast<StoreSDNode>(N)->getAddressingMode();
 750   return AM == ISD::PRE_INC || AM == ISD::PRE_DEC;
 751 }]>;
 752
 753 def itruncstore : PatFrag<(ops node:$val, node:$base, node:$offset),
 754                           (ist node:$val, node:$base, node:$offset), [{
 755   return cast<StoreSDNode>(N)->isTruncatingStore();
 756 }]>;
 757 def pre_truncst : PatFrag<(ops node:$val, node:$base, node:$offset),
 758                           (itruncstore node:$val, node:$base, node:$offset), [{
 759   ISD::MemIndexedMode AM = cast<StoreSDNode>(N)->getAddressingMode();
 760   return AM == ISD::PRE_INC || AM == ISD::PRE_DEC;
 761 }]>;
 762 def pre_truncsti1 : PatFrag<(ops node:$val, node:$base, node:$offset),
 763                             (pre_truncst node:$val, node:$base, node:$offset), [{
 764   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i1;
 765 }]>;
 766 def pre_truncsti8 : PatFrag<(ops node:$val, node:$base, node:$offset),
 767                             (pre_truncst node:$val, node:$base, node:$offset), [{
 768   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i8;
 769 }]>;
 770 def pre_truncsti16 : PatFrag<(ops node:$val, node:$base, node:$offset),
 771                              (pre_truncst node:$val, node:$base, node:$offset), [{
 772   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i16;
 773 }]>;
 774 def pre_truncsti32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 775                              (pre_truncst node:$val, node:$base, node:$offset), [{
 776   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i32;
 777 }]>;
 778 def pre_truncstf32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 779                              (pre_truncst node:$val, node:$base, node:$offset), [{
 780   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::f32;
 781 }]>;
 782
 783 def post_store : PatFrag<(ops node:$val, node:$ptr, node:$offset),
 784                          (istore node:$val, node:$ptr, node:$offset), [{
 785   ISD::MemIndexedMode AM = cast<StoreSDNode>(N)->getAddressingMode();
 786   return AM == ISD::POST_INC || AM == ISD::POST_DEC;
 787 }]>;
 788
 789 def post_truncst : PatFrag<(ops node:$val, node:$base, node:$offset),
 790                            (itruncstore node:$val, node:$base, node:$offset), [{
 791   ISD::MemIndexedMode AM = cast<StoreSDNode>(N)->getAddressingMode();
 792   return AM == ISD::POST_INC || AM == ISD::POST_DEC;
 793 }]>;
 794 def post_truncsti1 : PatFrag<(ops node:$val, node:$base, node:$offset),
 795                              (post_truncst node:$val, node:$base, node:$offset), [{
 796   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i1;
 797 }]>;
 798 def post_truncsti8 : PatFrag<(ops node:$val, node:$base, node:$offset),
 799                              (post_truncst node:$val, node:$base, node:$offset), [{
 800   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i8;
 801 }]>;
 802 def post_truncsti16 : PatFrag<(ops node:$val, node:$base, node:$offset),
 803                               (post_truncst node:$val, node:$base, node:$offset), [{
 804   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i16;
 805 }]>;
 806 def post_truncsti32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 807                               (post_truncst node:$val, node:$base, node:$offset), [{
 808   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i32;
 809 }]>;
 810 def post_truncstf32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 811                               (post_truncst node:$val, node:$base, node:$offset), [{
 812   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::f32;
 813 }]>;
 814
 815 // setcc convenience fragments.
 816 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 817                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 818 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 819                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 820 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 821                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 822 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 823                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 824 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 825                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 826 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 827                      (setcc node:$lhs, node:$rhs, SETONE)>;
 828 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 829                      (setcc node:$lhs, node:$rhs, SETO)>;
 830 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 831                      (setcc node:$lhs, node:$rhs, SETUO)>;
 832 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 833                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 834 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 835                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 836 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 837                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 838 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 839                      (setcc node:$lhs, node:$rhs, SETULT)>;
 840 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 841                      (setcc node:$lhs, node:$rhs, SETULE)>;
 842 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 843                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 844 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 845                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 846 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 847                      (setcc node:$lhs, node:$rhs, SETGT)>;
 848 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 849                      (setcc node:$lhs, node:$rhs, SETGE)>;
 850 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 851                      (setcc node:$lhs, node:$rhs, SETLT)>;
 852 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 853                      (setcc node:$lhs, node:$rhs, SETLE)>;
 854 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 855                      (setcc node:$lhs, node:$rhs, SETNE)>;
 856
 857 def atomic_cmp_swap_8 :
 858   PatFrag<(ops node:$ptr, node:$cmp, node:$swap),
 859           (atomic_cmp_swap node:$ptr, node:$cmp, node:$swap), [{
 860   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i8;
 861 }]>;
 862 def atomic_cmp_swap_16 :
 863   PatFrag<(ops node:$ptr, node:$cmp, node:$swap),
 864           (atomic_cmp_swap node:$ptr, node:$cmp, node:$swap), [{
 865   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i16;
 866 }]>;
 867 def atomic_cmp_swap_32 :
 868   PatFrag<(ops node:$ptr, node:$cmp, node:$swap),
 869           (atomic_cmp_swap node:$ptr, node:$cmp, node:$swap), [{
 870   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i32;
 871 }]>;
 872 def atomic_cmp_swap_64 :
 873   PatFrag<(ops node:$ptr, node:$cmp, node:$swap),
 874           (atomic_cmp_swap node:$ptr, node:$cmp, node:$swap), [{
 875   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i64;
 876 }]>;
 877
 878 multiclass binary_atomic_op<SDNode atomic_op> {
 879   def _8 : PatFrag<(ops node:$ptr, node:$val),
 880                    (atomic_op node:$ptr, node:$val), [{
 881     return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i8;
 882   }]>;
 883   def _16 : PatFrag<(ops node:$ptr, node:$val),
 884                    (atomic_op node:$ptr, node:$val), [{
 885     return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i16;
 886   }]>;
 887   def _32 : PatFrag<(ops node:$ptr, node:$val),
 888                    (atomic_op node:$ptr, node:$val), [{
 889     return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i32;
 890   }]>;
 891   def _64 : PatFrag<(ops node:$ptr, node:$val),
 892                    (atomic_op node:$ptr, node:$val), [{
 893     return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i64;
 894   }]>;
 895 }
 896
 897 defm atomic_load_add  : binary_atomic_op<atomic_load_add>;
 898 defm atomic_swap      : binary_atomic_op<atomic_swap>;
 899 defm atomic_load_sub  : binary_atomic_op<atomic_load_sub>;
 900 defm atomic_load_and  : binary_atomic_op<atomic_load_and>;
 901 defm atomic_load_or   : binary_atomic_op<atomic_load_or>;
 902 defm atomic_load_xor  : binary_atomic_op<atomic_load_xor>;
 903 defm atomic_load_nand : binary_atomic_op<atomic_load_nand>;
 904 defm atomic_load_min  : binary_atomic_op<atomic_load_min>;
 905 defm atomic_load_max  : binary_atomic_op<atomic_load_max>;
 906 defm atomic_load_umin : binary_atomic_op<atomic_load_umin>;
 907 defm atomic_load_umax : binary_atomic_op<atomic_load_umax>;
 908 defm atomic_store     : binary_atomic_op<atomic_store>;
 909
 910 def atomic_load_8 :
 911   PatFrag<(ops node:$ptr),
 912           (atomic_load node:$ptr), [{
 913   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i8;
 914 }]>;
 915 def atomic_load_16 :
 916   PatFrag<(ops node:$ptr),
 917           (atomic_load node:$ptr), [{
 918   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i16;
 919 }]>;
 920 def atomic_load_32 :
 921   PatFrag<(ops node:$ptr),
 922           (atomic_load node:$ptr), [{
 923   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i32;
 924 }]>;
 925 def atomic_load_64 :
 926   PatFrag<(ops node:$ptr),
 927           (atomic_load node:$ptr), [{
 928   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i64;
 929 }]>;
 930
 931 //===----------------------------------------------------------------------===//
 932 // Selection DAG CONVERT_RNDSAT patterns
 933
 934 def cvtff : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
 935     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
 936        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_FF;
 937     }]>;
 938
 939 def cvtss : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
 940     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
 941        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_SS;
 942     }]>;
 943
 944 def cvtsu : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
 945     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
 946        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_SU;
 947     }]>;
 948
 949 def cvtus : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
 950     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
 951        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_US;
 952     }]>;
 953
 954 def cvtuu : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
 955     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
 956        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_UU;
 957     }]>;
 958
 959 def cvtsf : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
 960     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
 961        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_SF;
 962     }]>;
 963
 964 def cvtuf : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
 965     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
 966        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_UF;
 967     }]>;
 968
 969 def cvtfs : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
 970     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
 971        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_FS;
 972     }]>;
 973
 974 def cvtfu : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
 975     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
 976        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_FU;
 977     }]>;
 978
 979 //===----------------------------------------------------------------------===//
 980 // Selection DAG Pattern Support.
 981 //
 982 // Patterns are what are actually matched against by the target-flavored
 983 // instruction selection DAG.  Instructions defined by the target implicitly
 984 // define patterns in most cases, but patterns can also be explicitly added when
 985 // an operation is defined by a sequence of instructions (e.g. loading a large
 986 // immediate value on RISC targets that do not support immediates as large as
 987 // their GPRs).
 988 //
 989
 990 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 991   dag             PatternToMatch  = patternToMatch;
 992   list<dag>       ResultInstrs    = resultInstrs;
 993   list<Predicate> Predicates      = [];  // See class Instruction in Target.td.
 994   int             AddedComplexity = 0;   // See class Instruction in Target.td.
 995 }
 996
 997 // Pat - A simple (but common) form of a pattern, which produces a simple result
 998 // not needing a full list.
 999 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
1000
1001 //===----------------------------------------------------------------------===//
1002 // Complex pattern definitions.
1003 //
1004
1005 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
1006 // in C++. NumOperands is the number of operands returned by the select function;
1007 // SelectFunc is the name of the function used to pattern match the max. pattern;
1008 // RootNodes are the list of possible root nodes of the sub-dags to match.
1009 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
1010 //
1011 class ComplexPattern<ValueType ty, int numops, string fn,
1012                      list<SDNode> roots = [], list<SDNodeProperty> props = []> {
1013   ValueType Ty = ty;
1014   int NumOperands = numops;
1015   string SelectFunc = fn;
1016   list<SDNode> RootNodes = roots;
1017   list<SDNodeProperty> Properties = props;
1018 }