release/doc/share/xml/release.xsl

   1 <?xml version="1.0"?>
   2 <!-- $FreeBSD$ -->
   3 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   4                 version='1.0'
   5                 xmlns="http://www.w3.org/TR/xhtml1/transitional"
   6                 xmlns:db="http://docbook.org/ns/docbook"
   7                 exclude-result-prefixes="db">
   8
   9   <xsl:import href="http://www.FreeBSD.org/XML/share/xml/freebsd-xhtml.xsl"/>
  10
  11   <xsl:import href="http://www.FreeBSD.org/release/XML/lang/share/xml/release.xsl"/>
  12
  13   <xsl:param name="release.url"/>
  14   <xsl:param name="release.branch"/>
  15
  16   <xsl:template name="paragraph">
  17     <xsl:param name="class" select="''"/>
  18     <xsl:param name="content"/>
  19
  20     <xsl:variable name="p">
  21       <p>
  22         <xsl:choose>
  23           <xsl:when test="$class != ''">
  24             <xsl:call-template name="common.html.attributes">
  25               <xsl:with-param name="class" select="$class"/>
  26              </xsl:call-template>
  27            </xsl:when>
  28           <xsl:otherwise>
  29             <xsl:call-template name="locale.html.attributes"/>
  30            </xsl:otherwise>
  31          </xsl:choose>
  32         <xsl:if test="@arch">
  33           <xsl:value-of select="concat('[', @arch, ']')"/>
  34           <xsl:value-of select='" "'/>
  35         </xsl:if>
  36         <xsl:copy-of select="$content"/>
  37         <xsl:value-of select='" "'/>
  38         <xsl:if test="@revision">
  39           <xsl:element name="a">
  40             <xsl:attribute name="href">
  41               <xsl:value-of select="concat('http://svn.freebsd.org/viewvc/base?view=revision&#38;revision=', @revision)"/>
  42             </xsl:attribute>
  43             <xsl:value-of select="concat('[r', @revision, ']')"/>
  44           </xsl:element>
  45         </xsl:if>
  46         <xsl:if test="@contrib">
  47           <xsl:element name="span">
  48             <xsl:attribute name="class">
  49               <xsl:value-of select="'contrib'"/>
  50             </xsl:attribute>
  51             <xsl:choose>
  52               <xsl:when test="@contrib = 'sponsor'">
  53                 <xsl:if test="@sponsor != ''">
  54                   (Sponsored by
  55                   <xsl:choose>
  56                     <xsl:when test="@sponsorurl != ''">
  57                       <xsl:element name="a">
  58                         <xsl:attribute name="href">
  59                           <xsl:value-of select="@sponsorurl"/>
  60                         </xsl:attribute>
  61                         <xsl:value-of select="concat(@sponsor, ')')"/>
  62                       </xsl:element>
  63                     </xsl:when>
  64                     <xsl:otherwise>
  65                       <xsl:value-of select="concat(@sponsor, ')')"/>
  66                     </xsl:otherwise>
  67                   </xsl:choose>
  68                 </xsl:if>
  69               </xsl:when>
  70               <xsl:when test="@contrib = 'vendor'">
  71                 <xsl:if test="@vendor != ''">
  72                   (Contributed / provided by
  73                   <xsl:choose>
  74                     <xsl:when test="@vendorurl != ''">
  75                       <xsl:element name="a">
  76                         <xsl:attribute name="href">
  77                           <xsl:value-of select="@vendorurl"/>
  78                         </xsl:attribute>
  79                         <xsl:value-of select="concat(@vendor, ')')"/>
  80                       </xsl:element>
  81                     </xsl:when>
  82                     <xsl:otherwise>
  83                       <xsl:value-of select="concat(@vendor, ')')"/>
  84                     </xsl:otherwise>
  85                   </xsl:choose>
  86                 </xsl:if>
  87               </xsl:when>
  88             </xsl:choose>
  89           </xsl:element>
  90         </xsl:if>
  91        </p>
  92      </xsl:variable>
  93
  94     <xsl:choose>
  95       <xsl:when test="$html.cleanup != 0">
  96         <xsl:call-template name="unwrap.p">
  97           <xsl:with-param name="p" select="$p"/>
  98          </xsl:call-template>
  99        </xsl:when>
 100       <xsl:otherwise>
 101         <xsl:copy-of select="$p"/>
 102        </xsl:otherwise>
 103      </xsl:choose>
 104    </xsl:template>
 105 </xsl:stylesheet>