media-gfx/gimp/gimp-2.6.11-r2.ebuild

   1 # Copyright 1999-2011 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.6.11-r2.ebuild,v 1.1 2011/04/19 20:08:45 hanno Exp $
   4
   5 EAPI="3"
   6 PYTHON_DEPEND="python? 2:2.5"
   7
   8 inherit eutils gnome2 fdo-mime multilib python
   9
  10 DESCRIPTION="GNU Image Manipulation Program"
  11 HOMEPAGE="http://www.gimp.org/"
  12 SRC_URI="mirror://gimp/v2.6/${P}.tar.bz2"
  13
  14 LICENSE="GPL-2"
  15 SLOT="2"
  16 KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
  17
  18 IUSE="alsa aalib altivec curl dbus debug doc exif gnome jpeg lcms mmx mng pdf png python smp sse svg tiff webkit wmf"
  19
  20 RDEPEND=">=dev-libs/glib-2.18.1:2
  21         >=x11-libs/gtk+-2.12.5:2
  22         >=x11-libs/pango-1.18.0
  23         x11-libs/libXpm
  24         >=media-libs/freetype-2.1.7
  25         >=media-libs/fontconfig-2.2.0
  26         sys-libs/zlib
  27         dev-libs/libxml2
  28         dev-libs/libxslt
  29         x11-misc/xdg-utils
  30         x11-themes/hicolor-icon-theme
  31         >=media-libs/gegl-0.0.22
  32         aalib? ( media-libs/aalib )
  33         alsa? ( media-libs/alsa-lib )
  34         curl? ( net-misc/curl )
  35         dbus? ( dev-libs/dbus-glib )
  36         gnome? ( gnome-base/gvfs )
  37         webkit? ( net-libs/webkit-gtk:2 )
  38         jpeg? ( virtual/jpeg:0 )
  39         exif? ( >=media-libs/libexif-0.6.15 )
  40         lcms? ( =media-libs/lcms-1* )
  41         mng? ( media-libs/libmng )
  42         pdf? ( >=app-text/poppler-0.12.3-r3[cairo] )
  43         png? ( >=media-libs/libpng-1.2.2:0 )
  44         python? ( >=dev-python/pygtk-2.10.4:2 )
  45         tiff? ( >=media-libs/tiff-3.5.7 )
  46         svg? ( >=gnome-base/librsvg-2.8.0:2 )
  47         wmf? ( >=media-libs/libwmf-0.2.8 )"
  48 DEPEND="${RDEPEND}
  49         >=dev-util/pkgconfig-0.12.0
  50         >=dev-util/intltool-0.40
  51         >=sys-devel/gettext-0.17
  52         doc? ( >=dev-util/gtk-doc-1 )"
  53
  54 DOCS="AUTHORS ChangeLog* HACKING NEWS README*"
  55
  56 pkg_setup() {
  57         G2CONF="--enable-default-binary \
  58                 --with-x \
  59                 $(use_with aalib aa) \
  60                 $(use_with alsa) \
  61                 $(use_enable altivec) \
  62                 $(use_with curl libcurl) \
  63                 $(use_with dbus) \
  64                 --without-hal \
  65                 $(use_with gnome gvfs) \
  66                 --without-gnomevfs \
  67                 $(use_with webkit) \
  68                 $(use_with jpeg libjpeg) \
  69                 $(use_with exif libexif) \
  70                 $(use_with lcms) \
  71                 $(use_enable mmx) \
  72                 $(use_with mng libmng) \
  73                 $(use_with pdf poppler) \
  74                 $(use_with png libpng) \
  75                 $(use_enable python) \
  76                 $(use_enable smp mp) \
  77                 $(use_enable sse) \
  78                 $(use_with svg librsvg) \
  79                 $(use_with tiff libtiff) \
  80                 $(use_with wmf)"
  81
  82         if use python; then
  83                 python_set_active_version 2
  84                 python_pkg_setup
  85         fi
  86 }
  87
  88 src_prepare() {
  89         # security fixes from upstream, see
  90         # https://bugzilla.gnome.org/show_bug.cgi?id=639203
  91         epatch "${FILESDIR}"/gimp-CVE-2010-4540-to-4543.diff
  92
  93         # fixes for libpng 1.5 (incomplete), see
  94         # https://bugzilla.gnome.org/show_bug.cgi?id=640409
  95         epatch "${FILESDIR}"/gimp-libpng15-v2.diff
  96
  97         echo '#!/bin/sh' > py-compile
  98         gnome2_src_prepare
  99 }
 100
 101 src_install() {
 102         gnome2_src_install
 103
 104         if use python; then
 105                 python_convert_shebangs -r $(python_get_version) "${ED}"
 106                 python_need_rebuild
 107         fi
 108 }
 109
 110 pkg_postinst() {
 111         gnome2_pkg_postinst
 112
 113         use python && python_mod_optimize /usr/$(get_libdir)/gimp/2.0/python \
 114                 /usr/$(get_libdir)/gimp/2.0/plug-ins
 115 }
 116
 117 pkg_postrm() {
 118         gnome2_pkg_postrm
 119
 120         use python && python_mod_cleanup /usr/$(get_libdir)/gimp/2.0/python \
 121                 /usr/$(get_libdir)/gimp/2.0/plug-ins
 122 }
 123