net-p2p/freenet/freenet-0.7.5_p1437.ebuild

   1 # Copyright 1999-2011 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/net-p2p/freenet/freenet-0.7.5_p1389.ebuild,v 1.1 2011/07/31 18:45:48 tommy Exp $
   4
   5 EAPI="2"
   6 DATE=20121030
   7 JAVA_PKG_IUSE="doc source"
   8
   9 inherit eutils java-pkg-2 java-ant-2 multilib
  10
  11 DESCRIPTION="An encrypted network without censorship"
  12 HOMEPAGE="http://www.freenetproject.org/"
  13 SRC_URI="http://github.com/${PN}/fred-official/zipball/build0${PV#*p} -> ${P}.zip
  14         mirror://gentoo/seednodes-${DATE}.fref.bz2
  15         mirror://gentoo/freenet-ant-1.7.1.jar"
  16
  17 LICENSE="as-is GPL-2"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE="freemail test"
  21
  22 CDEPEND="freemail? ( dev-java/bcprov )
  23         dev-java/commons-compress
  24         dev-db/db-je:3.3
  25         dev-java/fec
  26         dev-java/java-service-wrapper
  27         dev-java/db4o-jdk11
  28         dev-java/db4o-jdk12
  29         dev-java/db4o-jdk5
  30         dev-java/jbitcollider-core
  31         dev-java/lzma
  32         dev-java/lzmajio
  33         dev-java/mersennetwister"
  34 DEPEND="app-arch/unzip
  35         >=virtual/jdk-1.6
  36         ${CDEPEND}
  37         test? ( dev-java/junit
  38                 dev-java/ant-junit )
  39         dev-java/ant-core"
  40 RDEPEND=">=virtual/jre-1.6
  41         net-libs/nativebiginteger
  42         ${CDEPEND}"
  43 PDEPEND="net-libs/NativeThread"
  44
  45 EANT_BUILD_TARGET="package"
  46 EANT_TEST_TARGET="unit"
  47 EANT_BUILD_XML="build-clean.xml"
  48 EANT_GENTOO_CLASSPATH="commons-compress db4o-jdk5 db4o-jdk12 db4o-jdk11 db-je-3.3 fec java-service-wrapper jbitcollider-core lzma lzmajio mersennetwister"
  49 EANT_EXTRA_ARGS="-Dsuppress.gjs=true -Dlib.contrib.present=true -Dlib.junit.present=true"
  50 export EANT_EXTRA_ARGS+=" -Dtest.skip=true"
  51
  52 pkg_setup() {
  53         has_version dev-java/icedtea[cacao] && {
  54                 ewarn "dev-java/icedtea was built with cacao USE flag."
  55                 ewarn "freenet may compile with it, but it will refuse to run."
  56                 ewarn "Please remerge dev-java/icedtea without cacao USE flag,"
  57                 ewarn "if you plan to use it for running freenet."
  58         }
  59         java-pkg-2_pkg_setup
  60         enewgroup freenet
  61         enewuser freenet -1 -1 /var/freenet freenet
  62 }
  63
  64 src_unpack() {
  65         unpack ${P}.zip seednodes-${DATE}.fref.bz2
  66         mv "${WORKDIR}"/freenet-fred-* "${S}"
  67 }
  68
  69 src_prepare() {
  70         cp "${FILESDIR}"/freenet-0.7.5_p1389-wrapper.conf freenet-wrapper.conf || die
  71         cp "${FILESDIR}"/run.sh-20090501 run.sh || die
  72         epatch "${FILESDIR}"/0.7.5_p1302-ext.patch \
  73                 "${FILESDIR}"/freenet-0.7.5_p1384-nativebiginteger-no-nativedoublevalue.patch
  74
  75         sed -i -e "s:=/usr/lib:=/usr/$(get_libdir):g" \
  76                 freenet-wrapper.conf || die "sed failed"
  77
  78         echo "wrapper.java.classpath.1=/usr/share/freenet/lib/freenet.jar" >> freenet-wrapper.conf
  79
  80         local i=2 pkg jars jar
  81         for pkg in ${EANT_GENTOO_CLASSPATH} ; do
  82                 jars="$(java-pkg_getjars ${pkg})"
  83                 for jar in ${jars} ; do
  84                         echo "wrapper.java.classpath.$((i++))=${jar}" >> freenet-wrapper.conf
  85                 done
  86         done
  87         echo "wrapper.java.classpath.$((i++))=/usr/share/freenet/lib/ant.jar" >> freenet-wrapper.conf
  88
  89         if use freemail ; then
  90                 jars="$(java-pkg_getjars bcprov)"
  91                 for jar in ${jars} ; do
  92                         echo "wrapper.java.classpath.$((i++))=${jar}" >> freenet-wrapper.conf
  93                 done
  94         fi
  95
  96         java-ant_rewrite-classpath "${EANT_BUILD_XML}"
  97         java-pkg-2_src_prepare
  98         cp "${DISTDIR}"/freenet-ant-1.7.1.jar lib/ant.jar || die
  99 }
 100
 101 src_test() {
 102         java-pkg_jar-from --into lib fec
 103         java-pkg_jar-from --into lib java-service-wrapper
 104         java-pkg_jar-from --into lib mersennetwister
 105         java-pkg_jar-from --into lib lzma
 106         java-pkg_jar-from --into lib db4o-jdk5
 107         java-pkg_jar-from --into lib db4o-jdk12
 108         java-pkg_jar-from --into lib db4o-jdk11
 109         export EANT_EXTRA_ARGS+=" -Dtest.skip=false"
 110         java-pkg-2_src_test
 111 }
 112
 113 src_install() {
 114         java-pkg_dojar dist/freenet.jar
 115         java-pkg_newjar "${DISTDIR}"/freenet-ant-1.7.1.jar ant.jar
 116         if has_version =sys-apps/baselayout-2*; then
 117                 doinitd "${FILESDIR}"/freenet
 118         else
 119                 newinitd "${FILESDIR}"/freenet.old freenet
 120         fi
 121         dodoc AUTHORS README || die
 122         insinto /etc
 123         doins freenet-wrapper.conf || die
 124         insinto /var/freenet
 125         doins run.sh || die
 126         newins "${WORKDIR}"/seednodes-${DATE}.fref seednodes.fref || die
 127         fperms +x /var/freenet/run.sh
 128         dosym java-service-wrapper/libwrapper.so /usr/$(get_libdir)/libwrapper.so
 129         use doc && java-pkg_dojavadoc javadoc
 130         use source && java-pkg_dosrc src
 131 }
 132
 133 pkg_postinst() {
 134         elog " "
 135         elog "1. Start freenet with /etc/init.d/freenet start."
 136         elog "2. Open localhost:8888 in your browser for the web interface."
 137         #workaround for previously existing freenet user
 138         [[ $(stat --format="%U" /var/freenet) == "freenet" ]] || chown \
 139                 freenet:freenet /var/freenet
 140 }
 141
 142 pkg_postrm() {
 143         if ! [[ -e /usr/share/freenet/lib/freenet.jar ]] ; then
 144                 elog " "
 145                 elog "If you dont want to use freenet any more"
 146                 elog "and dont want to keep your identity/other stuff"
 147                 elog "remember to do 'rm -rf /var/freenet' to remove everything"
 148         fi
 149 }