configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[13])
  14 m4_define([VERSION_MICRO],[0])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl or https://github.com/NLnetLabs/unbound/issues, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=9
  21 LIBUNBOUND_REVISION=11
  22 LIBUNBOUND_AGE=1
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75 # 1.6.4 had 7:3:5
  76 # 1.6.5 had 7:4:5
  77 # 1.6.6 had 7:5:5
  78 # 1.6.7 had 7:6:5
  79 # 1.6.8 had 7:7:5
  80 # 1.7.0 had 7:8:5
  81 # 1.7.1 had 7:9:5
  82 # 1.7.2 had 7:10:5
  83 # 1.7.3 had 7:11:5
  84 # 1.8.0 had 8:0:0 # changes the event callback function signature
  85 # 1.8.1 had 8:1:0
  86 # 1.8.2 had 8:2:0
  87 # 1.8.3 had 8:3:0
  88 # 1.9.0 had 9:0:1 # add ub_ctx_set_tls
  89 # 1.9.1 had 9:1:1
  90 # 1.9.2 had 9:2:1
  91 # 1.9.3 had 9:3:1
  92 # 1.9.4 had 9:4:1
  93 # 1.9.5 had 9:5:1
  94 # 1.9.6 had 9:6:1
  95 # 1.10.0 had 9:7:1
  96 # 1.10.1 had 9:8:1
  97 # 1.11.0 had 9:9:1
  98 # 1.12.0 had 9:10:1
  99 # 1.13.0 had 9:11:1
 100
 101 #   Current  -- the number of the binary API that we're implementing
 102 #   Revision -- which iteration of the implementation of the binary
 103 #               API are we supplying?
 104 #   Age      -- How many previous binary API versions do we also
 105 #               support?
 106 #
 107 # If we release a new version that does not change the binary API,
 108 # increment Revision.
 109 #
 110 # If we release a new version that changes the binary API, but does
 111 # not break programs compiled against the old binary API, increment
 112 # Current and Age.  Set Revision to 0, since this is the first
 113 # implementation of the new API.
 114 #
 115 # Otherwise, we're changing the binary API and breaking backward
 116 # compatibility with old binaries.  Increment Current.  Set Age to 0,
 117 # since we're backward compatible with no previous APIs.  Set Revision
 118 # to 0 too.
 119 AC_SUBST(LIBUNBOUND_CURRENT)
 120 AC_SUBST(LIBUNBOUND_REVISION)
 121 AC_SUBST(LIBUNBOUND_AGE)
 122
 123
 124 cmdln="`echo $@ | sed -e 's/\\\\/\\\\\\\\/g' | sed -e 's/"/\\\\"/'g`"
 125 AC_DEFINE_UNQUOTED(CONFCMDLINE, ["$cmdln"], [Command line arguments used with configure])
 126
 127 CFLAGS="$CFLAGS"
 128 AC_AIX
 129 if test "$ac_cv_header_minix_config_h" = "yes"; then
 130         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 131 fi
 132
 133 dnl
 134 dnl By default set prefix to /usr/local
 135 dnl
 136 case "$prefix" in
 137         NONE)
 138                 prefix="/usr/local"
 139         ;;
 140 esac
 141 case "$exec_prefix" in
 142         NONE)
 143                 exec_prefix="$prefix"
 144         ;;
 145 esac
 146
 147 # are we on MinGW?
 148 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 149 else
 150         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 151         else on_mingw="no"; fi
 152 fi
 153
 154 #
 155 # Determine configuration file
 156 # the eval is to evaluate shell expansion twice
 157 UNBOUND_SBIN_DIR=`eval echo "${sbindir}"`
 158 AC_SUBST(UNBOUND_SBIN_DIR)
 159 UNBOUND_SYSCONF_DIR=`eval echo "${sysconfdir}"`
 160 AC_SUBST(UNBOUND_SYSCONF_DIR)
 161 UNBOUND_LOCALSTATE_DIR=`eval echo "${localstatedir}"`
 162 AC_SUBST(UNBOUND_LOCALSTATE_DIR)
 163 if test $on_mingw = "no"; then
 164   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 165 else
 166   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 167 fi
 168 AC_ARG_WITH([conf_file],
 169         AC_HELP_STRING([--with-conf-file=path],
 170         [Pathname to the Unbound configuration file]),
 171         [ub_conf_file="$withval"])
 172 AC_SUBST(ub_conf_file)
 173 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 174 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 175 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 176 AC_SUBST(ub_conf_dir)
 177
 178 # Determine run, chroot directory and pidfile locations
 179 AC_ARG_WITH(run-dir,
 180     AC_HELP_STRING([--with-run-dir=path],
 181     [set default directory to chdir to (by default dir part of cfg file)]),
 182     UNBOUND_RUN_DIR="$withval",
 183 if test $on_mingw = no; then
 184     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 185 else
 186     UNBOUND_RUN_DIR=""
 187 fi
 188 )
 189 AC_SUBST(UNBOUND_RUN_DIR)
 190 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 191 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 192
 193 AC_ARG_WITH(chroot-dir,
 194     AC_HELP_STRING([--with-chroot-dir=path],
 195     [set default directory to chroot to (by default same as run-dir)]),
 196     UNBOUND_CHROOT_DIR="$withval",
 197 if test $on_mingw = no; then
 198     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 199 else
 200     UNBOUND_CHROOT_DIR=""
 201 fi
 202 )
 203 AC_SUBST(UNBOUND_CHROOT_DIR)
 204 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 205 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 206
 207 AC_ARG_WITH(share-dir,
 208     AC_HELP_STRING([--with-share-dir=path],
 209     [set default directory with shared data (by default same as share/unbound)]),
 210     UNBOUND_SHARE_DIR="$withval",
 211     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 212 AC_SUBST(UNBOUND_SHARE_DIR)
 213 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 214
 215 AC_ARG_WITH(pidfile,
 216     AC_HELP_STRING([--with-pidfile=filename],
 217     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 218     UNBOUND_PIDFILE="$withval",
 219 if test $on_mingw = no; then
 220     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 221 else
 222     UNBOUND_PIDFILE=""
 223 fi
 224 )
 225 AC_SUBST(UNBOUND_PIDFILE)
 226 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 227 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 228
 229 AC_ARG_WITH(rootkey-file,
 230     AC_HELP_STRING([--with-rootkey-file=filename],
 231     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 232     UNBOUND_ROOTKEY_FILE="$withval",
 233 if test $on_mingw = no; then
 234     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 235 else
 236     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 237 fi
 238 )
 239 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 240 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 241 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 242
 243 AC_ARG_WITH(rootcert-file,
 244     AC_HELP_STRING([--with-rootcert-file=filename],
 245     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 246     UNBOUND_ROOTCERT_FILE="$withval",
 247 if test $on_mingw = no; then
 248     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 249 else
 250     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 251 fi
 252 )
 253 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 254 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 255 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 256
 257 AC_ARG_WITH(username,
 258     AC_HELP_STRING([--with-username=user],
 259     [set default user that unbound changes to (default user is unbound)]),
 260     UNBOUND_USERNAME="$withval",
 261     UNBOUND_USERNAME="unbound")
 262 AC_SUBST(UNBOUND_USERNAME)
 263 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 264
 265 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 266 ACX_RSRC_VERSION(wnvs)
 267 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 268
 269 # Checks for typedefs, structures, and compiler characteristics.
 270 AC_C_CONST
 271 AC_LANG_C
 272 # allow user to override the -g -O2 flags.
 273 default_cflags=no
 274 if test "x$CFLAGS" = "x" ; then
 275 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 276 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 277 default_cflags=yes
 278 fi
 279 AC_PROG_CC
 280 ACX_DEPFLAG
 281 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 282
 283 # debug mode flags warnings
 284 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 285 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 286 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 287 else debug_enabled="$enable_checking"; fi
 288 AC_SUBST(debug_enabled)
 289 case "$debug_enabled" in
 290         yes)
 291                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 292                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 293                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 294                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 295                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 296                 ;;
 297         no|*)
 298                 # nothing to do.
 299                 ;;
 300 esac
 301 if test "$default_cflags" = "yes"; then
 302         # only when CFLAGS was "" at the start, if the users wants to
 303         # override we shouldn't add default cflags, because they wouldn't
 304         # be able to turn off these options and set the CFLAGS wanted.
 305         ACX_CHECK_FLTO
 306         ACX_CHECK_PIE
 307         ACX_CHECK_RELRO_NOW
 308 fi
 309
 310 AC_C_INLINE
 311 ACX_CHECK_FORMAT_ATTRIBUTE
 312 ACX_CHECK_UNUSED_ATTRIBUTE
 313
 314 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 315 [AC_REQUIRE([AC_PROG_CC])
 316 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 317 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 318 [ac_cv_c_weak_attribute=no
 319 AC_TRY_COMPILE(
 320 [ #include <stdio.h>
 321 __attribute__((weak)) void f(int x) { printf("%d", x); }
 322 ], [
 323    f(1);
 324 ],
 325 [ac_cv_c_weak_attribute="yes"],
 326 [ac_cv_c_weak_attribute="no"])
 327 ])
 328
 329 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 330 if test $ac_cv_c_weak_attribute = yes; then
 331   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 332   AC_DEFINE(ATTR_WEAK, [__attribute__((weak))], [apply the weak attribute to a symbol])
 333 fi
 334 ])dnl End of CHECK_WEAK_ATTRIBUTE
 335
 336 CHECK_WEAK_ATTRIBUTE
 337
 338 AC_DEFUN([CHECK_NORETURN_ATTRIBUTE],
 339 [AC_REQUIRE([AC_PROG_CC])
 340 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "noreturn" attribute)
 341 AC_CACHE_VAL(ac_cv_c_noreturn_attribute,
 342 [ac_cv_c_noreturn_attribute=no
 343 AC_TRY_COMPILE(
 344 [ #include <stdio.h>
 345 __attribute__((noreturn)) void f(int x) { printf("%d", x); }
 346 ], [
 347    f(1);
 348 ],
 349 [ac_cv_c_noreturn_attribute="yes"],
 350 [ac_cv_c_noreturn_attribute="no"])
 351 ])
 352
 353 AC_MSG_RESULT($ac_cv_c_noreturn_attribute)
 354 if test $ac_cv_c_noreturn_attribute = yes; then
 355   AC_DEFINE(HAVE_ATTR_NORETURN, 1, [Whether the C compiler accepts the "noreturn" attribute])
 356   AC_DEFINE(ATTR_NORETURN, [__attribute__((__noreturn__))], [apply the noreturn attribute to a function that exits the program])
 357 fi
 358 ])dnl End of CHECK_NORETURN_ATTRIBUTE
 359
 360 CHECK_NORETURN_ATTRIBUTE
 361
 362 if test "$srcdir" != "."; then
 363         CPPFLAGS="$CPPFLAGS -I$srcdir"
 364 fi
 365
 366 AC_DEFUN([ACX_YYLEX_DESTROY], [
 367         AC_MSG_CHECKING([for yylex_destroy])
 368         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 369                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 370                 AC_MSG_RESULT(yes)
 371         else AC_MSG_RESULT(no);
 372                 LEX=":"
 373         fi
 374 ])
 375
 376 AC_DEFUN([ACX_YYLEX_OPTION], [
 377         AC_MSG_CHECKING([for lex %option])
 378         if cat <<EOF | $LEX -t 2>&1 | grep yy_delete_buffer >/dev/null 2>&1; then
 379 %option nounput
 380 %%
 381 EOF
 382                 AC_MSG_RESULT(yes)
 383         else AC_MSG_RESULT(no);
 384                 LEX=":"
 385         fi
 386 ])
 387
 388 AC_PROG_LEX
 389 if test "$LEX" != "" -a "$LEX" != ":"; then
 390 ACX_YYLEX_DESTROY
 391 fi
 392 if test "$LEX" != "" -a "$LEX" != ":"; then
 393 ACX_YYLEX_OPTION
 394 fi
 395 AC_PROG_YACC
 396 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 397 AC_CHECK_TOOL(STRIP, strip)
 398 ACX_LIBTOOL_C_ONLY
 399
 400 PKG_PROG_PKG_CONFIG
 401
 402 # Checks for header files.
 403 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/select.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/endian.h libkern/OSByteOrder.h sys/ipc.h sys/shm.h ifaddrs.h],,, [AC_INCLUDES_DEFAULT])
 404 # net/if.h portability for Darwin see:
 405 # https://www.gnu.org/software/autoconf/manual/autoconf-2.69/html_node/Header-Portability.html
 406 AC_CHECK_HEADERS([net/if.h],,, [
 407 #include <stdio.h>
 408 #ifdef STDC_HEADERS
 409 # include <stdlib.h>
 410 # include <stddef.h>
 411 #else
 412 # ifdef HAVE_STDLIB_H
 413 #  include <stdlib.h>
 414 # endif
 415 #endif
 416 #ifdef HAVE_SYS_SOCKET_H
 417 # include <sys/socket.h>
 418 #endif
 419 ])
 420
 421 # Check for Apple header. This uncovers TARGET_OS_IPHONE, TARGET_OS_TV or TARGET_OS_WATCH
 422 AC_CHECK_HEADERS([TargetConditionals.h])
 423
 424 # check for types.
 425 # Using own tests for int64* because autoconf builtin only give 32bit.
 426 AC_CHECK_TYPE(int8_t, signed char)
 427 AC_CHECK_TYPE(int16_t, short)
 428 AC_CHECK_TYPE(int32_t, int)
 429 AC_CHECK_TYPE(int64_t, long long)
 430 AC_CHECK_TYPE(uint8_t, unsigned char)
 431 AC_CHECK_TYPE(uint16_t, unsigned short)
 432 AC_CHECK_TYPE(uint32_t, unsigned int)
 433 AC_CHECK_TYPE(uint64_t, unsigned long long)
 434 AC_TYPE_SIZE_T
 435 AC_CHECK_TYPE(ssize_t, int)
 436 AC_TYPE_UID_T
 437 AC_TYPE_PID_T
 438 AC_TYPE_OFF_T
 439 ACX_TYPE_U_CHAR
 440 ACX_TYPE_RLIM_T
 441 ACX_TYPE_SOCKLEN_T
 442 ACX_TYPE_IN_ADDR_T
 443 ACX_TYPE_IN_PORT_T
 444 ACX_CHECK_MEMCMP_SIGNED
 445
 446 AC_CHECK_SIZEOF(time_t,,[
 447 AC_INCLUDES_DEFAULT
 448 #ifdef TIME_WITH_SYS_TIME
 449 # include <sys/time.h>
 450 # include <time.h>
 451 #else
 452 # ifdef HAVE_SYS_TIME_H
 453 #  include <sys/time.h>
 454 # else
 455 #  include <time.h>
 456 # endif
 457 #endif
 458 ])
 459 AC_CHECK_SIZEOF(size_t)
 460
 461 # add option to disable the evil rpath
 462 ACX_ARG_RPATH
 463 AC_SUBST(RUNTIME_PATH)
 464
 465 # check to see if libraries are needed for these functions.
 466 AC_SEARCH_LIBS([inet_pton], [nsl])
 467 AC_SEARCH_LIBS([socket], [socket])
 468
 469 # check wether strptime also works
 470 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 471 [AC_REQUIRE([AC_PROG_CC])
 472 AC_MSG_CHECKING(whether strptime works)
 473 if test c${cross_compiling} = cno; then
 474 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 475 #define _XOPEN_SOURCE 600
 476 #include <time.h>
 477 int main(void) { struct tm tm; char *res;
 478 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 479 if (!res) return 2;
 480 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 481 if (!res) return 1; return 0; }
 482 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 483 else
 484 eval "ac_cv_c_strptime_works=maybe"
 485 fi
 486 AC_MSG_RESULT($ac_cv_c_strptime_works)
 487 if test $ac_cv_c_strptime_works = no; then
 488 AC_LIBOBJ(strptime)
 489 else
 490 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 491 fi
 492 ])dnl
 493
 494 # check some functions of the OS before linking libs (while still runnable).
 495 AC_FUNC_CHOWN
 496 AC_FUNC_FORK
 497 AC_TYPE_SIGNAL
 498 AC_FUNC_FSEEKO
 499 ACX_SYS_LARGEFILE
 500 ACX_CHECK_NONBLOCKING_BROKEN
 501 ACX_MKDIR_ONE_ARG
 502 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 503
 504 # check if we can use SO_REUSEPORT
 505 if echo "$host" | $GREP -i -e linux -e dragonfly >/dev/null; then
 506         AC_DEFINE(REUSEPORT_DEFAULT, 1, [if REUSEPORT is enabled by default])
 507 else
 508         AC_DEFINE(REUSEPORT_DEFAULT, 0, [if REUSEPORT is enabled by default])
 509 fi
 510
 511 # Include systemd.m4 - begin
 512 sinclude(systemd.m4)
 513 # Include systemd.m4 - end
 514
 515 # set memory allocation checking if requested
 516 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 517         [ enable to memory allocation statistics, for debug purposes ]),
 518         , )
 519 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 520         [ enable for lightweight alloc assertions, for debug purposes ]),
 521         , )
 522 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 523         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 524         , )
 525 if test x_$enable_alloc_nonregional = x_yes; then
 526         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 527 fi
 528 if test x_$enable_alloc_checks = x_yes; then
 529         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 530         SLDNS_ALLOCCHECK_EXTRA_OBJ="alloc.lo log.lo"
 531         AC_SUBST(SLDNS_ALLOCCHECK_EXTRA_OBJ)
 532         ASYNCLOOK_ALLOCCHECK_EXTRA_OBJ="alloc.lo"
 533         AC_SUBST(ASYNCLOOK_ALLOCCHECK_EXTRA_OBJ)
 534 else
 535         if test x_$enable_alloc_lite = x_yes; then
 536                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 537         else
 538                 ACX_FUNC_MALLOC([unbound])
 539         fi
 540 fi
 541
 542 # check windows threads (we use them, not pthreads, on windows).
 543 if test "$on_mingw" = "yes"; then
 544 # check windows threads
 545         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 546         AC_MSG_CHECKING([for CreateThread])
 547         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 548 #ifdef HAVE_WINDOWS_H
 549 #include <windows.h>
 550 #endif
 551 ], [
 552         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 553 ])],
 554         AC_MSG_RESULT(yes)
 555         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 556 ,
 557         AC_MSG_RESULT(no)
 558 )
 559
 560 else
 561 # not on mingw, check thread libraries.
 562
 563 # check for thread library.
 564 # check this first, so that the pthread lib does not get linked in via
 565 # libssl or libpython, and thus distorts the tests, and we end up using
 566 # the non-threadsafe C libraries.
 567 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 568  [use pthreads library, or --without-pthreads to disable threading support.]),
 569  [ ],[ withval="yes" ])
 570 ub_have_pthreads=no
 571 if test x_$withval != x_no; then
 572         AX_PTHREAD([
 573                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 574                 if test -n "$PTHREAD_LIBS"; then
 575                   LIBS="$PTHREAD_LIBS $LIBS"
 576                 fi
 577                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 578                 CC="$PTHREAD_CC"
 579                 ub_have_pthreads=yes
 580                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 581
 582                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 583                 AC_MSG_CHECKING([if -pthread unused during linking])
 584                 # catch clang warning 'argument unused during compilation'
 585                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 586 [[
 587 int main(void) {return 0;}
 588 ]])])
 589                 pthread_unused="yes"
 590                 # first compile
 591                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 592                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 593                 if test $? = 0; then
 594                         # then link
 595                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 596                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 597                         if test $? -ne 0; then
 598                                 AC_MSG_RESULT(yes)
 599                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 600                                 PTHREAD_CFLAGS_ONLY="-pthread"
 601                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 602                         else
 603                                 AC_MSG_RESULT(no)
 604                         fi
 605                 else
 606                         AC_MSG_RESULT(no)
 607                 fi # endif cc successful
 608                 rm -f conftest conftest.c conftest.o
 609                 fi # endif -pthread in CFLAGS
 610
 611                 ])
 612 fi
 613
 614 # check solaris thread library
 615 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 616         [use solaris native thread library.]), [ ],[ withval="no" ])
 617 ub_have_sol_threads=no
 618 if test x_$withval != x_no; then
 619         if test x_$ub_have_pthreads != x_no; then
 620             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 621         else
 622         AC_SEARCH_LIBS(thr_create, [thread],
 623         [
 624                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 625
 626                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 627                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 628                 ub_have_sol_threads=yes
 629         ] , [
 630                 AC_ERROR([no solaris threads found.])
 631         ])
 632         fi
 633 fi
 634
 635 fi # end of non-mingw check of thread libraries
 636
 637 # Check for SYSLOG_FACILITY
 638 AC_ARG_WITH(syslog-facility, AC_HELP_STRING([--with-syslog-facility=LOCAL0 - LOCAL7], [ set SYSLOG_FACILITY, default DAEMON ]),
 639         [ UNBOUND_SYSLOG_FACILITY="$withval" ], [])
 640 case "${UNBOUND_SYSLOG_FACILITY}" in
 641
 642   LOCAL[[0-7]]) UNBOUND_SYSLOG_FACILITY="LOG_${UNBOUND_SYSLOG_FACILITY}" ;;
 643
 644            *) UNBOUND_SYSLOG_FACILITY="LOG_DAEMON" ;;
 645
 646 esac
 647 AC_DEFINE_UNQUOTED(UB_SYSLOG_FACILITY,${UNBOUND_SYSLOG_FACILITY},[the SYSLOG_FACILITY to use, default LOG_DAEMON])
 648
 649 # Check for dynamic library module
 650 AC_ARG_WITH(dynlibmodule,
 651    AC_HELP_STRING([--with-dynlibmodule],
 652    [build dynamic library module, or --without-dynlibmodule to disable it. (default=no)]),
 653    [], [ withval="no" ])
 654
 655 if test x_$withval != x_no; then
 656   AC_DEFINE(WITH_DYNLIBMODULE, 1, [Define if you want dynlib module.])
 657   WITH_DYNLIBMODULE=yes
 658   AC_SUBST(WITH_DYNLIBMODULE)
 659   DYNLIBMOD_OBJ="dynlibmod.lo"
 660   AC_SUBST(DYNLIBMOD_OBJ)
 661   DYNLIBMOD_HEADER='$(srcdir)/dynlibmod/dynlibmod.h'
 662   AC_SUBST(DYNLIBMOD_HEADER)
 663   if test $on_mingw = "no"; then
 664     DYNLIBMOD_EXTRALIBS="-ldl -export-dynamic"
 665   else
 666     DYNLIBMOD_EXTRALIBS="-Wl,--export-all-symbols,--out-implib,libunbound.a"
 667   fi
 668   AC_SUBST(DYNLIBMOD_EXTRALIBS)
 669 fi
 670
 671 # Check for PyUnbound
 672 AC_ARG_WITH(pyunbound,
 673    AC_HELP_STRING([--with-pyunbound],
 674    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 675    [], [ withval="no" ])
 676
 677 ub_test_python=no
 678 ub_with_pyunbound=no
 679 if test x_$withval != x_no; then
 680    ub_with_pyunbound=yes
 681    ub_test_python=yes
 682 fi
 683
 684 # Check for Python module
 685 AC_ARG_WITH(pythonmodule,
 686    AC_HELP_STRING([--with-pythonmodule],
 687    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 688    [], [ withval="no" ])
 689
 690 ub_with_pythonmod=no
 691 if test x_$withval != x_no; then
 692    ub_with_pythonmod=yes
 693    ub_test_python=yes
 694 fi
 695
 696 # Check for Python & SWIG only on PyUnbound or PyModule
 697 if test x_$ub_test_python != x_no; then
 698
 699    # Check for Python
 700    ub_have_python=no
 701    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 702    AC_PYTHON_DEVEL
 703    if test ! -z "$PYTHON_VERSION"; then
 704         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 705                 AC_ERROR([Python version >= 2.4.0 is required])
 706         fi
 707
 708       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 709       AC_SUBST(PY_MAJOR_VERSION)
 710       # Have Python
 711       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 712       if test -n "$LIBS"; then
 713         LIBS="$PYTHON_LDFLAGS $LIBS"
 714       else
 715         LIBS="$PYTHON_LDFLAGS"
 716       fi
 717       if test -n "$CPPFLAGS"; then
 718         CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 719       else
 720         CPPFLAGS="$PYTHON_CPPFLAGS"
 721       fi
 722       if test "$PYTHON_LIBDIR" != "/usr/lib" -a "$PYTHON_LIBDIR" != "" -a "$PYTHON_LIBDIR" != "/usr/lib64"; then
 723         ACX_RUNTIME_PATH_ADD([$PYTHON_LIBDIR])
 724       fi
 725       ub_have_python=yes
 726       PKG_CHECK_EXISTS(["python${PY_MAJOR_VERSION}"],
 727                        [PC_PY_DEPENDENCY="python${PY_MAJOR_VERSION}"],
 728                        [PC_PY_DEPENDENCY="python"])
 729       AC_SUBST(PC_PY_DEPENDENCY)
 730
 731       # Check for SWIG
 732       ub_have_swig=no
 733       AC_ARG_ENABLE(swig-version-check, AC_HELP_STRING([--disable-swig-version-check], [Disable swig version check to build python modules with older swig even though that is unreliable]))
 734       if test "$enable_swig_version_check" = "yes"; then
 735         AC_PROG_SWIG(2.0.1)
 736       else
 737         AC_PROG_SWIG
 738       fi
 739       AC_MSG_CHECKING(SWIG)
 740       if test ! -x "$SWIG"; then
 741          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 742       else
 743          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 744          AC_SUBST(swig, "$SWIG")
 745          AC_MSG_RESULT(present)
 746
 747          # If have Python & SWIG
 748          # Declare PythonMod
 749          if test x_$ub_with_pythonmod != x_no; then
 750             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 751             WITH_PYTHONMODULE=yes
 752             AC_SUBST(WITH_PYTHONMODULE)
 753             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 754             AC_SUBST(PYTHONMOD_OBJ)
 755             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 756             AC_SUBST(PYTHONMOD_HEADER)
 757             PYTHONMOD_INSTALL=pythonmod-install
 758             AC_SUBST(PYTHONMOD_INSTALL)
 759             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 760             AC_SUBST(PYTHONMOD_UNINSTALL)
 761          fi
 762
 763          # Declare PyUnbound
 764          if test x_$ub_with_pyunbound != x_no; then
 765             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 766             WITH_PYUNBOUND=yes
 767             AC_SUBST(WITH_PYUNBOUND)
 768             PYUNBOUND_OBJ="libunbound_wrap.lo"
 769             AC_SUBST(PYUNBOUND_OBJ)
 770             PYUNBOUND_TARGET="_unbound.la"
 771             AC_SUBST(PYUNBOUND_TARGET)
 772             PYUNBOUND_INSTALL=pyunbound-install
 773             AC_SUBST(PYUNBOUND_INSTALL)
 774             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 775             AC_SUBST(PYUNBOUND_UNINSTALL)
 776          fi
 777       fi
 778    else
 779       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 780       ub_with_pyunbound=no
 781       ub_with_pythonmod=no
 782    fi
 783 fi
 784
 785 if test "`uname`" = "NetBSD"; then
 786         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 787         AC_SUBST(NETBSD_LINTFLAGS)
 788 fi
 789 CONFIG_DATE=`date +%Y%m%d`
 790 AC_SUBST(CONFIG_DATE)
 791
 792 # Checks for libraries.
 793
 794 # libnss
 795 USE_NSS="no"
 796 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 797         [use libnss instead of openssl, installed at path.]),
 798         [
 799         USE_NSS="yes"
 800         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 801         if test "$withval" != "" -a "$withval" != "yes"; then
 802                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 803                 LDFLAGS="$LDFLAGS -L$withval/lib"
 804                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 805                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 806         else
 807                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 808                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 809         fi
 810         LIBS="$LIBS -lnss3 -lnspr4"
 811         SSLLIB=""
 812         PC_CRYPTO_DEPENDENCY="nss nspr"
 813         AC_SUBST(PC_CRYPTO_DEPENDENCY)
 814         ]
 815 )
 816
 817 # libnettle
 818 USE_NETTLE="no"
 819 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 820         [use libnettle as crypto library, installed at path.]),
 821         [
 822         USE_NETTLE="yes"
 823         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 824         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 825         if test "$withval" != "" -a "$withval" != "yes"; then
 826                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 827                 LDFLAGS="$LDFLAGS -L$withval/lib"
 828                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 829         else
 830                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 831         fi
 832         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 833         SSLLIB=""
 834         PC_CRYPTO_DEPENDENCY="hogweed nettle"
 835         AC_SUBST(PC_CRYPTO_DEPENDENCY)
 836         ]
 837 )
 838
 839 # openssl
 840 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 841 ACX_WITH_SSL
 842 ACX_LIB_SSL
 843 SSLLIB="-lssl"
 844
 845 PC_CRYPTO_DEPENDENCY="libcrypto libssl"
 846 AC_SUBST(PC_CRYPTO_DEPENDENCY)
 847
 848 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 849 BAKLIBS="$LIBS"
 850 LIBS="-lssl $LIBS"
 851 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 852 AC_TRY_LINK_FUNC([EVP_sha256], [
 853         AC_MSG_RESULT([no])
 854         LIBS="$BAKLIBS"
 855 ], [
 856         AC_MSG_RESULT([yes])
 857         LIBS="$BAKLIBS"
 858         LIBS="$LIBS -lcrypt32"
 859 ])
 860
 861 AC_MSG_CHECKING([for LibreSSL])
 862 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 863         AC_MSG_RESULT([yes])
 864         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 865         # libressl provides these compat functions, but they may also be
 866         # declared by the OS in libc.  See if they have been declared.
 867         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform])
 868 else
 869         AC_MSG_RESULT([no])
 870 fi
 871 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h openssl/core_names.h],,, [AC_INCLUDES_DEFAULT])
 872 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ENGINE_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1 EVP_DigestVerify EVP_aes_256_cbc EVP_EncryptInit_ex HMAC_Init_ex CRYPTO_THREADID_set_callback EVP_MAC_CTX_set_params])
 873
 874 # these check_funcs need -lssl
 875 BAKLIBS="$LIBS"
 876 LIBS="-lssl $LIBS"
 877 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level SSL_set1_host SSL_get0_peername X509_VERIFY_PARAM_set1_host SSL_CTX_set_ciphersuites SSL_CTX_set_tlsext_ticket_key_evp_cb SSL_CTX_set_alpn_select_cb])
 878 LIBS="$BAKLIBS"
 879
 880 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 881 AC_INCLUDES_DEFAULT
 882 #ifdef HAVE_OPENSSL_ERR_H
 883 #include <openssl/err.h>
 884 #endif
 885
 886 #ifdef HAVE_OPENSSL_RAND_H
 887 #include <openssl/rand.h>
 888 #endif
 889
 890 #ifdef HAVE_OPENSSL_CONF_H
 891 #include <openssl/conf.h>
 892 #endif
 893
 894 #ifdef HAVE_OPENSSL_ENGINE_H
 895 #include <openssl/engine.h>
 896 #endif
 897 #include <openssl/ssl.h>
 898 #include <openssl/evp.h>
 899 ])
 900
 901 if test "$ac_cv_func_HMAC_Init_ex" = "yes"; then
 902 # check function return type.
 903 AC_MSG_CHECKING(the return type of HMAC_Init_ex)
 904 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 905 #ifdef HAVE_OPENSSL_ERR_H
 906 #include <openssl/err.h>
 907 #endif
 908
 909 #ifdef HAVE_OPENSSL_RAND_H
 910 #include <openssl/rand.h>
 911 #endif
 912
 913 #ifdef HAVE_OPENSSL_CONF_H
 914 #include <openssl/conf.h>
 915 #endif
 916
 917 #ifdef HAVE_OPENSSL_ENGINE_H
 918 #include <openssl/engine.h>
 919 #endif
 920 #include <openssl/ssl.h>
 921 #include <openssl/evp.h>
 922 ], [
 923         HMAC_CTX* hmac_ctx = NULL;
 924         void* hmac_key = NULL;
 925         const EVP_MD* digest = NULL;
 926         int x = HMAC_Init_ex(hmac_ctx, hmac_key, 32, digest, NULL);
 927         (void)x;
 928 ])], [
 929         AC_MSG_RESULT(int)
 930 ], [
 931         AC_MSG_RESULT(void)
 932         AC_DEFINE([HMAC_INIT_EX_RETURNS_VOID], 1, [If HMAC_Init_ex() returns void])
 933 ])
 934 fi
 935
 936 fi
 937 AC_SUBST(SSLLIB)
 938
 939 # libbsd
 940 AC_ARG_WITH([libbsd], AC_HELP_STRING([--with-libbsd], [Use portable libbsd functions]), [
 941         AC_CHECK_HEADERS([bsd/string.h bsd/stdlib.h],,, [AC_INCLUDES_DEFAULT])
 942         if test "x$ac_cv_header_bsd_string_h" = xyes -a "x$ac_cv_header_bsd_stdlib_h" = xyes; then
 943                 for func in strlcpy strlcat arc4random arc4random_uniform reallocarray; do
 944                         AC_SEARCH_LIBS([$func], [bsd], [
 945                                 AC_DEFINE(HAVE_LIBBSD, 1, [Use portable libbsd functions])
 946                                 PC_LIBBSD_DEPENDENCY=libbsd
 947                                 AC_SUBST(PC_LIBBSD_DEPENDENCY)
 948                         ])
 949                 done
 950         fi
 951 ])
 952
 953 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 954 case "$enable_sha1" in
 955         no)
 956         ;;
 957         yes|*)
 958         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 959         ;;
 960 esac
 961
 962
 963 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 964 case "$enable_sha2" in
 965         no)
 966         ;;
 967         yes|*)
 968         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 969         ;;
 970 esac
 971
 972 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 973 case "$enable_subnet" in
 974         yes)
 975         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 976         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 977         AC_SUBST(SUBNET_OBJ)
 978         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 979         AC_SUBST(SUBNET_HEADER)
 980         ;;
 981         no|*)
 982         ;;
 983 esac
 984
 985 # check wether gost also works
 986 AC_DEFUN([AC_CHECK_GOST_WORKS],
 987 [AC_REQUIRE([AC_PROG_CC])
 988 AC_MSG_CHECKING([if GOST works])
 989 if test c${cross_compiling} = cno; then
 990 BAKCFLAGS="$CFLAGS"
 991 if test -n "$ssldir"; then
 992         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 993 fi
 994 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 995 #include <string.h>
 996 #include <openssl/ssl.h>
 997 #include <openssl/evp.h>
 998 #include <openssl/engine.h>
 999 #include <openssl/conf.h>
1000 /* routine to load gost (from sldns) */
1001 int load_gost_id(void)
1002 {
1003         static int gost_id = 0;
1004         const EVP_PKEY_ASN1_METHOD* meth;
1005         ENGINE* e;
1006
1007         if(gost_id) return gost_id;
1008
1009         /* see if configuration loaded gost implementation from other engine*/
1010         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
1011         if(meth) {
1012                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
1013                 return gost_id;
1014         }
1015
1016         /* see if engine can be loaded already */
1017         e = ENGINE_by_id("gost");
1018         if(!e) {
1019                 /* load it ourself, in case statically linked */
1020                 ENGINE_load_builtin_engines();
1021                 ENGINE_load_dynamic();
1022                 e = ENGINE_by_id("gost");
1023         }
1024         if(!e) {
1025                 /* no gost engine in openssl */
1026                 return 0;
1027         }
1028         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
1029                 ENGINE_finish(e);
1030                 ENGINE_free(e);
1031                 return 0;
1032         }
1033
1034         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
1035         if(!meth) {
1036                 /* algo not found */
1037                 ENGINE_finish(e);
1038                 ENGINE_free(e);
1039                 return 0;
1040         }
1041         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
1042         return gost_id;
1043 }
1044 int main(void) {
1045         EVP_MD_CTX* ctx;
1046         const EVP_MD* md;
1047         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
1048         const char* str = "Hello world";
1049         const unsigned char check[] = {
1050                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
1051                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
1052                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
1053                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
1054         };
1055         OPENSSL_config(NULL);
1056         (void)load_gost_id();
1057         md = EVP_get_digestbyname("md_gost94");
1058         if(!md) return 1;
1059         memset(digest, 0, sizeof(digest));
1060         ctx = EVP_MD_CTX_create();
1061         if(!ctx) return 2;
1062         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
1063         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
1064         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
1065         /* uncomment to see the hash calculated.
1066                 {int i;
1067                 for(i=0; i<32; i++)
1068                         printf(" %2.2x", (int)digest[i]);
1069                 printf("\n");}
1070         */
1071         if(memcmp(digest, check, sizeof(check)) != 0)
1072                 return 6;
1073         return 0;
1074 }
1075 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
1076 CFLAGS="$BAKCFLAGS"
1077 else
1078 eval "ac_cv_c_gost_works=maybe"
1079 fi
1080 AC_MSG_RESULT($ac_cv_c_gost_works)
1081 ])dnl
1082
1083 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
1084 use_gost="no"
1085 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1086 case "$enable_gost" in
1087         no)
1088         ;;
1089         *)
1090         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
1091         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
1092         AC_CHECK_GOST_WORKS
1093         if test "$ac_cv_c_gost_works" != no; then
1094                 use_gost="yes"
1095                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
1096         fi
1097         ;;
1098 esac
1099 fi dnl !USE_NSS && !USE_NETTLE
1100
1101 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
1102 use_ecdsa="no"
1103 case "$enable_ecdsa" in
1104     no)
1105       ;;
1106     *)
1107       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1108               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
1109               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
1110               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
1111 #include <openssl/evp.h>
1112               ])
1113               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
1114               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
1115               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
1116                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
1117                   AC_MSG_RESULT([no])
1118                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
1119                 else
1120                   AC_MSG_RESULT([yes])
1121                 fi
1122               else
1123                 # not OpenSSL, thus likely LibreSSL, which supports it
1124                 AC_MSG_RESULT([yes])
1125               fi
1126       fi
1127       # we now know we have ECDSA and the required curves.
1128       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
1129       use_ecdsa="yes"
1130       ;;
1131 esac
1132
1133 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
1134 use_dsa="no"
1135 case "$enable_dsa" in
1136     yes)
1137       # detect if DSA is supported, and turn it off if not.
1138       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1139       AC_CHECK_FUNC(DSA_SIG_new, [
1140       AC_CHECK_TYPE(DSA_SIG*, [
1141       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1142       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1143                fi ], [
1144 AC_INCLUDES_DEFAULT
1145 #ifdef HAVE_OPENSSL_ERR_H
1146 #include <openssl/err.h>
1147 #endif
1148
1149 #ifdef HAVE_OPENSSL_RAND_H
1150 #include <openssl/rand.h>
1151 #endif
1152
1153 #ifdef HAVE_OPENSSL_CONF_H
1154 #include <openssl/conf.h>
1155 #endif
1156
1157 #ifdef HAVE_OPENSSL_ENGINE_H
1158 #include <openssl/engine.h>
1159 #endif
1160       ])
1161       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1162                fi ])
1163       else
1164       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1165       fi
1166       ;;
1167     *)
1168       # disable dsa by default, RFC 8624 section 3.1, validators MUST NOT
1169       # support DSA for DNSSEC Validation.
1170       ;;
1171 esac
1172
1173 AC_ARG_ENABLE(ed25519, AC_HELP_STRING([--disable-ed25519], [Disable ED25519 support]))
1174 use_ed25519="no"
1175 case "$enable_ed25519" in
1176     no)
1177       ;;
1178     *)
1179       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1180               AC_CHECK_DECLS([NID_ED25519], [
1181                 use_ed25519="yes"
1182               ], [ if test "x$enable_ed25519" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED25519 and you used --enable-ed25519.])
1183                 fi ], [AC_INCLUDES_DEFAULT
1184 #include <openssl/evp.h>
1185               ])
1186       fi
1187       if test $USE_NETTLE = "yes"; then
1188                 AC_CHECK_HEADERS([nettle/eddsa.h], use_ed25519="yes",, [AC_INCLUDES_DEFAULT])
1189       fi
1190       if test $use_ed25519 = "yes"; then
1191                 AC_DEFINE_UNQUOTED([USE_ED25519], [1], [Define this to enable ED25519 support.])
1192       fi
1193       ;;
1194 esac
1195
1196 AC_ARG_ENABLE(ed448, AC_HELP_STRING([--disable-ed448], [Disable ED448 support]))
1197 use_ed448="no"
1198 case "$enable_ed448" in
1199     no)
1200       ;;
1201     *)
1202       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1203               AC_CHECK_DECLS([NID_ED448], [
1204                 use_ed448="yes"
1205               ], [ if test "x$enable_ed448" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED448 and you used --enable-ed448.])
1206                 fi ], [AC_INCLUDES_DEFAULT
1207 #include <openssl/evp.h>
1208               ])
1209       fi
1210       if test $use_ed448 = "yes"; then
1211                 AC_DEFINE_UNQUOTED([USE_ED448], [1], [Define this to enable ED448 support.])
1212       fi
1213       ;;
1214 esac
1215
1216 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
1217 case "$enable_event_api" in
1218     yes)
1219       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
1220       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
1221       ;;
1222     *)
1223       ;;
1224 esac
1225
1226 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
1227 case "$enable_tfo_client" in
1228         yes)
1229                 case `uname` in
1230                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1231                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1232                                              [AC_INCLUDES_DEFAULT
1233 #include <netinet/tcp.h>
1234 ])
1235                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1236                           ;;
1237                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1238                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1239                                               [AC_INCLUDES_DEFAULT
1240 #include <sys/socket.h>
1241 ])
1242                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1243                           ;;
1244                 esac
1245         ;;
1246         no|*)
1247                 ;;
1248 esac
1249
1250 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
1251 case "$enable_tfo_server" in
1252         yes)
1253               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
1254 #include <netinet/tcp.h>
1255               ])
1256                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
1257                 ;;
1258         no|*)
1259                 ;;
1260 esac
1261
1262 # check for libevent
1263 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
1264     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
1265     [ ],[ with_libevent="no" ])
1266 if test "x_$with_libevent" != x_no; then
1267         AC_DEFINE([USE_LIBEVENT], [1], [Define if you enable libevent])
1268         AC_MSG_CHECKING(for libevent)
1269         if test "x_$with_libevent" = x_ -o "x_$with_libevent" = x_yes; then
1270             with_libevent="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1271         fi
1272         for dir in $with_libevent; do
1273             thedir="$dir"
1274             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
1275                 found_libevent="yes"
1276                                 dnl assume /usr is in default path.
1277                                 if test "$thedir" != "/usr"; then
1278                                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
1279                                 fi
1280                                 break;
1281                     fi
1282         done
1283         if test x_$found_libevent != x_yes; then
1284                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
1285                         # libevent source directory
1286                         AC_MSG_RESULT(found in $thedir)
1287                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
1288                         BAK_LDFLAGS_SET="1"
1289                         BAK_LDFLAGS="$LDFLAGS"
1290                         # remove evdns from linking
1291                         mkdir build >/dev/null 2>&1
1292                         mkdir build/libevent >/dev/null 2>&1
1293                         mkdir build/libevent/.libs >/dev/null 2>&1
1294                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1295                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
1296                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1297                         cp $ev_files_o build/libevent
1298                         cp $ev_files_lo build/libevent
1299                         cp $ev_files_libso build/libevent/.libs
1300                         LATE_LDFLAGS="build/libevent/*.lo -lm"
1301                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
1302                 else
1303             AC_MSG_ERROR([Cannot find the libevent library in $with_libevent
1304 You can restart ./configure --with-libevent=no to use a builtin alternative.
1305 Please note that this alternative is not as capable as libevent when using
1306 large outgoing port ranges.  ])
1307                 fi
1308         else
1309             AC_MSG_RESULT(found in $thedir)
1310             dnl if event2 exists and no event lib in dir itself, use subdir
1311             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1312                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1313                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1314             else
1315                     dnl assume /usr is in default path, do not add "".
1316                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1317                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1318                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1319                     fi
1320             fi
1321         fi
1322         # check for library used by libevent after 1.3c
1323         AC_SEARCH_LIBS([clock_gettime], [rt])
1324
1325         # is the event.h header libev or libevent?
1326         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1327         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1328                 AC_SEARCH_LIBS(event_set, [ev])
1329         ],[
1330                 AC_SEARCH_LIBS(event_set, [event])
1331         ],[AC_INCLUDES_DEFAULT
1332 #include <event.h>
1333         ])
1334         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1335         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1336         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1337         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1338         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1339         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1340         AC_CHECK_FUNCS([event_assign]) # in libevent, for thread-safety
1341         AC_CHECK_DECLS([evsignal_assign], [], [], [AC_INCLUDES_DEFAULT
1342 #ifdef HAVE_EVENT_H
1343 #  include <event.h>
1344 #else
1345 #  include "event2/event.h"
1346 #endif
1347         ])
1348         PC_LIBEVENT_DEPENDENCY="libevent"
1349         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1350         if test -n "$BAK_LDFLAGS_SET"; then
1351                 LDFLAGS="$BAK_LDFLAGS"
1352         fi
1353 else
1354         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1355 fi
1356
1357 # check for libexpat
1358 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1359     [specify explicit path for libexpat.]),
1360     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1361 AC_MSG_CHECKING(for libexpat)
1362 found_libexpat="no"
1363 for dir in $withval ; do
1364             if test -f "$dir/include/expat.h"; then
1365                 found_libexpat="yes"
1366                 dnl assume /usr is in default path.
1367                 if test "$dir" != "/usr"; then
1368                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1369                     LDFLAGS="$LDFLAGS -L$dir/lib"
1370                 fi
1371                 AC_MSG_RESULT(found in $dir)
1372                 break;
1373             fi
1374 done
1375 if test x_$found_libexpat != x_yes; then
1376         AC_ERROR([Could not find libexpat, expat.h])
1377 fi
1378 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1379 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1380 #include <expat.h>
1381 ])
1382
1383 # hiredis (redis C client for cachedb)
1384 AC_ARG_WITH(libhiredis, AC_HELP_STRING([--with-libhiredis=path],
1385     [specify explicit path for libhiredis.]),
1386     [ ],[ withval="no" ])
1387 found_libhiredis="no"
1388 if test x_$withval = x_yes -o x_$withval != x_no; then
1389    AC_MSG_CHECKING(for libhiredis)
1390    if test x_$withval = x_ -o x_$withval = x_yes; then
1391             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1392    fi
1393    for dir in $withval ; do
1394             if test -f "$dir/include/hiredis/hiredis.h"; then
1395                 found_libhiredis="yes"
1396                 dnl assume /usr is in default path.
1397                 if test "$dir" != "/usr"; then
1398                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1399                     LDFLAGS="$LDFLAGS -L$dir/lib"
1400                 fi
1401                 AC_MSG_RESULT(found in $dir)
1402                 AC_DEFINE([USE_REDIS], [1], [Define this to use hiredis client.])
1403                 LIBS="$LIBS -lhiredis"
1404                 break;
1405             fi
1406     done
1407     if test x_$found_libhiredis != x_yes; then
1408         AC_ERROR([Could not find libhiredis, hiredis.h])
1409     fi
1410     AC_CHECK_HEADERS([hiredis/hiredis.h],,, [AC_INCLUDES_DEFAULT])
1411     AC_CHECK_DECLS([redisConnect], [], [], [AC_INCLUDES_DEFAULT
1412     #include <hiredis/hiredis.h>
1413     ])
1414 fi
1415
1416 # nghttp2
1417 AC_ARG_WITH(libnghttp2, AC_HELP_STRING([--with-libnghttp2=path],
1418     [specify explicit path for libnghttp2.]),
1419     [ ],[ withval="no" ])
1420 found_libnghttp2="no"
1421 if test x_$withval = x_yes -o x_$withval != x_no; then
1422    AC_MSG_CHECKING(for libnghttp2)
1423    if test x_$withval = x_ -o x_$withval = x_yes; then
1424             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1425    fi
1426    for dir in $withval ; do
1427             if test -f "$dir/include/nghttp2/nghttp2.h"; then
1428                 found_libnghttp2="yes"
1429                 dnl assume /usr is in default path.
1430                 if test "$dir" != "/usr"; then
1431                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1432                     LDFLAGS="$LDFLAGS -L$dir/lib"
1433                 fi
1434                 AC_MSG_RESULT(found in $dir)
1435                 AC_DEFINE([HAVE_NGHTTP2], [1], [Define this to use nghttp2 client.])
1436                 LIBS="$LIBS -lnghttp2"
1437                 break;
1438             fi
1439     done
1440     if test x_$found_libnghttp2 != x_yes; then
1441         AC_ERROR([Could not find libnghttp2, nghttp2.h])
1442     fi
1443     AC_CHECK_HEADERS([nghttp2/nghttp2.h],,, [AC_INCLUDES_DEFAULT])
1444     AC_CHECK_DECLS([nghttp2_session_server_new], [], [], [AC_INCLUDES_DEFAULT
1445     #include <nghttp2/nghttp2.h>
1446     ])
1447 fi
1448
1449 # set static linking for uninstalled libraries if requested
1450 AC_SUBST(staticexe)
1451 staticexe=""
1452 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1453         [ enable to compile executables statically against (event) uninstalled libs, for debug purposes ]),
1454         , )
1455 if test x_$enable_static_exe = x_yes; then
1456         staticexe="-static"
1457         if test "$on_mingw" = yes; then
1458                 staticexe="-all-static"
1459                 # for static compile, include gdi32 and zlib here.
1460                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1461                         :
1462                 else
1463                         LIBS="$LIBS -lgdi32"
1464                 fi
1465                 LIBS="$LIBS -lz"
1466         fi
1467 fi
1468
1469 # set full static linking if requested
1470 AC_ARG_ENABLE(fully-static, AC_HELP_STRING([--enable-fully-static],
1471         [ enable to compile fully static ]),
1472         , )
1473 if test x_$enable_fully_static = x_yes; then
1474         staticexe="-all-static"
1475         if test "$on_mingw" = yes; then
1476                 # for static compile, include gdi32 and zlib here.
1477                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1478                         :
1479                 else
1480                         LIBS="$LIBS -lgdi32"
1481                 fi
1482                 LIBS="$LIBS -lz"
1483         fi
1484 fi
1485
1486 # set lock checking if requested
1487 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1488         [ enable to check lock and unlock calls, for debug purposes ]),
1489         , )
1490 if test x_$enable_lock_checks = x_yes; then
1491         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1492         CHECKLOCK_OBJ="checklocks.lo"
1493         AC_SUBST(CHECKLOCK_OBJ)
1494 fi
1495
1496 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1497 if test "$USE_WINSOCK" = 1; then
1498         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1499         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1500 #include <windows.h>
1501         ])
1502         AC_CHECK_TOOL(WINDRES, windres)
1503         LIBS="$LIBS -liphlpapi -lcrypt32"
1504         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1505         AC_SUBST(WINAPPS)
1506         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1507         AC_SUBST(WIN_DAEMON_SRC)
1508         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1509         AC_SUBST(WIN_DAEMON_OBJ)
1510         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1511         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1512         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1513         AC_SUBST(WIN_HOST_OBJ_LINK)
1514         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1515         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1516         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1517         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1518         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1519         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1520 fi
1521 if test $ac_cv_func_getaddrinfo = no; then
1522         AC_LIBOBJ([fake-rfc2553])
1523 fi
1524 # check after getaddrinfo for its libraries
1525 ACX_FUNC_IOCTLSOCKET
1526
1527 # see if daemon(3) exists, and if it is deprecated.
1528 AC_CHECK_FUNCS([daemon])
1529 if test $ac_cv_func_daemon = yes; then
1530         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1531 #include <stdlib.h>
1532 ])
1533 fi
1534
1535 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1536 AC_INCLUDES_DEFAULT
1537 #ifdef HAVE_SYS_UN_H
1538 #include <sys/un.h>
1539 #endif
1540 ])
1541 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1542 AC_INCLUDES_DEFAULT
1543 #if HAVE_SYS_PARAM_H
1544 #include <sys/param.h>
1545 #endif
1546
1547 #ifdef HAVE_SYS_SOCKET_H
1548 #include <sys/socket.h>
1549 #endif
1550
1551 #ifdef HAVE_SYS_UIO_H
1552 #include <sys/uio.h>
1553 #endif
1554
1555 #ifdef HAVE_NETINET_IN_H
1556 #include <netinet/in.h>
1557 #endif
1558
1559 #ifdef HAVE_NETINET_TCP_H
1560 #include <netinet/tcp.h>
1561 #endif
1562
1563 #ifdef HAVE_ARPA_INET_H
1564 #include <arpa/inet.h>
1565 #endif
1566
1567 #ifdef HAVE_WINSOCK2_H
1568 #include <winsock2.h>
1569 #endif
1570
1571 #ifdef HAVE_WS2TCPIP_H
1572 #include <ws2tcpip.h>
1573 #endif
1574 ])
1575
1576 AC_MSG_CHECKING([for htobe64])
1577 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1578 #include <stdio.h>
1579 #ifdef HAVE_ENDIAN_H
1580 #  include <endian.h>
1581 #endif
1582 #ifdef HAVE_SYS_ENDIAN_H
1583 #  include <sys/endian.h>
1584 #endif
1585 ], [unsigned long long x = htobe64(0); printf("%u", (unsigned)x);])],
1586   AC_MSG_RESULT(yes)
1587   AC_DEFINE(HAVE_HTOBE64, 1, [If we have htobe64]),
1588   AC_MSG_RESULT(no))
1589
1590 AC_MSG_CHECKING([for be64toh])
1591 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1592 #include <stdio.h>
1593 #ifdef HAVE_ENDIAN_H
1594 #  include <endian.h>
1595 #endif
1596 #ifdef HAVE_SYS_ENDIAN_H
1597 #  include <sys/endian.h>
1598 #endif
1599 ], [unsigned long long x = be64toh(0); printf("%u", (unsigned)x);])],
1600   AC_MSG_RESULT(yes)
1601   AC_DEFINE(HAVE_BE64TOH, 1, [If we have be64toh]),
1602   AC_MSG_RESULT(no))
1603
1604 AC_SEARCH_LIBS([setusercontext], [util])
1605 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget accept4 getifaddrs])
1606 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1607 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1608
1609 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1610 if echo $target_os | grep darwin8 > /dev/null; then
1611         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1612 fi
1613 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1614 AC_INCLUDES_DEFAULT
1615 #ifdef HAVE_NETINET_IN_H
1616 #include <netinet/in.h>
1617 #endif
1618
1619 #ifdef HAVE_NETINET_TCP_H
1620 #include <netinet/tcp.h>
1621 #endif
1622
1623 #ifdef HAVE_ARPA_INET_H
1624 #include <arpa/inet.h>
1625 #endif
1626
1627 #ifdef HAVE_WINSOCK2_H
1628 #include <winsock2.h>
1629 #endif
1630
1631 #ifdef HAVE_WS2TCPIP_H
1632 #include <ws2tcpip.h>
1633 #endif
1634 ])
1635 AC_REPLACE_FUNCS(inet_aton)
1636 AC_REPLACE_FUNCS(inet_pton)
1637 AC_REPLACE_FUNCS(inet_ntop)
1638 AC_REPLACE_FUNCS(snprintf)
1639 # test if snprintf return the proper length
1640 if test "x$ac_cv_func_snprintf" = xyes; then
1641     if test c${cross_compiling} = cno; then
1642         AC_MSG_CHECKING([for correct snprintf return value])
1643         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1644 [[
1645 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1646 ]])], [AC_MSG_RESULT(yes)], [
1647                 AC_MSG_RESULT(no)
1648                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1649                 AC_LIBOBJ(snprintf)
1650           ])
1651     fi
1652 fi
1653 AC_REPLACE_FUNCS(strlcat)
1654 AC_REPLACE_FUNCS(strlcpy)
1655 AC_REPLACE_FUNCS(memmove)
1656 AC_REPLACE_FUNCS(gmtime_r)
1657 AC_REPLACE_FUNCS(isblank)
1658 AC_REPLACE_FUNCS(explicit_bzero)
1659 dnl without CTIME, ARC4-functions and without reallocarray.
1660 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1661 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1662 AC_MSG_CHECKING([for reallocarray])
1663 AC_LINK_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1664 [[
1665 #ifndef _OPENBSD_SOURCE
1666 #define _OPENBSD_SOURCE 1
1667 #endif
1668 #include <stdlib.h>
1669 int main(void) {
1670         void* p = reallocarray(NULL, 10, 100);
1671         free(p);
1672         return 0;
1673 }
1674 ]])], [AC_MSG_RESULT(yes)
1675         AC_DEFINE(HAVE_REALLOCARRAY, 1, [If we have reallocarray(3)])
1676 ], [
1677         AC_MSG_RESULT(no)
1678         AC_LIBOBJ(reallocarray)
1679 ])
1680 AC_CHECK_DECLS([reallocarray])
1681 if test "$USE_NSS" = "no"; then
1682         AC_REPLACE_FUNCS(arc4random)
1683         AC_REPLACE_FUNCS(arc4random_uniform)
1684         if test "$ac_cv_func_arc4random" = "no"; then
1685                 AC_LIBOBJ(arc4_lock)
1686                 AC_CHECK_FUNCS([getentropy],,[
1687                     if test "$USE_WINSOCK" = 1; then
1688                         AC_LIBOBJ(getentropy_win)
1689                     else
1690                         case "$host" in
1691                         Darwin|*darwin*)
1692                                 AC_LIBOBJ(getentropy_osx)
1693                         ;;
1694                         *solaris*|*sunos*|SunOS)
1695                                 AC_LIBOBJ(getentropy_solaris)
1696                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1697                                         AC_CHECK_FUNCS([SHA512_Update],,[
1698                                                 AC_LIBOBJ(sha512)
1699                                         ])
1700                                 ], [AC_INCLUDES_DEFAULT])
1701                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1702                                         # this lib needed for sha2 on solaris
1703                                         LIBS="$LIBS -lmd"
1704                                 fi
1705                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1706                         ;;
1707                         *freebsd*|*FreeBSD)
1708                                 AC_LIBOBJ(getentropy_freebsd)
1709                         ;;
1710                         *linux*|Linux|*)
1711                                 AC_LIBOBJ(getentropy_linux)
1712                                 AC_CHECK_FUNCS([SHA512_Update],,[
1713                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1714                                         AC_LIBOBJ(sha512)
1715                                 ])
1716                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1717                                 AC_CHECK_FUNCS([getauxval])
1718                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1719                         ;;
1720                         esac
1721                     fi
1722                 ])
1723         fi
1724 fi
1725 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1726 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1727 AC_REPLACE_FUNCS(ctime_r)
1728 AC_REPLACE_FUNCS(strsep)
1729
1730 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1731 case "$enable_allsymbols" in
1732         yes)
1733         COMMON_OBJ_ALL_SYMBOLS=""
1734         UBSYMS=""
1735         EXTRALINK="-L. -L.libs -lunbound"
1736         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1737         ;;
1738         no|*)
1739         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1740         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1741         EXTRALINK=""
1742         ;;
1743 esac
1744 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1745 AC_SUBST(EXTRALINK)
1746 AC_SUBST(UBSYMS)
1747 if test x_$enable_lock_checks = x_yes; then
1748         UBSYMS="-export-symbols clubsyms.def"
1749         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1750         echo lock_protect >> clubsyms.def
1751         echo lock_unprotect >> clubsyms.def
1752         echo lock_get_mem >> clubsyms.def
1753         echo checklock_start >> clubsyms.def
1754         echo checklock_stop >> clubsyms.def
1755         echo checklock_lock >> clubsyms.def
1756         echo checklock_unlock >> clubsyms.def
1757         echo checklock_init >> clubsyms.def
1758         echo checklock_thrcreate >> clubsyms.def
1759         echo checklock_thrjoin >> clubsyms.def
1760 fi
1761
1762 # check for dnstap if requested
1763 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1764     [
1765         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1766         AC_SUBST([ENABLE_DNSTAP], [1])
1767
1768         AC_SUBST([opt_dnstap_socket_path])
1769         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1770         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1771             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1772         AC_SUBST(DNSTAP_SOCKET_PATH,["$hdr_dnstap_socket_path"])
1773
1774         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c dnstap/dnstap_fstrm.c dnstap/dtstream.c"])
1775         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo dnstap_fstrm.lo dtstream.lo"])
1776     ],
1777     [
1778         AC_SUBST([ENABLE_DNSTAP], [0])
1779     ]
1780 )
1781
1782 # check for dnscrypt if requested
1783 dnsc_DNSCRYPT([
1784         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1785         AC_SUBST([ENABLE_DNSCRYPT], [1])
1786
1787         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1788         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1789     ],
1790     [
1791         AC_SUBST([ENABLE_DNSCRYPT], [0])
1792     ]
1793 )
1794
1795 # check for cachedb if requested
1796 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1797 # turn on cachedb when hiredis support is enabled.
1798 if test "$found_libhiredis" = "yes"; then enable_cachedb="yes"; fi
1799 case "$enable_cachedb" in
1800     yes)
1801         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1802         ;;
1803     no|*)
1804         # nothing
1805         ;;
1806 esac
1807
1808 # check for ipsecmod if requested
1809 AC_ARG_ENABLE(ipsecmod, AC_HELP_STRING([--enable-ipsecmod], [Enable ipsecmod module that facilitates opportunistic IPsec]))
1810 case "$enable_ipsecmod" in
1811         yes)
1812                 AC_DEFINE([USE_IPSECMOD], [1], [Define to 1 to use ipsecmod support.])
1813                 IPSECMOD_OBJ="ipsecmod.lo ipsecmod-whitelist.lo"
1814                 AC_SUBST(IPSECMOD_OBJ)
1815                 IPSECMOD_HEADER='$(srcdir)/ipsecmod/ipsecmod.h $(srcdir)/ipsecmod/ipsecmod-whitelist.h'
1816                 AC_SUBST(IPSECMOD_HEADER)
1817                 ;;
1818         no|*)
1819                 # nothing
1820                 ;;
1821 esac
1822
1823 # check for ipset if requested
1824 AC_ARG_ENABLE(ipset, AC_HELP_STRING([--enable-ipset], [enable ipset module]))
1825 case "$enable_ipset" in
1826     yes)
1827                 AC_DEFINE([USE_IPSET], [1], [Define to 1 to use ipset support])
1828                 IPSET_SRC="ipset/ipset.c"
1829                 AC_SUBST(IPSET_SRC)
1830                 IPSET_OBJ="ipset.lo"
1831                 AC_SUBST(IPSET_OBJ)
1832
1833                 # mnl
1834                 AC_ARG_WITH(libmnl, AC_HELP_STRING([--with-libmnl=path],
1835                         [specify explicit path for libmnl.]),
1836                         [ ],[ withval="yes" ])
1837                 found_libmnl="no"
1838                 AC_MSG_CHECKING(for libmnl)
1839                 if test x_$withval = x_ -o x_$withval = x_yes; then
1840                         withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1841                 fi
1842                 for dir in $withval ; do
1843                         if test -f "$dir/include/libmnl/libmnl.h"; then
1844                                 found_libmnl="yes"
1845                                 dnl assume /usr is in default path.
1846                                 if test "$dir" != "/usr"; then
1847                                         CPPFLAGS="$CPPFLAGS -I$dir/include"
1848                                         LDFLAGS="$LDFLAGS -L$dir/lib"
1849                                 fi
1850                                 AC_MSG_RESULT(found in $dir)
1851                                 LIBS="$LIBS -lmnl"
1852                                 break;
1853                         fi
1854                 done
1855                 if test x_$found_libmnl != x_yes; then
1856                         AC_ERROR([Could not find libmnl, libmnl.h])
1857                 fi
1858                 ;;
1859     no|*)
1860         # nothing
1861                 ;;
1862 esac
1863 AC_ARG_ENABLE(explicit-port-randomisation, AC_HELP_STRING([--disable-explicit-port-randomisation], [disable explicit source port randomisation and rely on the kernel to provide random source ports]))
1864 case "$enable_explicit_port_randomisation" in
1865         no)
1866                 AC_DEFINE([DISABLE_EXPLICIT_PORT_RANDOMISATION], [1], [Define this to enable kernel based UDP source port randomization.])
1867                 ;;
1868         yes|*)
1869                 ;;
1870 esac
1871
1872
1873 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1874 # on openBSD, the implicit rule make $< work.
1875 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1876 # gmake works.
1877 cat >conftest.make <<EOF
1878 all:    conftest.lo
1879
1880 conftest.lo foo.lo bla.lo:
1881         if test -f "\$<"; then touch \$@; fi
1882
1883 .SUFFIXES: .lo
1884 .c.lo:
1885         if test -f "\$<"; then touch \$@; fi
1886
1887 conftest.lo:        conftest.dir/conftest.c
1888 EOF
1889 mkdir conftest.dir
1890 touch conftest.dir/conftest.c
1891 rm -f conftest.lo conftest.c
1892 ${MAKE:-make} -f conftest.make >/dev/null
1893 rm -f conftest.make conftest.c conftest.dir/conftest.c
1894 rm -rf conftest.dir
1895 if test ! -f conftest.lo; then
1896         AC_MSG_RESULT(no)
1897         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1898         SOURCEFILE='`cat .source`'
1899 else
1900         AC_MSG_RESULT(yes)
1901         SOURCEDETERMINE=':'
1902         SOURCEFILE='$<'
1903 fi
1904 rm -f conftest.lo
1905 AC_SUBST(SOURCEDETERMINE)
1906 AC_SUBST(SOURCEFILE)
1907
1908 # see if we want to build the library or everything
1909 ALLTARGET="alltargets"
1910 INSTALLTARGET="install-all"
1911 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1912         [do not build daemon and tool programs]),
1913         [
1914         if test "$withval" = "yes"; then
1915                 ALLTARGET="lib"
1916                 INSTALLTARGET="install-lib"
1917         fi
1918 ])
1919 if test $ALLTARGET = "alltargets"; then
1920         if test $USE_NSS = "yes"; then
1921                 AC_ERROR([--with-nss can only be used in combination with --with-libunbound-only.])
1922         fi
1923         if test $USE_NETTLE = "yes"; then
1924                 AC_ERROR([--with-nettle can only be used in combination with --with-libunbound-only.])
1925         fi
1926 fi
1927
1928 AC_SUBST(ALLTARGET)
1929 AC_SUBST(INSTALLTARGET)
1930
1931 ACX_STRIP_EXT_FLAGS
1932 if test -n "$LATE_LDFLAGS"; then
1933   LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1934 fi
1935 # remove start spaces
1936 LDFLAGS=`echo "$LDFLAGS"|sed -e 's/^ *//'`
1937 LIBS=`echo "$LIBS"|sed -e 's/^ *//'`
1938
1939 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1940
1941 AH_BOTTOM(
1942 dnl this must be first AH_CONFIG, to define the flags before any includes.
1943 AHX_CONFIG_EXT_FLAGS
1944
1945 dnl includes
1946 [
1947 #ifndef _OPENBSD_SOURCE
1948 #define _OPENBSD_SOURCE 1
1949 #endif
1950
1951 #ifndef UNBOUND_DEBUG
1952 # ifndef NDEBUG
1953 #  define NDEBUG
1954 # endif
1955 #endif
1956
1957 /** Use small-ldns codebase */
1958 #define USE_SLDNS 1
1959 #ifdef HAVE_SSL
1960 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1961 #endif
1962
1963 #include <stdio.h>
1964 #include <string.h>
1965 #include <unistd.h>
1966 #include <assert.h>
1967
1968 #if STDC_HEADERS
1969 #include <stdlib.h>
1970 #include <stddef.h>
1971 #endif
1972
1973 #ifdef HAVE_STDARG_H
1974 #include <stdarg.h>
1975 #endif
1976
1977 #ifdef HAVE_STDINT_H
1978 #include <stdint.h>
1979 #endif
1980
1981 #include <errno.h>
1982
1983 #if HAVE_SYS_PARAM_H
1984 #include <sys/param.h>
1985 #endif
1986
1987 #ifdef HAVE_SYS_SOCKET_H
1988 #include <sys/socket.h>
1989 #endif
1990
1991 #ifdef HAVE_SYS_UIO_H
1992 #include <sys/uio.h>
1993 #endif
1994
1995 #ifdef HAVE_NETINET_IN_H
1996 #include <netinet/in.h>
1997 #endif
1998
1999 #ifdef HAVE_NETINET_TCP_H
2000 #include <netinet/tcp.h>
2001 #endif
2002
2003 #ifdef HAVE_ARPA_INET_H
2004 #include <arpa/inet.h>
2005 #endif
2006
2007 #ifdef HAVE_WINSOCK2_H
2008 #include <winsock2.h>
2009 #endif
2010
2011 #ifdef HAVE_WS2TCPIP_H
2012 #include <ws2tcpip.h>
2013 #endif
2014
2015 #ifndef USE_WINSOCK
2016 #define ARG_LL "%ll"
2017 #else
2018 #define ARG_LL "%I64"
2019 #endif
2020
2021 #ifndef AF_LOCAL
2022 #define AF_LOCAL AF_UNIX
2023 #endif
2024 ]
2025
2026 AHX_CONFIG_FORMAT_ATTRIBUTE
2027 AHX_CONFIG_UNUSED_ATTRIBUTE
2028 AHX_CONFIG_FSEEKO
2029 AHX_CONFIG_MAXHOSTNAMELEN
2030 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
2031 #define snprintf snprintf_unbound
2032 #define vsnprintf vsnprintf_unbound
2033 #include <stdarg.h>
2034 int snprintf (char *str, size_t count, const char *fmt, ...);
2035 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
2036 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
2037 AHX_CONFIG_INET_PTON(unbound)
2038 AHX_CONFIG_INET_NTOP(unbound)
2039 AHX_CONFIG_INET_ATON(unbound)
2040 AHX_CONFIG_MEMMOVE(unbound)
2041 AHX_CONFIG_STRLCAT(unbound)
2042 AHX_CONFIG_STRLCPY(unbound)
2043 AHX_CONFIG_GMTIME_R(unbound)
2044 AHX_CONFIG_REALLOCARRAY(unbound)
2045 AHX_CONFIG_W32_SLEEP
2046 AHX_CONFIG_W32_USLEEP
2047 AHX_CONFIG_W32_RANDOM
2048 AHX_CONFIG_W32_SRANDOM
2049 AHX_CONFIG_W32_FD_SET_T
2050 AHX_CONFIG_IPV6_MIN_MTU
2051 AHX_MEMCMP_BROKEN(unbound)
2052
2053 [
2054 #ifndef HAVE_CTIME_R
2055 #define ctime_r unbound_ctime_r
2056 char *ctime_r(const time_t *timep, char *buf);
2057 #endif
2058
2059 #ifndef HAVE_STRSEP
2060 #define strsep unbound_strsep
2061 char *strsep(char **stringp, const char *delim);
2062 #endif
2063
2064 #ifndef HAVE_ISBLANK
2065 #define isblank unbound_isblank
2066 int isblank(int c);
2067 #endif
2068
2069 #ifndef HAVE_EXPLICIT_BZERO
2070 #define explicit_bzero unbound_explicit_bzero
2071 void explicit_bzero(void* buf, size_t len);
2072 #endif
2073
2074 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
2075 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
2076 #endif
2077
2078 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
2079 int inet_pton(int af, const char* src, void* dst);
2080 #endif
2081
2082 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
2083 #define strptime unbound_strptime
2084 struct tm;
2085 char *strptime(const char *s, const char *format, struct tm *tm);
2086 #endif
2087
2088 #if !HAVE_DECL_REALLOCARRAY
2089 void *reallocarray(void *ptr, size_t nmemb, size_t size);
2090 #endif
2091
2092 #ifdef HAVE_LIBBSD
2093 #include <bsd/string.h>
2094 #include <bsd/stdlib.h>
2095 #endif
2096
2097 #ifdef HAVE_LIBRESSL
2098 #  if !HAVE_DECL_STRLCPY
2099 size_t strlcpy(char *dst, const char *src, size_t siz);
2100 #  endif
2101 #  if !HAVE_DECL_STRLCAT
2102 size_t strlcat(char *dst, const char *src, size_t siz);
2103 #  endif
2104 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
2105 uint32_t arc4random(void);
2106 #  endif
2107 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
2108 uint32_t arc4random_uniform(uint32_t upper_bound);
2109 #  endif
2110 #endif /* HAVE_LIBRESSL */
2111 #ifndef HAVE_ARC4RANDOM
2112 int getentropy(void* buf, size_t len);
2113 uint32_t arc4random(void);
2114 void arc4random_buf(void* buf, size_t n);
2115 void _ARC4_LOCK(void);
2116 void _ARC4_UNLOCK(void);
2117 void _ARC4_LOCK_DESTROY(void);
2118 #endif
2119 #ifndef HAVE_ARC4RANDOM_UNIFORM
2120 uint32_t arc4random_uniform(uint32_t upper_bound);
2121 #endif
2122 #ifdef COMPAT_SHA512
2123 #ifndef SHA512_DIGEST_LENGTH
2124 #define SHA512_BLOCK_LENGTH             128
2125 #define SHA512_DIGEST_LENGTH            64
2126 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
2127 typedef struct _SHA512_CTX {
2128         uint64_t        state[8];
2129         uint64_t        bitcount[2];
2130         uint8_t buffer[SHA512_BLOCK_LENGTH];
2131 } SHA512_CTX;
2132 #endif /* SHA512_DIGEST_LENGTH */
2133 void SHA512_Init(SHA512_CTX*);
2134 void SHA512_Update(SHA512_CTX*, void*, size_t);
2135 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
2136 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
2137 #endif /* COMPAT_SHA512 */
2138
2139
2140
2141 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
2142    /* using version of libevent that is not threadsafe. */
2143 #  define LIBEVENT_SIGNAL_PROBLEM 1
2144 #endif
2145
2146 #ifndef CHECKED_INET6
2147 #  define CHECKED_INET6
2148 #  ifdef AF_INET6
2149 #    define INET6
2150 #  else
2151 #    define AF_INET6        28
2152 #  endif
2153 #endif /* CHECKED_INET6 */
2154
2155 #ifndef HAVE_GETADDRINFO
2156 struct sockaddr_storage;
2157 #include "compat/fake-rfc2553.h"
2158 #endif
2159
2160 #ifdef UNBOUND_ALLOC_STATS
2161 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
2162 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
2163 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
2164 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
2165 void *unbound_stat_malloc(size_t size);
2166 void *unbound_stat_calloc(size_t nmemb, size_t size);
2167 void unbound_stat_free(void *ptr);
2168 void *unbound_stat_realloc(void *ptr, size_t size);
2169 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
2170         const char* func);
2171 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
2172         int line, const char* func);
2173 void unbound_stat_free_log(void *ptr, const char* file, int line,
2174         const char* func);
2175 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
2176         int line, const char* func);
2177 #elif defined(UNBOUND_ALLOC_LITE)
2178 #  include "util/alloc.h"
2179 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
2180
2181 /** default port for DNS traffic. */
2182 #define UNBOUND_DNS_PORT 53
2183 /** default port for DNS over TLS traffic. */
2184 #define UNBOUND_DNS_OVER_TLS_PORT 853
2185 /** default port for DNS over HTTPS traffic. */
2186 #define UNBOUND_DNS_OVER_HTTPS_PORT 443
2187 /** default port for unbound control traffic, registered port with IANA,
2188     ub-dns-control  8953/tcp    unbound dns nameserver control */
2189 #define UNBOUND_CONTROL_PORT 8953
2190 /** the version of unbound-control that this software implements */
2191 #define UNBOUND_CONTROL_VERSION 1
2192
2193 ])
2194
2195 dnl if we build from source tree, the man pages need @date@ and @version@
2196 dnl if this is a distro tarball, that was already done by makedist.sh
2197 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
2198 AC_SUBST(date, [`date +'%b %e, %Y'`])
2199
2200 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service contrib/unbound_portable.service])
2201 AC_CONFIG_HEADER([config.h])
2202 AC_OUTPUT