configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[9])
  14 m4_define([VERSION_MICRO],[2])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=9
  21 LIBUNBOUND_REVISION=2
  22 LIBUNBOUND_AGE=1
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75 # 1.6.4 had 7:3:5
  76 # 1.6.5 had 7:4:5
  77 # 1.6.6 had 7:5:5
  78 # 1.6.7 had 7:6:5
  79 # 1.6.8 had 7:7:5
  80 # 1.7.0 had 7:8:5
  81 # 1.7.1 had 7:9:5
  82 # 1.7.2 had 7:10:5
  83 # 1.7.3 had 7:11:5
  84 # 1.8.0 had 8:0:0 # changes the event callback function signature
  85 # 1.8.1 had 8:1:0
  86 # 1.8.2 had 8:2:0
  87 # 1.8.3 had 8:3:0
  88 # 1.9.0 had 9:0:1 # add ub_ctx_set_tls
  89 # 1.9.1 had 9:1:1
  90 # 1.9.2 had 9:2:1
  91
  92 #   Current  -- the number of the binary API that we're implementing
  93 #   Revision -- which iteration of the implementation of the binary
  94 #               API are we supplying?
  95 #   Age      -- How many previous binary API versions do we also
  96 #               support?
  97 #
  98 # If we release a new version that does not change the binary API,
  99 # increment Revision.
 100 #
 101 # If we release a new version that changes the binary API, but does
 102 # not break programs compiled against the old binary API, increment
 103 # Current and Age.  Set Revision to 0, since this is the first
 104 # implementation of the new API.
 105 #
 106 # Otherwise, we're changing the binary API and breaking backward
 107 # compatibility with old binaries.  Increment Current.  Set Age to 0,
 108 # since we're backward compatible with no previous APIs.  Set Revision
 109 # to 0 too.
 110 AC_SUBST(LIBUNBOUND_CURRENT)
 111 AC_SUBST(LIBUNBOUND_REVISION)
 112 AC_SUBST(LIBUNBOUND_AGE)
 113
 114 CFLAGS="$CFLAGS"
 115 AC_AIX
 116 if test "$ac_cv_header_minix_config_h" = "yes"; then
 117         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 118 fi
 119
 120 dnl
 121 dnl By default set prefix to /usr/local
 122 dnl
 123 case "$prefix" in
 124         NONE)
 125                 prefix="/usr/local"
 126         ;;
 127 esac
 128 case "$exec_prefix" in
 129         NONE)
 130                 exec_prefix="$prefix"
 131         ;;
 132 esac
 133
 134 # are we on MinGW?
 135 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 136 else
 137         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 138         else on_mingw="no"; fi
 139 fi
 140
 141 #
 142 # Determine configuration file
 143 # the eval is to evaluate shell expansion twice
 144 UNBOUND_SBIN_DIR=`eval echo "${sbindir}"`
 145 AC_SUBST(UNBOUND_SBIN_DIR)
 146 UNBOUND_SYSCONF_DIR=`eval echo "${sysconfdir}"`
 147 AC_SUBST(UNBOUND_SYSCONF_DIR)
 148 UNBOUND_LOCALSTATE_DIR=`eval echo "${localstatedir}"`
 149 AC_SUBST(UNBOUND_LOCALSTATE_DIR)
 150 if test $on_mingw = "no"; then
 151   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 152 else
 153   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 154 fi
 155 AC_ARG_WITH([conf_file],
 156         AC_HELP_STRING([--with-conf-file=path],
 157         [Pathname to the Unbound configuration file]),
 158         [ub_conf_file="$withval"])
 159 AC_SUBST(ub_conf_file)
 160 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 161 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 162 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 163 AC_SUBST(ub_conf_dir)
 164
 165 # Determine run, chroot directory and pidfile locations
 166 AC_ARG_WITH(run-dir,
 167     AC_HELP_STRING([--with-run-dir=path],
 168     [set default directory to chdir to (by default dir part of cfg file)]),
 169     UNBOUND_RUN_DIR="$withval",
 170 if test $on_mingw = no; then
 171     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 172 else
 173     UNBOUND_RUN_DIR=""
 174 fi
 175 )
 176 AC_SUBST(UNBOUND_RUN_DIR)
 177 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 178 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 179
 180 AC_ARG_WITH(chroot-dir,
 181     AC_HELP_STRING([--with-chroot-dir=path],
 182     [set default directory to chroot to (by default same as run-dir)]),
 183     UNBOUND_CHROOT_DIR="$withval",
 184 if test $on_mingw = no; then
 185     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 186 else
 187     UNBOUND_CHROOT_DIR=""
 188 fi
 189 )
 190 AC_SUBST(UNBOUND_CHROOT_DIR)
 191 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 192 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 193
 194 AC_ARG_WITH(share-dir,
 195     AC_HELP_STRING([--with-share-dir=path],
 196     [set default directory with shared data (by default same as share/unbound)]),
 197     UNBOUND_SHARE_DIR="$withval",
 198     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 199 AC_SUBST(UNBOUND_SHARE_DIR)
 200 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 201
 202 AC_ARG_WITH(pidfile,
 203     AC_HELP_STRING([--with-pidfile=filename],
 204     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 205     UNBOUND_PIDFILE="$withval",
 206 if test $on_mingw = no; then
 207     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 208 else
 209     UNBOUND_PIDFILE=""
 210 fi
 211 )
 212 AC_SUBST(UNBOUND_PIDFILE)
 213 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 214 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 215
 216 AC_ARG_WITH(rootkey-file,
 217     AC_HELP_STRING([--with-rootkey-file=filename],
 218     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 219     UNBOUND_ROOTKEY_FILE="$withval",
 220 if test $on_mingw = no; then
 221     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 222 else
 223     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 224 fi
 225 )
 226 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 227 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 228 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 229
 230 AC_ARG_WITH(rootcert-file,
 231     AC_HELP_STRING([--with-rootcert-file=filename],
 232     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 233     UNBOUND_ROOTCERT_FILE="$withval",
 234 if test $on_mingw = no; then
 235     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 236 else
 237     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 238 fi
 239 )
 240 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 241 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 242 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 243
 244 AC_ARG_WITH(username,
 245     AC_HELP_STRING([--with-username=user],
 246     [set default user that unbound changes to (default user is unbound)]),
 247     UNBOUND_USERNAME="$withval",
 248     UNBOUND_USERNAME="unbound")
 249 AC_SUBST(UNBOUND_USERNAME)
 250 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 251
 252 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 253 ACX_RSRC_VERSION(wnvs)
 254 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 255
 256 # Checks for typedefs, structures, and compiler characteristics.
 257 AC_C_CONST
 258 AC_LANG_C
 259 # allow user to override the -g -O2 flags.
 260 default_cflags=no
 261 if test "x$CFLAGS" = "x" ; then
 262 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 263 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 264 default_cflags=yes
 265 fi
 266 AC_PROG_CC
 267 ACX_DEPFLAG
 268 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 269
 270 # debug mode flags warnings
 271 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 272 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 273 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 274 else debug_enabled="$enable_checking"; fi
 275 AC_SUBST(debug_enabled)
 276 case "$debug_enabled" in
 277         yes)
 278                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 279                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 280                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 281                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 282                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 283                 ;;
 284         no|*)
 285                 # nothing to do.
 286                 ;;
 287 esac
 288 if test "$default_cflags" = "yes"; then
 289         # only when CFLAGS was "" at the start, if the users wants to
 290         # override we shouldn't add default cflags, because they wouldn't
 291         # be able to turn off these options and set the CFLAGS wanted.
 292         ACX_CHECK_FLTO
 293         ACX_CHECK_PIE
 294         ACX_CHECK_RELRO_NOW
 295 fi
 296
 297 AC_C_INLINE
 298 ACX_CHECK_FORMAT_ATTRIBUTE
 299 ACX_CHECK_UNUSED_ATTRIBUTE
 300
 301 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 302 [AC_REQUIRE([AC_PROG_CC])
 303 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 304 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 305 [ac_cv_c_weak_attribute=no
 306 AC_TRY_COMPILE(
 307 [ #include <stdio.h>
 308 __attribute__((weak)) void f(int x) { printf("%d", x); }
 309 ], [
 310    f(1);
 311 ],
 312 [ac_cv_c_weak_attribute="yes"],
 313 [ac_cv_c_weak_attribute="no"])
 314 ])
 315
 316 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 317 if test $ac_cv_c_weak_attribute = yes; then
 318   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 319   AC_DEFINE(ATTR_WEAK, [__attribute__((weak))], [apply the weak attribute to a symbol])
 320 fi
 321 ])dnl End of CHECK_WEAK_ATTRIBUTE
 322
 323 CHECK_WEAK_ATTRIBUTE
 324
 325 AC_DEFUN([CHECK_NORETURN_ATTRIBUTE],
 326 [AC_REQUIRE([AC_PROG_CC])
 327 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "noreturn" attribute)
 328 AC_CACHE_VAL(ac_cv_c_noreturn_attribute,
 329 [ac_cv_c_noreturn_attribute=no
 330 AC_TRY_COMPILE(
 331 [ #include <stdio.h>
 332 __attribute__((noreturn)) void f(int x) { printf("%d", x); }
 333 ], [
 334    f(1);
 335 ],
 336 [ac_cv_c_noreturn_attribute="yes"],
 337 [ac_cv_c_noreturn_attribute="no"])
 338 ])
 339
 340 AC_MSG_RESULT($ac_cv_c_noreturn_attribute)
 341 if test $ac_cv_c_noreturn_attribute = yes; then
 342   AC_DEFINE(HAVE_ATTR_NORETURN, 1, [Whether the C compiler accepts the "noreturn" attribute])
 343   AC_DEFINE(ATTR_NORETURN, [__attribute__((__noreturn__))], [apply the noreturn attribute to a function that exits the program])
 344 fi
 345 ])dnl End of CHECK_NORETURN_ATTRIBUTE
 346
 347 CHECK_NORETURN_ATTRIBUTE
 348
 349 if test "$srcdir" != "."; then
 350         CPPFLAGS="$CPPFLAGS -I$srcdir"
 351 fi
 352
 353 AC_DEFUN([ACX_YYLEX_DESTROY], [
 354         AC_MSG_CHECKING([for yylex_destroy])
 355         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 356                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 357                 AC_MSG_RESULT(yes)
 358         else AC_MSG_RESULT(no);
 359                 LEX=":"
 360         fi
 361 ])
 362
 363 AC_DEFUN([ACX_YYLEX_OPTION], [
 364         AC_MSG_CHECKING([for lex %option])
 365         if cat <<EOF | $LEX -t 2>&1 | grep yy_delete_buffer >/dev/null 2>&1; then
 366 %option nounput
 367 %%
 368 EOF
 369                 AC_MSG_RESULT(yes)
 370         else AC_MSG_RESULT(no);
 371                 LEX=":"
 372         fi
 373 ])
 374
 375 AC_PROG_LEX
 376 if test "$LEX" != "" -a "$LEX" != ":"; then
 377 ACX_YYLEX_DESTROY
 378 fi
 379 if test "$LEX" != "" -a "$LEX" != ":"; then
 380 ACX_YYLEX_OPTION
 381 fi
 382 AC_PROG_YACC
 383 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 384 AC_CHECK_TOOL(STRIP, strip)
 385 ACX_LIBTOOL_C_ONLY
 386
 387 PKG_PROG_PKG_CONFIG
 388
 389 # Checks for header files.
 390 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/endian.h libkern/OSByteOrder.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 391
 392 # check for types.
 393 # Using own tests for int64* because autoconf builtin only give 32bit.
 394 AC_CHECK_TYPE(int8_t, signed char)
 395 AC_CHECK_TYPE(int16_t, short)
 396 AC_CHECK_TYPE(int32_t, int)
 397 AC_CHECK_TYPE(int64_t, long long)
 398 AC_CHECK_TYPE(uint8_t, unsigned char)
 399 AC_CHECK_TYPE(uint16_t, unsigned short)
 400 AC_CHECK_TYPE(uint32_t, unsigned int)
 401 AC_CHECK_TYPE(uint64_t, unsigned long long)
 402 AC_TYPE_SIZE_T
 403 AC_CHECK_TYPE(ssize_t, int)
 404 AC_TYPE_UID_T
 405 AC_TYPE_PID_T
 406 AC_TYPE_OFF_T
 407 ACX_TYPE_U_CHAR
 408 ACX_TYPE_RLIM_T
 409 ACX_TYPE_SOCKLEN_T
 410 ACX_TYPE_IN_ADDR_T
 411 ACX_TYPE_IN_PORT_T
 412 ACX_CHECK_MEMCMP_SIGNED
 413
 414 AC_CHECK_SIZEOF(time_t,,[
 415 AC_INCLUDES_DEFAULT
 416 #ifdef TIME_WITH_SYS_TIME
 417 # include <sys/time.h>
 418 # include <time.h>
 419 #else
 420 # ifdef HAVE_SYS_TIME_H
 421 #  include <sys/time.h>
 422 # else
 423 #  include <time.h>
 424 # endif
 425 #endif
 426 ])
 427
 428 # add option to disable the evil rpath
 429 ACX_ARG_RPATH
 430 AC_SUBST(RUNTIME_PATH)
 431
 432 # check to see if libraries are needed for these functions.
 433 AC_SEARCH_LIBS([inet_pton], [nsl])
 434 AC_SEARCH_LIBS([socket], [socket])
 435
 436 # check wether strptime also works
 437 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 438 [AC_REQUIRE([AC_PROG_CC])
 439 AC_MSG_CHECKING(whether strptime works)
 440 if test c${cross_compiling} = cno; then
 441 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 442 #define _XOPEN_SOURCE 600
 443 #include <time.h>
 444 int main(void) { struct tm tm; char *res;
 445 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 446 if (!res) return 2;
 447 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 448 if (!res) return 1; return 0; }
 449 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 450 else
 451 eval "ac_cv_c_strptime_works=maybe"
 452 fi
 453 AC_MSG_RESULT($ac_cv_c_strptime_works)
 454 if test $ac_cv_c_strptime_works = no; then
 455 AC_LIBOBJ(strptime)
 456 else
 457 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 458 fi
 459 ])dnl
 460
 461 # check some functions of the OS before linking libs (while still runnable).
 462 AC_FUNC_CHOWN
 463 AC_FUNC_FORK
 464 AC_TYPE_SIGNAL
 465 AC_FUNC_FSEEKO
 466 ACX_SYS_LARGEFILE
 467 ACX_CHECK_NONBLOCKING_BROKEN
 468 ACX_MKDIR_ONE_ARG
 469 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 470
 471 # check if we can use SO_REUSEPORT
 472 if echo "$host" | grep -i -e linux -e dragonfly >/dev/null; then
 473         AC_DEFINE(REUSEPORT_DEFAULT, 1, [if REUSEPORT is enabled by default])
 474 else
 475         AC_DEFINE(REUSEPORT_DEFAULT, 0, [if REUSEPORT is enabled by default])
 476 fi
 477
 478 # set memory allocation checking if requested
 479 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 480         [ enable to memory allocation statistics, for debug purposes ]),
 481         , )
 482 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 483         [ enable for lightweight alloc assertions, for debug purposes ]),
 484         , )
 485 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 486         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 487         , )
 488 if test x_$enable_alloc_nonregional = x_yes; then
 489         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 490 fi
 491 if test x_$enable_alloc_checks = x_yes; then
 492         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 493 else
 494         if test x_$enable_alloc_lite = x_yes; then
 495                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 496         else
 497                 ACX_FUNC_MALLOC([unbound])
 498         fi
 499 fi
 500
 501 # check windows threads (we use them, not pthreads, on windows).
 502 if test "$on_mingw" = "yes"; then
 503 # check windows threads
 504         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 505         AC_MSG_CHECKING([for CreateThread])
 506         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 507 #ifdef HAVE_WINDOWS_H
 508 #include <windows.h>
 509 #endif
 510 ], [
 511         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 512 ])],
 513         AC_MSG_RESULT(yes)
 514         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 515 ,
 516         AC_MSG_RESULT(no)
 517 )
 518
 519 else
 520 # not on mingw, check thread libraries.
 521
 522 # check for thread library.
 523 # check this first, so that the pthread lib does not get linked in via
 524 # libssl or libpython, and thus distorts the tests, and we end up using
 525 # the non-threadsafe C libraries.
 526 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 527  [use pthreads library, or --without-pthreads to disable threading support.]),
 528  [ ],[ withval="yes" ])
 529 ub_have_pthreads=no
 530 if test x_$withval != x_no; then
 531         AX_PTHREAD([
 532                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 533                 if test -n "$PTHREAD_LIBS"; then
 534                   LIBS="$PTHREAD_LIBS $LIBS"
 535                 fi
 536                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 537                 CC="$PTHREAD_CC"
 538                 ub_have_pthreads=yes
 539                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 540
 541                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 542                 AC_MSG_CHECKING([if -pthread unused during linking])
 543                 # catch clang warning 'argument unused during compilation'
 544                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 545 [[
 546 int main(void) {return 0;}
 547 ]])])
 548                 pthread_unused="yes"
 549                 # first compile
 550                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 551                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 552                 if test $? = 0; then
 553                         # then link
 554                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 555                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 556                         if test $? -ne 0; then
 557                                 AC_MSG_RESULT(yes)
 558                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 559                                 PTHREAD_CFLAGS_ONLY="-pthread"
 560                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 561                         else
 562                                 AC_MSG_RESULT(no)
 563                         fi
 564                 else
 565                         AC_MSG_RESULT(no)
 566                 fi # endif cc successful
 567                 rm -f conftest conftest.c conftest.o
 568                 fi # endif -pthread in CFLAGS
 569
 570                 ])
 571 fi
 572
 573 # check solaris thread library
 574 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 575         [use solaris native thread library.]), [ ],[ withval="no" ])
 576 ub_have_sol_threads=no
 577 if test x_$withval != x_no; then
 578         if test x_$ub_have_pthreads != x_no; then
 579             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 580         else
 581         AC_SEARCH_LIBS(thr_create, [thread],
 582         [
 583                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 584
 585                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 586                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 587                 ub_have_sol_threads=yes
 588         ] , [
 589                 AC_ERROR([no solaris threads found.])
 590         ])
 591         fi
 592 fi
 593
 594 fi # end of non-mingw check of thread libraries
 595
 596 # Check for PyUnbound
 597 AC_ARG_WITH(pyunbound,
 598    AC_HELP_STRING([--with-pyunbound],
 599    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 600    [], [ withval="no" ])
 601
 602 ub_test_python=no
 603 ub_with_pyunbound=no
 604 if test x_$withval != x_no; then
 605    ub_with_pyunbound=yes
 606    ub_test_python=yes
 607 fi
 608
 609 # Check for Python module
 610 AC_ARG_WITH(pythonmodule,
 611    AC_HELP_STRING([--with-pythonmodule],
 612    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 613    [], [ withval="no" ])
 614
 615 ub_with_pythonmod=no
 616 if test x_$withval != x_no; then
 617    ub_with_pythonmod=yes
 618    ub_test_python=yes
 619 fi
 620
 621 # Check for Python & SWIG only on PyUnbound or PyModule
 622 if test x_$ub_test_python != x_no; then
 623
 624    # Check for Python
 625    ub_have_python=no
 626    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 627    AC_PYTHON_DEVEL
 628    if test ! -z "$PYTHON_VERSION"; then
 629         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 630                 AC_ERROR([Python version >= 2.4.0 is required])
 631         fi
 632
 633       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 634       AC_SUBST(PY_MAJOR_VERSION)
 635       # Have Python
 636       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 637       if test -n "$LIBS"; then
 638         LIBS="$PYTHON_LDFLAGS $LIBS"
 639       else
 640         LIBS="$PYTHON_LDFLAGS"
 641       fi
 642       if test -n "$CPPFLAGS"; then
 643         CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 644       else
 645         CPPFLAGS="$PYTHON_CPPFLAGS"
 646       fi
 647       ub_have_python=yes
 648       PKG_CHECK_EXISTS(["python${PY_MAJOR_VERSION}"],
 649                        [PC_PY_DEPENDENCY="python${PY_MAJOR_VERSION}"],
 650                        [PC_PY_DEPENDENCY="python"])
 651       AC_SUBST(PC_PY_DEPENDENCY)
 652
 653       # Check for SWIG
 654       ub_have_swig=no
 655       AC_ARG_ENABLE(swig-version-check, AC_HELP_STRING([--disable-swig-version-check], [Disable swig version check to build python modules with older swig even though that is unreliable]))
 656       if test "$enable_swig_version_check" = "yes"; then
 657         AC_PROG_SWIG(2.0.1)
 658       else
 659         AC_PROG_SWIG
 660       fi
 661       AC_MSG_CHECKING(SWIG)
 662       if test ! -x "$SWIG"; then
 663          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 664       else
 665          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 666          AC_SUBST(swig, "$SWIG")
 667          AC_MSG_RESULT(present)
 668
 669          # If have Python & SWIG
 670          # Declare PythonMod
 671          if test x_$ub_with_pythonmod != x_no; then
 672             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 673             WITH_PYTHONMODULE=yes
 674             AC_SUBST(WITH_PYTHONMODULE)
 675             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 676             AC_SUBST(PYTHONMOD_OBJ)
 677             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 678             AC_SUBST(PYTHONMOD_HEADER)
 679             PYTHONMOD_INSTALL=pythonmod-install
 680             AC_SUBST(PYTHONMOD_INSTALL)
 681             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 682             AC_SUBST(PYTHONMOD_UNINSTALL)
 683          fi
 684
 685          # Declare PyUnbound
 686          if test x_$ub_with_pyunbound != x_no; then
 687             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 688             WITH_PYUNBOUND=yes
 689             AC_SUBST(WITH_PYUNBOUND)
 690             PYUNBOUND_OBJ="libunbound_wrap.lo"
 691             AC_SUBST(PYUNBOUND_OBJ)
 692             PYUNBOUND_TARGET="_unbound.la"
 693             AC_SUBST(PYUNBOUND_TARGET)
 694             PYUNBOUND_INSTALL=pyunbound-install
 695             AC_SUBST(PYUNBOUND_INSTALL)
 696             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 697             AC_SUBST(PYUNBOUND_UNINSTALL)
 698          fi
 699       fi
 700    else
 701       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 702       ub_with_pyunbound=no
 703       ub_with_pythonmod=no
 704    fi
 705 fi
 706
 707 if test "`uname`" = "NetBSD"; then
 708         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 709         AC_SUBST(NETBSD_LINTFLAGS)
 710 fi
 711 CONFIG_DATE=`date +%Y%m%d`
 712 AC_SUBST(CONFIG_DATE)
 713
 714 # Checks for libraries.
 715
 716 # libnss
 717 USE_NSS="no"
 718 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 719         [use libnss instead of openssl, installed at path.]),
 720         [
 721         USE_NSS="yes"
 722         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 723         if test "$withval" != "" -a "$withval" != "yes"; then
 724                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 725                 LDFLAGS="$LDFLAGS -L$withval/lib"
 726                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 727                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 728         else
 729                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 730                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 731         fi
 732         LIBS="$LIBS -lnss3 -lnspr4"
 733         SSLLIB=""
 734         ]
 735 )
 736
 737 # libnettle
 738 USE_NETTLE="no"
 739 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 740         [use libnettle as crypto library, installed at path.]),
 741         [
 742         USE_NETTLE="yes"
 743         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 744         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 745         if test "$withval" != "" -a "$withval" != "yes"; then
 746                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 747                 LDFLAGS="$LDFLAGS -L$withval/lib"
 748                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 749         else
 750                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 751         fi
 752         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 753         SSLLIB=""
 754         ]
 755 )
 756
 757 # openssl
 758 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 759 ACX_WITH_SSL
 760 ACX_LIB_SSL
 761 SSLLIB="-lssl"
 762
 763 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 764 BAKLIBS="$LIBS"
 765 LIBS="-lssl $LIBS"
 766 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 767 AC_TRY_LINK_FUNC([HMAC_Update], [
 768         AC_MSG_RESULT([no])
 769         LIBS="$BAKLIBS"
 770 ], [
 771         AC_MSG_RESULT([yes])
 772         LIBS="$BAKLIBS"
 773         LIBS="$LIBS -lcrypt32"
 774 ])
 775
 776 AC_MSG_CHECKING([for LibreSSL])
 777 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 778         AC_MSG_RESULT([yes])
 779         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 780         # libressl provides these compat functions, but they may also be
 781         # declared by the OS in libc.  See if they have been declared.
 782         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform,reallocarray])
 783 else
 784         AC_MSG_RESULT([no])
 785 fi
 786 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h],,, [AC_INCLUDES_DEFAULT])
 787 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1 EVP_DigestVerify SSL_CTX_set_tlsext_ticket_key_cb EVP_aes_256_cbc EVP_EncryptInit_ex HMAC_Init_ex CRYPTO_THREADID_set_callback])
 788
 789 # these check_funcs need -lssl
 790 BAKLIBS="$LIBS"
 791 LIBS="-lssl $LIBS"
 792 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level SSL_set1_host SSL_get0_peername X509_VERIFY_PARAM_set1_host SSL_CTX_set_ciphersuites])
 793 LIBS="$BAKLIBS"
 794
 795 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 796 AC_INCLUDES_DEFAULT
 797 #ifdef HAVE_OPENSSL_ERR_H
 798 #include <openssl/err.h>
 799 #endif
 800
 801 #ifdef HAVE_OPENSSL_RAND_H
 802 #include <openssl/rand.h>
 803 #endif
 804
 805 #ifdef HAVE_OPENSSL_CONF_H
 806 #include <openssl/conf.h>
 807 #endif
 808
 809 #ifdef HAVE_OPENSSL_ENGINE_H
 810 #include <openssl/engine.h>
 811 #endif
 812 #include <openssl/ssl.h>
 813 #include <openssl/evp.h>
 814 ])
 815 fi
 816 AC_SUBST(SSLLIB)
 817
 818
 819 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 820 case "$enable_sha1" in
 821         no)
 822         ;;
 823         yes|*)
 824         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 825         ;;
 826 esac
 827
 828
 829 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 830 case "$enable_sha2" in
 831         no)
 832         ;;
 833         yes|*)
 834         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 835         ;;
 836 esac
 837
 838 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 839 case "$enable_subnet" in
 840         yes)
 841         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 842         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 843         AC_SUBST(SUBNET_OBJ)
 844         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 845         AC_SUBST(SUBNET_HEADER)
 846         ;;
 847         no|*)
 848         ;;
 849 esac
 850
 851 # check wether gost also works
 852 AC_DEFUN([AC_CHECK_GOST_WORKS],
 853 [AC_REQUIRE([AC_PROG_CC])
 854 AC_MSG_CHECKING([if GOST works])
 855 if test c${cross_compiling} = cno; then
 856 BAKCFLAGS="$CFLAGS"
 857 if test -n "$ssldir"; then
 858         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 859 fi
 860 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 861 #include <string.h>
 862 #include <openssl/ssl.h>
 863 #include <openssl/evp.h>
 864 #include <openssl/engine.h>
 865 #include <openssl/conf.h>
 866 /* routine to load gost (from sldns) */
 867 int load_gost_id(void)
 868 {
 869         static int gost_id = 0;
 870         const EVP_PKEY_ASN1_METHOD* meth;
 871         ENGINE* e;
 872
 873         if(gost_id) return gost_id;
 874
 875         /* see if configuration loaded gost implementation from other engine*/
 876         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 877         if(meth) {
 878                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 879                 return gost_id;
 880         }
 881
 882         /* see if engine can be loaded already */
 883         e = ENGINE_by_id("gost");
 884         if(!e) {
 885                 /* load it ourself, in case statically linked */
 886                 ENGINE_load_builtin_engines();
 887                 ENGINE_load_dynamic();
 888                 e = ENGINE_by_id("gost");
 889         }
 890         if(!e) {
 891                 /* no gost engine in openssl */
 892                 return 0;
 893         }
 894         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 895                 ENGINE_finish(e);
 896                 ENGINE_free(e);
 897                 return 0;
 898         }
 899
 900         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 901         if(!meth) {
 902                 /* algo not found */
 903                 ENGINE_finish(e);
 904                 ENGINE_free(e);
 905                 return 0;
 906         }
 907         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 908         return gost_id;
 909 }
 910 int main(void) {
 911         EVP_MD_CTX* ctx;
 912         const EVP_MD* md;
 913         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 914         const char* str = "Hello world";
 915         const unsigned char check[] = {
 916                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 917                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 918                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 919                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 920         };
 921         OPENSSL_config(NULL);
 922         (void)load_gost_id();
 923         md = EVP_get_digestbyname("md_gost94");
 924         if(!md) return 1;
 925         memset(digest, 0, sizeof(digest));
 926         ctx = EVP_MD_CTX_create();
 927         if(!ctx) return 2;
 928         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 929         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 930         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 931         /* uncomment to see the hash calculated.
 932                 {int i;
 933                 for(i=0; i<32; i++)
 934                         printf(" %2.2x", (int)digest[i]);
 935                 printf("\n");}
 936         */
 937         if(memcmp(digest, check, sizeof(check)) != 0)
 938                 return 6;
 939         return 0;
 940 }
 941 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 942 CFLAGS="$BAKCFLAGS"
 943 else
 944 eval "ac_cv_c_gost_works=maybe"
 945 fi
 946 AC_MSG_RESULT($ac_cv_c_gost_works)
 947 ])dnl
 948
 949 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 950 use_gost="no"
 951 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 952 case "$enable_gost" in
 953         no)
 954         ;;
 955         *)
 956         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 957         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 958         AC_CHECK_GOST_WORKS
 959         if test "$ac_cv_c_gost_works" != no; then
 960                 use_gost="yes"
 961                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 962         fi
 963         ;;
 964 esac
 965 fi dnl !USE_NSS && !USE_NETTLE
 966
 967 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 968 use_ecdsa="no"
 969 case "$enable_ecdsa" in
 970     no)
 971       ;;
 972     *)
 973       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 974               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 975               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 976               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 977 #include <openssl/evp.h>
 978               ])
 979               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 980               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 981               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
 982                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 983                   AC_MSG_RESULT([no])
 984                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 985                 else
 986                   AC_MSG_RESULT([yes])
 987                 fi
 988               else
 989                 # not OpenSSL, thus likely LibreSSL, which supports it
 990                 AC_MSG_RESULT([yes])
 991               fi
 992       fi
 993       # we now know we have ECDSA and the required curves.
 994       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 995       use_ecdsa="yes"
 996       ;;
 997 esac
 998
 999 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
1000 use_dsa="no"
1001 case "$enable_dsa" in
1002     no)
1003       ;;
1004     *)
1005       # detect if DSA is supported, and turn it off if not.
1006       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1007       AC_CHECK_FUNC(DSA_SIG_new, [
1008       AC_CHECK_TYPE(DSA_SIG*, [
1009       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1010       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1011                fi ], [
1012 AC_INCLUDES_DEFAULT
1013 #ifdef HAVE_OPENSSL_ERR_H
1014 #include <openssl/err.h>
1015 #endif
1016
1017 #ifdef HAVE_OPENSSL_RAND_H
1018 #include <openssl/rand.h>
1019 #endif
1020
1021 #ifdef HAVE_OPENSSL_CONF_H
1022 #include <openssl/conf.h>
1023 #endif
1024
1025 #ifdef HAVE_OPENSSL_ENGINE_H
1026 #include <openssl/engine.h>
1027 #endif
1028       ])
1029       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1030                fi ])
1031       else
1032       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1033       fi
1034       ;;
1035 esac
1036
1037 AC_ARG_ENABLE(ed25519, AC_HELP_STRING([--disable-ed25519], [Disable ED25519 support]))
1038 use_ed25519="no"
1039 case "$enable_ed25519" in
1040     no)
1041       ;;
1042     *)
1043       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1044               AC_CHECK_DECLS([NID_ED25519], [
1045                 use_ed25519="yes"
1046               ], [ if test "x$enable_ed25519" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED25519 and you used --enable-ed25519.])
1047                 fi ], [AC_INCLUDES_DEFAULT
1048 #include <openssl/evp.h>
1049               ])
1050       fi
1051       if test $USE_NETTLE = "yes"; then
1052                 AC_CHECK_HEADERS([nettle/eddsa.h], use_ed25519="yes",, [AC_INCLUDES_DEFAULT])
1053       fi
1054       if test $use_ed25519 = "yes"; then
1055                 AC_DEFINE_UNQUOTED([USE_ED25519], [1], [Define this to enable ED25519 support.])
1056       fi
1057       ;;
1058 esac
1059
1060 AC_ARG_ENABLE(ed448, AC_HELP_STRING([--disable-ed448], [Disable ED448 support]))
1061 use_ed448="no"
1062 case "$enable_ed448" in
1063     no)
1064       ;;
1065     *)
1066       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1067               AC_CHECK_DECLS([NID_ED448], [
1068                 use_ed448="yes"
1069               ], [ if test "x$enable_ed448" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED448 and you used --enable-ed448.])
1070                 fi ], [AC_INCLUDES_DEFAULT
1071 #include <openssl/evp.h>
1072               ])
1073       fi
1074       if test $use_ed448 = "yes"; then
1075                 AC_DEFINE_UNQUOTED([USE_ED448], [1], [Define this to enable ED448 support.])
1076       fi
1077       ;;
1078 esac
1079
1080 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
1081 case "$enable_event_api" in
1082     yes)
1083       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
1084       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
1085       ;;
1086     *)
1087       ;;
1088 esac
1089
1090 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
1091 case "$enable_tfo_client" in
1092         yes)
1093                 case `uname` in
1094                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1095                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1096                                              [AC_INCLUDES_DEFAULT
1097 #include <netinet/tcp.h>
1098 ])
1099                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1100                           ;;
1101                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1102                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1103                                               [AC_INCLUDES_DEFAULT
1104 #include <sys/socket.h>
1105 ])
1106                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1107                           ;;
1108                 esac
1109         ;;
1110         no|*)
1111                 ;;
1112 esac
1113
1114 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
1115 case "$enable_tfo_server" in
1116         yes)
1117               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
1118 #include <netinet/tcp.h>
1119               ])
1120                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
1121                 ;;
1122         no|*)
1123                 ;;
1124 esac
1125
1126 # check for libevent
1127 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
1128     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
1129     [ ],[ withval="no" ])
1130 if test x_$withval = x_yes -o x_$withval != x_no; then
1131         AC_MSG_CHECKING(for libevent)
1132         if test x_$withval = x_ -o x_$withval = x_yes; then
1133             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1134         fi
1135         for dir in $withval; do
1136             thedir="$dir"
1137             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
1138                 found_libevent="yes"
1139                 dnl assume /usr is in default path.
1140                 if test "$thedir" != "/usr"; then
1141                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
1142                 fi
1143                 break;
1144             fi
1145         done
1146         if test x_$found_libevent != x_yes; then
1147                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
1148                         # libevent source directory
1149                         AC_MSG_RESULT(found in $thedir)
1150                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
1151                         BAK_LDFLAGS_SET="1"
1152                         BAK_LDFLAGS="$LDFLAGS"
1153                         # remove evdns from linking
1154                         mkdir build >/dev/null 2>&1
1155                         mkdir build/libevent >/dev/null 2>&1
1156                         mkdir build/libevent/.libs >/dev/null 2>&1
1157                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1158                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
1159                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1160                         cp $ev_files_o build/libevent
1161                         cp $ev_files_lo build/libevent
1162                         cp $ev_files_libso build/libevent/.libs
1163                         LATE_LDFLAGS="build/libevent/*.lo -lm"
1164                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
1165                 else
1166                         AC_MSG_ERROR([Cannot find the libevent library in $withval
1167 You can restart ./configure --with-libevent=no to use a builtin alternative.
1168 Please note that this alternative is not as capable as libevent when using
1169 large outgoing port ranges.  ])
1170                 fi
1171         else
1172             AC_MSG_RESULT(found in $thedir)
1173             dnl if event2 exists and no event lib in dir itself, use subdir
1174             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1175                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1176                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1177             else
1178                     dnl assume /usr is in default path, do not add "".
1179                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1180                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1181                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1182                     fi
1183             fi
1184         fi
1185         # check for library used by libevent after 1.3c
1186         AC_SEARCH_LIBS([clock_gettime], [rt])
1187
1188         # is the event.h header libev or libevent?
1189         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1190         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1191                 AC_SEARCH_LIBS(event_set, [ev])
1192         ],[
1193                 AC_SEARCH_LIBS(event_set, [event])
1194         ],[AC_INCLUDES_DEFAULT
1195 #include <event.h>
1196         ])
1197         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1198         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1199         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1200         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1201         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1202         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1203         AC_CHECK_FUNCS([event_assign]) # in libevent, for thread-safety
1204         AC_CHECK_DECLS([evsignal_assign], [], [], [AC_INCLUDES_DEFAULT
1205 #ifdef HAVE_EVENT_H
1206 #  include <event.h>
1207 #else
1208 #  include "event2/event.h"
1209 #endif
1210         ])
1211         PC_LIBEVENT_DEPENDENCY="libevent"
1212         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1213         if test -n "$BAK_LDFLAGS_SET"; then
1214                 LDFLAGS="$BAK_LDFLAGS"
1215         fi
1216 else
1217         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1218 fi
1219
1220 # check for libexpat
1221 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1222     [specify explicit path for libexpat.]),
1223     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1224 AC_MSG_CHECKING(for libexpat)
1225 found_libexpat="no"
1226 for dir in $withval ; do
1227             if test -f "$dir/include/expat.h"; then
1228                 found_libexpat="yes"
1229                 dnl assume /usr is in default path.
1230                 if test "$dir" != "/usr"; then
1231                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1232                     LDFLAGS="$LDFLAGS -L$dir/lib"
1233                 fi
1234                 AC_MSG_RESULT(found in $dir)
1235                 break;
1236             fi
1237 done
1238 if test x_$found_libexpat != x_yes; then
1239         AC_ERROR([Could not find libexpat, expat.h])
1240 fi
1241 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1242 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1243 #include <expat.h>
1244 ])
1245
1246 # hiredis (redis C client for cachedb)
1247 AC_ARG_WITH(libhiredis, AC_HELP_STRING([--with-libhiredis=path],
1248     [specify explicit path for libhiredis.]),
1249     [ ],[ withval="no" ])
1250 found_libhiredis="no"
1251 if test x_$withval = x_yes -o x_$withval != x_no; then
1252    AC_MSG_CHECKING(for libhiredis)
1253    if test x_$withval = x_ -o x_$withval = x_yes; then
1254             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1255    fi
1256    for dir in $withval ; do
1257             if test -f "$dir/include/hiredis/hiredis.h"; then
1258                 found_libhiredis="yes"
1259                 dnl assume /usr is in default path.
1260                 if test "$dir" != "/usr"; then
1261                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1262                     LDFLAGS="$LDFLAGS -L$dir/lib"
1263                 fi
1264                 AC_MSG_RESULT(found in $dir)
1265                 AC_DEFINE([USE_REDIS], [1], [Define this to use hiredis client.])
1266                 LIBS="$LIBS -lhiredis"
1267                 break;
1268             fi
1269     done
1270     if test x_$found_libhiredis != x_yes; then
1271         AC_ERROR([Could not find libhiredis, hiredis.h])
1272     fi
1273     AC_CHECK_HEADERS([hiredis/hiredis.h],,, [AC_INCLUDES_DEFAULT])
1274     AC_CHECK_DECLS([redisConnect], [], [], [AC_INCLUDES_DEFAULT
1275     #include <hiredis/hiredis.h>
1276     ])
1277 fi
1278
1279 # set static linking if requested
1280 AC_SUBST(staticexe)
1281 staticexe=""
1282 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1283         [ enable to compile executables statically against (event) libs, for debug purposes ]),
1284         , )
1285 if test x_$enable_static_exe = x_yes; then
1286         staticexe="-static"
1287         if test "$on_mingw" = yes; then
1288                 staticexe="-all-static"
1289                 # for static compile, include gdi32 and zlib here.
1290                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1291                         :
1292                 else
1293                         LIBS="$LIBS -lgdi32"
1294                 fi
1295                 LIBS="$LIBS -lz"
1296         fi
1297 fi
1298
1299 # Include systemd.m4 - begin
1300 sinclude(systemd.m4)
1301 # Include systemd.m4 - end
1302
1303 # set lock checking if requested
1304 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1305         [ enable to check lock and unlock calls, for debug purposes ]),
1306         , )
1307 if test x_$enable_lock_checks = x_yes; then
1308         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1309         CHECKLOCK_OBJ="checklocks.lo"
1310         AC_SUBST(CHECKLOCK_OBJ)
1311 fi
1312
1313 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1314 if test "$USE_WINSOCK" = 1; then
1315         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1316         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1317 #include <windows.h>
1318         ])
1319         AC_CHECK_TOOL(WINDRES, windres)
1320         LIBS="$LIBS -liphlpapi -lcrypt32"
1321         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1322         AC_SUBST(WINAPPS)
1323         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1324         AC_SUBST(WIN_DAEMON_SRC)
1325         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1326         AC_SUBST(WIN_DAEMON_OBJ)
1327         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1328         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1329         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1330         AC_SUBST(WIN_HOST_OBJ_LINK)
1331         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1332         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1333         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1334         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1335         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1336         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1337 fi
1338 if test $ac_cv_func_getaddrinfo = no; then
1339         AC_LIBOBJ([fake-rfc2553])
1340 fi
1341 # check after getaddrinfo for its libraries
1342 ACX_FUNC_IOCTLSOCKET
1343
1344 # see if daemon(3) exists, and if it is deprecated.
1345 AC_CHECK_FUNCS([daemon])
1346 if test $ac_cv_func_daemon = yes; then
1347         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1348 #include <stdlib.h>
1349 ])
1350 fi
1351
1352 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1353 AC_INCLUDES_DEFAULT
1354 #ifdef HAVE_SYS_UN_H
1355 #include <sys/un.h>
1356 #endif
1357 ])
1358 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1359 AC_INCLUDES_DEFAULT
1360 #if HAVE_SYS_PARAM_H
1361 #include <sys/param.h>
1362 #endif
1363
1364 #ifdef HAVE_SYS_SOCKET_H
1365 #include <sys/socket.h>
1366 #endif
1367
1368 #ifdef HAVE_SYS_UIO_H
1369 #include <sys/uio.h>
1370 #endif
1371
1372 #ifdef HAVE_NETINET_IN_H
1373 #include <netinet/in.h>
1374 #endif
1375
1376 #ifdef HAVE_NETINET_TCP_H
1377 #include <netinet/tcp.h>
1378 #endif
1379
1380 #ifdef HAVE_ARPA_INET_H
1381 #include <arpa/inet.h>
1382 #endif
1383
1384 #ifdef HAVE_WINSOCK2_H
1385 #include <winsock2.h>
1386 #endif
1387
1388 #ifdef HAVE_WS2TCPIP_H
1389 #include <ws2tcpip.h>
1390 #endif
1391 ])
1392 AC_SEARCH_LIBS([setusercontext], [util])
1393 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget accept4])
1394 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1395 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1396
1397 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1398 if echo $target_os | grep darwin8 > /dev/null; then
1399         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1400 fi
1401 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1402 AC_INCLUDES_DEFAULT
1403 #ifdef HAVE_NETINET_IN_H
1404 #include <netinet/in.h>
1405 #endif
1406
1407 #ifdef HAVE_NETINET_TCP_H
1408 #include <netinet/tcp.h>
1409 #endif
1410
1411 #ifdef HAVE_ARPA_INET_H
1412 #include <arpa/inet.h>
1413 #endif
1414
1415 #ifdef HAVE_WINSOCK2_H
1416 #include <winsock2.h>
1417 #endif
1418
1419 #ifdef HAVE_WS2TCPIP_H
1420 #include <ws2tcpip.h>
1421 #endif
1422 ])
1423 AC_REPLACE_FUNCS(inet_aton)
1424 AC_REPLACE_FUNCS(inet_pton)
1425 AC_REPLACE_FUNCS(inet_ntop)
1426 AC_REPLACE_FUNCS(snprintf)
1427 # test if snprintf return the proper length
1428 if test "x$ac_cv_func_snprintf" = xyes; then
1429     if test c${cross_compiling} = cno; then
1430         AC_MSG_CHECKING([for correct snprintf return value])
1431         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1432 [[
1433 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1434 ]])], [AC_MSG_RESULT(yes)], [
1435                 AC_MSG_RESULT(no)
1436                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1437                 AC_LIBOBJ(snprintf)
1438           ])
1439     fi
1440 fi
1441 AC_REPLACE_FUNCS(strlcat)
1442 AC_REPLACE_FUNCS(strlcpy)
1443 AC_REPLACE_FUNCS(memmove)
1444 AC_REPLACE_FUNCS(gmtime_r)
1445 AC_REPLACE_FUNCS(isblank)
1446 AC_REPLACE_FUNCS(explicit_bzero)
1447 dnl without CTIME, ARC4-functions and without reallocarray.
1448 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1449 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1450 AC_MSG_CHECKING([for reallocarray])
1451 AC_LINK_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1452 [[
1453 #ifndef _OPENBSD_SOURCE
1454 #define _OPENBSD_SOURCE 1
1455 #endif
1456 #include <stdlib.h>
1457 int main(void) {
1458         void* p = reallocarray(NULL, 10, 100);
1459         free(p);
1460         return 0;
1461 }
1462 ]])], [AC_MSG_RESULT(yes)
1463         AC_DEFINE(HAVE_REALLOCARRAY, 1, [If we have reallocarray(3)])
1464 ], [
1465         AC_MSG_RESULT(no)
1466         AC_LIBOBJ(reallocarray)
1467 ])
1468 if test "$USE_NSS" = "no"; then
1469         AC_REPLACE_FUNCS(arc4random)
1470         AC_REPLACE_FUNCS(arc4random_uniform)
1471         if test "$ac_cv_func_arc4random" = "no"; then
1472                 AC_LIBOBJ(arc4_lock)
1473                 AC_CHECK_FUNCS([getentropy],,[
1474                     if test "$USE_WINSOCK" = 1; then
1475                         AC_LIBOBJ(getentropy_win)
1476                     else
1477                         case "$host" in
1478                         Darwin|*darwin*)
1479                                 AC_LIBOBJ(getentropy_osx)
1480                         ;;
1481                         *solaris*|*sunos*|SunOS)
1482                                 AC_LIBOBJ(getentropy_solaris)
1483                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1484                                         AC_CHECK_FUNCS([SHA512_Update],,[
1485                                                 AC_LIBOBJ(sha512)
1486                                         ])
1487                                 ], [AC_INCLUDES_DEFAULT])
1488                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1489                                         # this lib needed for sha2 on solaris
1490                                         LIBS="$LIBS -lmd"
1491                                 fi
1492                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1493                         ;;
1494                         *linux*|Linux|*)
1495                                 AC_LIBOBJ(getentropy_linux)
1496                                 AC_CHECK_FUNCS([SHA512_Update],,[
1497                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1498                                         AC_LIBOBJ(sha512)
1499                                 ])
1500                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1501                                 AC_CHECK_FUNCS([getauxval])
1502                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1503                         ;;
1504                         esac
1505                     fi
1506                 ])
1507         fi
1508 fi
1509 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1510 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1511 AC_REPLACE_FUNCS(ctime_r)
1512 AC_REPLACE_FUNCS(strsep)
1513
1514 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1515 case "$enable_allsymbols" in
1516         yes)
1517         COMMON_OBJ_ALL_SYMBOLS=""
1518         UBSYMS=""
1519         EXTRALINK="-L. -L.libs -lunbound"
1520         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1521         ;;
1522         no|*)
1523         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1524         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1525         EXTRALINK=""
1526         ;;
1527 esac
1528 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1529 AC_SUBST(EXTRALINK)
1530 AC_SUBST(UBSYMS)
1531 if test x_$enable_lock_checks = x_yes; then
1532         UBSYMS="-export-symbols clubsyms.def"
1533         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1534         echo lock_protect >> clubsyms.def
1535         echo lock_unprotect >> clubsyms.def
1536         echo lock_get_mem >> clubsyms.def
1537         echo checklock_start >> clubsyms.def
1538         echo checklock_stop >> clubsyms.def
1539         echo checklock_lock >> clubsyms.def
1540         echo checklock_unlock >> clubsyms.def
1541         echo checklock_init >> clubsyms.def
1542         echo checklock_thrcreate >> clubsyms.def
1543         echo checklock_thrjoin >> clubsyms.def
1544 fi
1545
1546 # check for dnstap if requested
1547 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1548     [
1549         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1550         AC_SUBST([ENABLE_DNSTAP], [1])
1551
1552         AC_SUBST([opt_dnstap_socket_path])
1553         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1554         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1555             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1556
1557         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1558         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1559     ],
1560     [
1561         AC_SUBST([ENABLE_DNSTAP], [0])
1562     ]
1563 )
1564
1565 # check for dnscrypt if requested
1566 dnsc_DNSCRYPT([
1567         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1568         AC_SUBST([ENABLE_DNSCRYPT], [1])
1569
1570         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1571         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1572     ],
1573     [
1574         AC_SUBST([ENABLE_DNSCRYPT], [0])
1575     ]
1576 )
1577
1578 # check for cachedb if requested
1579 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1580 # turn on cachedb when hiredis support is enabled.
1581 if test "$found_libhiredis" = "yes"; then enable_cachedb="yes"; fi
1582 case "$enable_cachedb" in
1583     yes)
1584         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1585         ;;
1586     no|*)
1587         # nothing
1588         ;;
1589 esac
1590
1591 # check for ipsecmod if requested
1592 AC_ARG_ENABLE(ipsecmod, AC_HELP_STRING([--enable-ipsecmod], [Enable ipsecmod module that facilitates opportunistic IPsec]))
1593 case "$enable_ipsecmod" in
1594         yes)
1595                 AC_DEFINE([USE_IPSECMOD], [1], [Define to 1 to use ipsecmod support.])
1596                 IPSECMOD_OBJ="ipsecmod.lo ipsecmod-whitelist.lo"
1597                 AC_SUBST(IPSECMOD_OBJ)
1598                 IPSECMOD_HEADER='$(srcdir)/ipsecmod/ipsecmod.h $(srcdir)/ipsecmod/ipsecmod-whitelist.h'
1599                 AC_SUBST(IPSECMOD_HEADER)
1600                 ;;
1601         no|*)
1602                 # nothing
1603                 ;;
1604 esac
1605
1606 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1607 # on openBSD, the implicit rule make $< work.
1608 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1609 # gmake works.
1610 cat >conftest.make <<EOF
1611 all:    conftest.lo
1612
1613 conftest.lo foo.lo bla.lo:
1614         if test -f "\$<"; then touch \$@; fi
1615
1616 .SUFFIXES: .lo
1617 .c.lo:
1618         if test -f "\$<"; then touch \$@; fi
1619
1620 conftest.lo:        conftest.dir/conftest.c
1621 EOF
1622 mkdir conftest.dir
1623 touch conftest.dir/conftest.c
1624 rm -f conftest.lo conftest.c
1625 ${MAKE:-make} -f conftest.make >/dev/null
1626 rm -f conftest.make conftest.c conftest.dir/conftest.c
1627 rm -rf conftest.dir
1628 if test ! -f conftest.lo; then
1629         AC_MSG_RESULT(no)
1630         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1631         SOURCEFILE='`cat .source`'
1632 else
1633         AC_MSG_RESULT(yes)
1634         SOURCEDETERMINE=':'
1635         SOURCEFILE='$<'
1636 fi
1637 rm -f conftest.lo
1638 AC_SUBST(SOURCEDETERMINE)
1639 AC_SUBST(SOURCEFILE)
1640
1641 # see if we want to build the library or everything
1642 ALLTARGET="alltargets"
1643 INSTALLTARGET="install-all"
1644 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1645         [do not build daemon and tool programs]),
1646         [
1647         if test "$withval" = "yes"; then
1648                 ALLTARGET="lib"
1649                 INSTALLTARGET="install-lib"
1650         fi
1651 ])
1652 if test $ALLTARGET = "alltargets"; then
1653         if test $USE_NSS = "yes"; then
1654                 AC_ERROR([--with-nss can only be used in combination with --with-libunbound-only.])
1655         fi
1656         if test $USE_NETTLE = "yes"; then
1657                 AC_ERROR([--with-nettle can only be used in combination with --with-libunbound-only.])
1658         fi
1659 fi
1660
1661 AC_SUBST(ALLTARGET)
1662 AC_SUBST(INSTALLTARGET)
1663
1664 ACX_STRIP_EXT_FLAGS
1665 if test -n "$LATE_LDFLAGS"; then
1666   LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1667 fi
1668 # remove start spaces
1669 LDFLAGS=`echo "$LDFLAGS"|sed -e 's/^ *//'`
1670 LIBS=`echo "$LIBS"|sed -e 's/^ *//'`
1671
1672 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1673
1674 AH_BOTTOM(
1675 dnl this must be first AH_CONFIG, to define the flags before any includes.
1676 AHX_CONFIG_EXT_FLAGS
1677
1678 dnl includes
1679 [
1680 #ifndef _OPENBSD_SOURCE
1681 #define _OPENBSD_SOURCE 1
1682 #endif
1683
1684 #ifndef UNBOUND_DEBUG
1685 # ifndef NDEBUG
1686 #  define NDEBUG
1687 # endif
1688 #endif
1689
1690 /** Use small-ldns codebase */
1691 #define USE_SLDNS 1
1692 #ifdef HAVE_SSL
1693 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1694 #endif
1695
1696 #include <stdio.h>
1697 #include <string.h>
1698 #include <unistd.h>
1699 #include <assert.h>
1700
1701 #if STDC_HEADERS
1702 #include <stdlib.h>
1703 #include <stddef.h>
1704 #endif
1705
1706 #ifdef HAVE_STDARG_H
1707 #include <stdarg.h>
1708 #endif
1709
1710 #ifdef HAVE_STDINT_H
1711 #include <stdint.h>
1712 #endif
1713
1714 #include <errno.h>
1715
1716 #if HAVE_SYS_PARAM_H
1717 #include <sys/param.h>
1718 #endif
1719
1720 #ifdef HAVE_SYS_SOCKET_H
1721 #include <sys/socket.h>
1722 #endif
1723
1724 #ifdef HAVE_SYS_UIO_H
1725 #include <sys/uio.h>
1726 #endif
1727
1728 #ifdef HAVE_NETINET_IN_H
1729 #include <netinet/in.h>
1730 #endif
1731
1732 #ifdef HAVE_NETINET_TCP_H
1733 #include <netinet/tcp.h>
1734 #endif
1735
1736 #ifdef HAVE_ARPA_INET_H
1737 #include <arpa/inet.h>
1738 #endif
1739
1740 #ifdef HAVE_WINSOCK2_H
1741 #include <winsock2.h>
1742 #endif
1743
1744 #ifdef HAVE_WS2TCPIP_H
1745 #include <ws2tcpip.h>
1746 #endif
1747
1748 #ifndef USE_WINSOCK
1749 #define ARG_LL "%ll"
1750 #else
1751 #define ARG_LL "%I64"
1752 #endif
1753
1754 #ifndef AF_LOCAL
1755 #define AF_LOCAL AF_UNIX
1756 #endif
1757 ]
1758
1759 AHX_CONFIG_FORMAT_ATTRIBUTE
1760 AHX_CONFIG_UNUSED_ATTRIBUTE
1761 AHX_CONFIG_FSEEKO
1762 AHX_CONFIG_MAXHOSTNAMELEN
1763 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1764 #define snprintf snprintf_unbound
1765 #define vsnprintf vsnprintf_unbound
1766 #include <stdarg.h>
1767 int snprintf (char *str, size_t count, const char *fmt, ...);
1768 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1769 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1770 AHX_CONFIG_INET_PTON(unbound)
1771 AHX_CONFIG_INET_NTOP(unbound)
1772 AHX_CONFIG_INET_ATON(unbound)
1773 AHX_CONFIG_MEMMOVE(unbound)
1774 AHX_CONFIG_STRLCAT(unbound)
1775 AHX_CONFIG_STRLCPY(unbound)
1776 AHX_CONFIG_GMTIME_R(unbound)
1777 AHX_CONFIG_REALLOCARRAY(unbound)
1778 AHX_CONFIG_W32_SLEEP
1779 AHX_CONFIG_W32_USLEEP
1780 AHX_CONFIG_W32_RANDOM
1781 AHX_CONFIG_W32_SRANDOM
1782 AHX_CONFIG_W32_FD_SET_T
1783 AHX_CONFIG_IPV6_MIN_MTU
1784 AHX_MEMCMP_BROKEN(unbound)
1785
1786 [
1787 #ifndef HAVE_CTIME_R
1788 #define ctime_r unbound_ctime_r
1789 char *ctime_r(const time_t *timep, char *buf);
1790 #endif
1791
1792 #ifndef HAVE_STRSEP
1793 #define strsep unbound_strsep
1794 char *strsep(char **stringp, const char *delim);
1795 #endif
1796
1797 #ifndef HAVE_ISBLANK
1798 #define isblank unbound_isblank
1799 int isblank(int c);
1800 #endif
1801
1802 #ifndef HAVE_EXPLICIT_BZERO
1803 #define explicit_bzero unbound_explicit_bzero
1804 void explicit_bzero(void* buf, size_t len);
1805 #endif
1806
1807 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
1808 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
1809 #endif
1810
1811 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
1812 int inet_pton(int af, const char* src, void* dst);
1813 #endif
1814
1815 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1816 #define strptime unbound_strptime
1817 struct tm;
1818 char *strptime(const char *s, const char *format, struct tm *tm);
1819 #endif
1820
1821 #ifdef HAVE_LIBRESSL
1822 #  if !HAVE_DECL_STRLCPY
1823 size_t strlcpy(char *dst, const char *src, size_t siz);
1824 #  endif
1825 #  if !HAVE_DECL_STRLCAT
1826 size_t strlcat(char *dst, const char *src, size_t siz);
1827 #  endif
1828 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
1829 uint32_t arc4random(void);
1830 #  endif
1831 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
1832 uint32_t arc4random_uniform(uint32_t upper_bound);
1833 #  endif
1834 #  if !HAVE_DECL_REALLOCARRAY
1835 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1836 #  endif
1837 #endif /* HAVE_LIBRESSL */
1838 #ifndef HAVE_ARC4RANDOM
1839 int getentropy(void* buf, size_t len);
1840 uint32_t arc4random(void);
1841 void arc4random_buf(void* buf, size_t n);
1842 void _ARC4_LOCK(void);
1843 void _ARC4_UNLOCK(void);
1844 void _ARC4_LOCK_DESTROY(void);
1845 #endif
1846 #ifndef HAVE_ARC4RANDOM_UNIFORM
1847 uint32_t arc4random_uniform(uint32_t upper_bound);
1848 #endif
1849 #ifdef COMPAT_SHA512
1850 #ifndef SHA512_DIGEST_LENGTH
1851 #define SHA512_BLOCK_LENGTH             128
1852 #define SHA512_DIGEST_LENGTH            64
1853 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
1854 typedef struct _SHA512_CTX {
1855         uint64_t        state[8];
1856         uint64_t        bitcount[2];
1857         uint8_t buffer[SHA512_BLOCK_LENGTH];
1858 } SHA512_CTX;
1859 #endif /* SHA512_DIGEST_LENGTH */
1860 void SHA512_Init(SHA512_CTX*);
1861 void SHA512_Update(SHA512_CTX*, void*, size_t);
1862 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
1863 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
1864 #endif /* COMPAT_SHA512 */
1865
1866
1867
1868 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1869    /* using version of libevent that is not threadsafe. */
1870 #  define LIBEVENT_SIGNAL_PROBLEM 1
1871 #endif
1872
1873 #ifndef CHECKED_INET6
1874 #  define CHECKED_INET6
1875 #  ifdef AF_INET6
1876 #    define INET6
1877 #  else
1878 #    define AF_INET6        28
1879 #  endif
1880 #endif /* CHECKED_INET6 */
1881
1882 #ifndef HAVE_GETADDRINFO
1883 struct sockaddr_storage;
1884 #include "compat/fake-rfc2553.h"
1885 #endif
1886
1887 #ifdef UNBOUND_ALLOC_STATS
1888 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1889 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1890 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1891 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1892 void *unbound_stat_malloc(size_t size);
1893 void *unbound_stat_calloc(size_t nmemb, size_t size);
1894 void unbound_stat_free(void *ptr);
1895 void *unbound_stat_realloc(void *ptr, size_t size);
1896 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1897         const char* func);
1898 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1899         int line, const char* func);
1900 void unbound_stat_free_log(void *ptr, const char* file, int line,
1901         const char* func);
1902 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1903         int line, const char* func);
1904 #elif defined(UNBOUND_ALLOC_LITE)
1905 #  include "util/alloc.h"
1906 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1907
1908 /** default port for DNS traffic. */
1909 #define UNBOUND_DNS_PORT 53
1910 /** default port for DNS over TLS traffic. */
1911 #define UNBOUND_DNS_OVER_TLS_PORT 853
1912 /** default port for unbound control traffic, registered port with IANA,
1913     ub-dns-control  8953/tcp    unbound dns nameserver control */
1914 #define UNBOUND_CONTROL_PORT 8953
1915 /** the version of unbound-control that this software implements */
1916 #define UNBOUND_CONTROL_VERSION 1
1917
1918 ])
1919
1920 dnl if we build from source tree, the man pages need @date@ and @version@
1921 dnl if this is a distro tarball, that was already done by makedist.sh
1922 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
1923 AC_SUBST(date, [`date +'%b %e, %Y'`])
1924
1925 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service])
1926 AC_CONFIG_HEADER([config.h])
1927 AC_OUTPUT