contrib/tzdata/leapseconds.awk

   1 # Generate zic format 'leapseconds' from NIST format 'leap-seconds.list'.
   2
   3 # This file is in the public domain.
   4
   5 # This program uses awk arithmetic.  POSIX requires awk to support
   6 # exact integer arithmetic only through 10**10, which means for NTP
   7 # timestamps this program works only to the year 2216, which is the
   8 # year 1900 plus 10**10 seconds.  However, in practice
   9 # POSIX-conforming awk implementations invariably use IEEE-754 double
  10 # and so support exact integers through 2**53.  By the year 2216,
  11 # POSIX will almost surely require at least 2**53 for awk, so for NTP
  12 # timestamps this program should be good until the year 285,428,681
  13 # (the year 1900 plus 2**53 seconds).  By then leap seconds will be
  14 # long obsolete, as the Earth will likely slow down so much that
  15 # there will be more than 25 hours per day and so some other scheme
  16 # will be needed.
  17
  18 BEGIN {
  19   print "# Allowance for leap seconds added to each time zone file."
  20   print ""
  21   print "# This file is in the public domain."
  22   print ""
  23   print "# This file is generated automatically from the data in the public-domain"
  24   print "# NIST format leap-seconds.list file, which can be copied from"
  25   print "# <ftp://ftp.nist.gov/pub/time/leap-seconds.list>"
  26   print "# or <ftp://ftp.boulder.nist.gov/pub/time/leap-seconds.list>."
  27   print "# For more about leap-seconds.list, please see"
  28   print "# The NTP Timescale and Leap Seconds"
  29   print "# <https://www.eecis.udel.edu/~mills/leap.html>."
  30   print ""
  31   print "# The rules for leap seconds are specified in Annex 1 (Time scales) of:"
  32   print "# Standard-frequency and time-signal emissions."
  33   print "# International Telecommunication Union - Radiocommunication Sector"
  34   print "# (ITU-R) Recommendation TF.460-6 (02/2002)"
  35   print "# <https://www.itu.int/rec/R-REC-TF.460-6-200202-I/>."
  36   print "# The International Earth Rotation and Reference Systems Service (IERS)"
  37   print "# periodically uses leap seconds to keep UTC to within 0.9 s of UT1"
  38   print "# (a proxy for Earth's angle in space as measured by astronomers)"
  39   print "# and publishes leap second data in a copyrighted file"
  40   print "# <https://hpiers.obspm.fr/iers/bul/bulc/Leap_Second.dat>."
  41   print "# See: Levine J. Coordinated Universal Time and the leap second."
  42   print "# URSI Radio Sci Bull. 2016;89(4):30-6. doi:10.23919/URSIRSB.2016.7909995"
  43   print "# <https://ieeexplore.ieee.org/document/7909995>."
  44   print ""
  45   print "# There were no leap seconds before 1972, as no official mechanism"
  46   print "# accounted for the discrepancy between atomic time (TAI) and the earth's"
  47   print "# rotation.  The first (\"1 Jan 1972\") data line in leap-seconds.list"
  48   print "# does not denote a leap second; it denotes the start of the current definition"
  49   print "# of UTC."
  50   print ""
  51   print "# All leap-seconds are Stationary (S) at the given UTC time."
  52   print "# The correction (+ or -) is made at the given time, so in the unlikely"
  53   print "# event of a negative leap second, a line would look like this:"
  54   print "# Leap YEAR    MON     DAY     23:59:59        -       S"
  55   print "# Typical lines look like this:"
  56   print "# Leap YEAR    MON     DAY     23:59:60        +       S"
  57
  58   monthabbr[ 1] = "Jan"
  59   monthabbr[ 2] = "Feb"
  60   monthabbr[ 3] = "Mar"
  61   monthabbr[ 4] = "Apr"
  62   monthabbr[ 5] = "May"
  63   monthabbr[ 6] = "Jun"
  64   monthabbr[ 7] = "Jul"
  65   monthabbr[ 8] = "Aug"
  66   monthabbr[ 9] = "Sep"
  67   monthabbr[10] = "Oct"
  68   monthabbr[11] = "Nov"
  69   monthabbr[12] = "Dec"
  70
  71   sstamp_init()
  72 }
  73
  74 # In case the input has CRLF form a la NIST.
  75 { sub(/\r$/, "") }
  76
  77 /^#[ \t]*[Uu]pdated through/ || /^#[ \t]*[Ff]ile expires on/ {
  78     last_lines = last_lines $0 "\n"
  79 }
  80
  81 /^#[$][ \t]/ { updated = $2 }
  82 /^#[@][ \t]/ { expires = $2 }
  83
  84 /^[ \t]*#/ { next }
  85
  86 {
  87     NTP_timestamp = $1
  88     TAI_minus_UTC = $2
  89     if (old_TAI_minus_UTC) {
  90         if (old_TAI_minus_UTC < TAI_minus_UTC) {
  91             sign = "23:59:60\t+"
  92         } else {
  93             sign = "23:59:59\t-"
  94         }
  95         sstamp_to_ymdhMs(NTP_timestamp - 1, ss_NTP)
  96         printf "Leap\t%d\t%s\t%d\t%s\tS\n", \
  97           ss_year, monthabbr[ss_month], ss_mday, sign
  98     }
  99     old_TAI_minus_UTC = TAI_minus_UTC
 100 }
 101
 102 END {
 103     sstamp_to_ymdhMs(expires, ss_NTP)
 104
 105     print ""
 106     print "# UTC timestamp when this leap second list expires."
 107     print "# Any additional leap seconds will come after this."
 108     if (! EXPIRES_LINE) {
 109       print "# This Expires line is commented out for now,"
 110       print "# so that pre-2020a zic implementations do not reject this file."
 111     }
 112     printf "%sExpires %.4d\t%s\t%.2d\t%.2d:%.2d:%.2d\n", \
 113       EXPIRES_LINE ? "" : "#", \
 114       ss_year, monthabbr[ss_month], ss_mday, ss_hour, ss_min, ss_sec
 115
 116     # The difference between the NTP and POSIX epochs is 70 years
 117     # (including 17 leap days), each 24 hours of 60 minutes of 60
 118     # seconds each.
 119     epoch_minus_NTP = ((1970 - 1900) * 365 + 17) * 24 * 60 * 60
 120
 121     print ""
 122     print "# POSIX timestamps for the data in this file:"
 123     sstamp_to_ymdhMs(updated, ss_NTP)
 124     printf "#updated %d (%.4d-%.2d-%.2d %.2d:%.2d:%.2d UTC)\n", \
 125       updated - epoch_minus_NTP, \
 126       ss_year, ss_month, ss_mday, ss_hour, ss_min, ss_sec
 127     sstamp_to_ymdhMs(expires, ss_NTP)
 128     printf "#expires %d (%.4d-%.2d-%.2d %.2d:%.2d:%.2d UTC)\n", \
 129       expires - epoch_minus_NTP, \
 130       ss_year, ss_month, ss_mday, ss_hour, ss_min, ss_sec
 131
 132     printf "\n%s", last_lines
 133 }
 134
 135 # sstamp_to_ymdhMs - convert seconds timestamp to date and time
 136 #
 137 # Call as:
 138 #
 139 #    sstamp_to_ymdhMs(sstamp, epoch_days)
 140 #
 141 # where:
 142 #
 143 #    sstamp - is the seconds timestamp.
 144 #    epoch_days - is the timestamp epoch in Gregorian days since 1600-03-01.
 145 #       ss_NTP is appropriate for an NTP sstamp.
 146 #
 147 # Both arguments should be nonnegative integers.
 148 # On return, the following variables are set based on sstamp:
 149 #
 150 #    ss_year    - Gregorian calendar year
 151 #    ss_month   - month of the year (1-January to 12-December)
 152 #    ss_mday    - day of the month (1-31)
 153 #    ss_hour    - hour (0-23)
 154 #    ss_min     - minute (0-59)
 155 #    ss_sec     - second (0-59)
 156 #    ss_wday    - day of week (0-Sunday to 6-Saturday)
 157 #
 158 # The function sstamp_init should be called prior to using sstamp_to_ymdhMs.
 159
 160 function sstamp_init()
 161 {
 162   # Days in month N, where March is month 0 and January month 10.
 163   ss_mon_days[ 0] = 31
 164   ss_mon_days[ 1] = 30
 165   ss_mon_days[ 2] = 31
 166   ss_mon_days[ 3] = 30
 167   ss_mon_days[ 4] = 31
 168   ss_mon_days[ 5] = 31
 169   ss_mon_days[ 6] = 30
 170   ss_mon_days[ 7] = 31
 171   ss_mon_days[ 8] = 30
 172   ss_mon_days[ 9] = 31
 173   ss_mon_days[10] = 31
 174
 175   # Counts of days in a Gregorian year, quad-year, century, and quad-century.
 176   ss_year_days = 365
 177   ss_quadyear_days = ss_year_days * 4 + 1
 178   ss_century_days = ss_quadyear_days * 25 - 1
 179   ss_quadcentury_days = ss_century_days * 4 + 1
 180
 181   # Standard day epochs, suitable for epoch_days.
 182   # ss_MJD = 94493
 183   # ss_POSIX = 135080
 184   ss_NTP = 109513
 185 }
 186
 187 function sstamp_to_ymdhMs(sstamp, epoch_days, \
 188                           quadcentury, century, quadyear, year, month, day)
 189 {
 190   ss_hour = int(sstamp / 3600) % 24
 191   ss_min = int(sstamp / 60) % 60
 192   ss_sec = sstamp % 60
 193
 194   # Start with a count of days since 1600-03-01 Gregorian.
 195   day = epoch_days + int(sstamp / (24 * 60 * 60))
 196
 197   # Compute a year-month-day date with days of the month numbered
 198   # 0-30, months (March-February) numbered 0-11, and years that start
 199   # start March 1 and end after the last day of February.  A quad-year
 200   # starts on March 1 of a year evenly divisible by 4 and ends after
 201   # the last day of February 4 years later.  A century starts on and
 202   # ends before March 1 in years evenly divisible by 100.
 203   # A quad-century starts on and ends before March 1 in years divisible
 204   # by 400.  While the number of days in a quad-century is a constant,
 205   # the number of days in each other time period can vary by 1.
 206   # Any variation is in the last day of the time period (there might
 207   # or might not be a February 29) where it is easy to deal with.
 208
 209   quadcentury = int(day / ss_quadcentury_days)
 210   day -= quadcentury * ss_quadcentury_days
 211   ss_wday = (day + 3) % 7
 212   century = int(day / ss_century_days)
 213   century -= century == 4
 214   day -= century * ss_century_days
 215   quadyear = int(day / ss_quadyear_days)
 216   day -= quadyear * ss_quadyear_days
 217   year = int(day / ss_year_days)
 218   year -= year == 4
 219   day -= year * ss_year_days
 220   for (month = 0; month < 11; month++) {
 221     if (day < ss_mon_days[month])
 222       break
 223     day -= ss_mon_days[month]
 224   }
 225
 226   # Convert the date to a conventional day of month (1-31),
 227   # month (1-12, January-December) and Gregorian year.
 228   ss_mday = day + 1
 229   if (month <= 9) {
 230     ss_month = month + 3
 231   } else {
 232     ss_month = month - 9
 233     year++
 234   }
 235   ss_year = 1600 + quadcentury * 400 + century * 100 + quadyear * 4 + year
 236 }