contrib/tzdata/leapseconds.awk

   1 # Generate zic format 'leapseconds' from NIST format 'leap-seconds.list'.
   2
   3 # This file is in the public domain.
   4
   5 # This program uses awk arithmetic.  POSIX requires awk to support
   6 # exact integer arithmetic only through 10**10, which means for NTP
   7 # timestamps this program works only to the year 2216, which is the
   8 # year 1900 plus 10**10 seconds.  However, in practice
   9 # POSIX-conforming awk implementations invariably use IEEE-754 double
  10 # and so support exact integers through 2**53.  By the year 2216,
  11 # POSIX will almost surely require at least 2**53 for awk, so for NTP
  12 # timestamps this program should be good until the year 285,428,681
  13 # (the year 1900 plus 2**53 seconds).  By then leap seconds will be
  14 # long obsolete, as the Earth will likely slow down so much that
  15 # there will be more than 25 hours per day and so some other scheme
  16 # will be needed.
  17
  18 BEGIN {
  19   print "# Allowance for leap seconds added to each time zone file."
  20   print ""
  21   print "# This file is in the public domain."
  22   print ""
  23   print "# This file is generated automatically from the data in the public-domain"
  24   print "# NIST format leap-seconds.list file, which can be copied from"
  25   print "# <ftp://ftp.nist.gov/pub/time/leap-seconds.list>"
  26   print "# or <ftp://ftp.boulder.nist.gov/pub/time/leap-seconds.list>."
  27   print "# For more about leap-seconds.list, please see"
  28   print "# The NTP Timescale and Leap Seconds"
  29   print "# <https://www.eecis.udel.edu/~mills/leap.html>."
  30   print ""
  31   print "# The rules for leap seconds are specified in Annex 1 (Time scales) of:"
  32   print "# Standard-frequency and time-signal emissions."
  33   print "# International Telecommunication Union - Radiocommunication Sector"
  34   print "# (ITU-R) Recommendation TF.460-6 (02/2002)"
  35   print "# <https://www.itu.int/rec/R-REC-TF.460-6-200202-I/>."
  36   print "# The International Earth Rotation and Reference Systems Service (IERS)"
  37   print "# periodically uses leap seconds to keep UTC to within 0.9 s of UT1"
  38   print "# (a proxy for Earth's angle in space as measured by astronomers)"
  39   print "# and publishes leap second data in a copyrighted file"
  40   print "# <https://hpiers.obspm.fr/iers/bul/bulc/Leap_Second.dat>."
  41   print "# See: Levine J. Coordinated Universal Time and the leap second."
  42   print "# URSI Radio Sci Bull. 2016;89(4):30-6. doi:10.23919/URSIRSB.2016.7909995"
  43   print "# <https://ieeexplore.ieee.org/document/7909995>."
  44   print ""
  45   print "# There were no leap seconds before 1972, as no official mechanism"
  46   print "# accounted for the discrepancy between atomic time (TAI) and the earth's"
  47   print "# rotation.  The first (\"1 Jan 1972\") data line in leap-seconds.list"
  48   print "# does not denote a leap second; it denotes the start of the current definition"
  49   print "# of UTC."
  50   print ""
  51   print "# All leap-seconds are Stationary (S) at the given UTC time."
  52   print "# The correction (+ or -) is made at the given time, so in the unlikely"
  53   print "# event of a negative leap second, a line would look like this:"
  54   print "# Leap YEAR    MON     DAY     23:59:59        -       S"
  55   print "# Typical lines look like this:"
  56   print "# Leap YEAR    MON     DAY     23:59:60        +       S"
  57
  58   monthabbr[ 1] = "Jan"
  59   monthabbr[ 2] = "Feb"
  60   monthabbr[ 3] = "Mar"
  61   monthabbr[ 4] = "Apr"
  62   monthabbr[ 5] = "May"
  63   monthabbr[ 6] = "Jun"
  64   monthabbr[ 7] = "Jul"
  65   monthabbr[ 8] = "Aug"
  66   monthabbr[ 9] = "Sep"
  67   monthabbr[10] = "Oct"
  68   monthabbr[11] = "Nov"
  69   monthabbr[12] = "Dec"
  70
  71   sstamp_init()
  72 }
  73
  74 # In case the input has CRLF form a la NIST.
  75 { sub(/\r$/, "") }
  76
  77 /^#[ \t]*[Uu]pdated through/ || /^#[ \t]*[Ff]ile expires on/ {
  78     last_lines = last_lines $0 "\n"
  79 }
  80
  81 /^#[$][ \t]/ { updated = $2 }
  82 /^#[@][ \t]/ { expires = $2 }
  83
  84 /^[ \t]*#/ { next }
  85
  86 {
  87     NTP_timestamp = $1
  88     TAI_minus_UTC = $2
  89     if (old_TAI_minus_UTC) {
  90         if (old_TAI_minus_UTC < TAI_minus_UTC) {
  91             sign = "23:59:60\t+"
  92         } else {
  93             sign = "23:59:59\t-"
  94         }
  95         sstamp_to_ymdhMs(NTP_timestamp - 1, ss_NTP)
  96         printf "Leap\t%d\t%s\t%d\t%s\tS\n", \
  97           ss_year, monthabbr[ss_month], ss_mday, sign
  98     }
  99     old_TAI_minus_UTC = TAI_minus_UTC
 100 }
 101
 102 END {
 103     sstamp_to_ymdhMs(expires, ss_NTP)
 104
 105     print ""
 106     print "# UTC timestamp when this leap second list expires."
 107     print "# Any additional leap seconds will come after this."
 108     print "# This Expires line is commented out for now,"
 109     print "# so that pre-2020a zic implementations do not reject this file."
 110     printf "%sExpires %.4d\t%s\t%.2d\t%.2d:%.2d:%.2d\n", \
 111       EXPIRES_LINE ? "" : "#", \
 112       ss_year, monthabbr[ss_month], ss_mday, ss_hour, ss_min, ss_sec
 113
 114     # The difference between the NTP and POSIX epochs is 70 years
 115     # (including 17 leap days), each 24 hours of 60 minutes of 60
 116     # seconds each.
 117     epoch_minus_NTP = ((1970 - 1900) * 365 + 17) * 24 * 60 * 60
 118
 119     print ""
 120     print "# POSIX timestamps for the data in this file:"
 121     sstamp_to_ymdhMs(updated, ss_NTP)
 122     printf "#updated %d (%.4d-%.2d-%.2d %.2d:%.2d:%.2d UTC)\n", \
 123       updated - epoch_minus_NTP, \
 124       ss_year, ss_month, ss_mday, ss_hour, ss_min, ss_sec
 125     sstamp_to_ymdhMs(expires, ss_NTP)
 126     printf "#expires %d (%.4d-%.2d-%.2d %.2d:%.2d:%.2d UTC)\n", \
 127       expires - epoch_minus_NTP, \
 128       ss_year, ss_month, ss_mday, ss_hour, ss_min, ss_sec
 129
 130     printf "\n%s", last_lines
 131 }
 132
 133 # sstamp_to_ymdhMs - convert seconds timestamp to date and time
 134 #
 135 # Call as:
 136 #
 137 #    sstamp_to_ymdhMs(sstamp, epoch_days)
 138 #
 139 # where:
 140 #
 141 #    sstamp - is the seconds timestamp.
 142 #    epoch_days - is the timestamp epoch in Gregorian days since 1600-03-01.
 143 #       ss_NTP is appropriate for an NTP sstamp.
 144 #
 145 # Both arguments should be nonnegative integers.
 146 # On return, the following variables are set based on sstamp:
 147 #
 148 #    ss_year    - Gregorian calendar year
 149 #    ss_month   - month of the year (1-January to 12-December)
 150 #    ss_mday    - day of the month (1-31)
 151 #    ss_hour    - hour (0-23)
 152 #    ss_min     - minute (0-59)
 153 #    ss_sec     - second (0-59)
 154 #    ss_wday    - day of week (0-Sunday to 6-Saturday)
 155 #
 156 # The function sstamp_init should be called prior to using sstamp_to_ymdhMs.
 157
 158 function sstamp_init()
 159 {
 160   # Days in month N, where March is month 0 and January month 10.
 161   ss_mon_days[ 0] = 31
 162   ss_mon_days[ 1] = 30
 163   ss_mon_days[ 2] = 31
 164   ss_mon_days[ 3] = 30
 165   ss_mon_days[ 4] = 31
 166   ss_mon_days[ 5] = 31
 167   ss_mon_days[ 6] = 30
 168   ss_mon_days[ 7] = 31
 169   ss_mon_days[ 8] = 30
 170   ss_mon_days[ 9] = 31
 171   ss_mon_days[10] = 31
 172
 173   # Counts of days in a Gregorian year, quad-year, century, and quad-century.
 174   ss_year_days = 365
 175   ss_quadyear_days = ss_year_days * 4 + 1
 176   ss_century_days = ss_quadyear_days * 25 - 1
 177   ss_quadcentury_days = ss_century_days * 4 + 1
 178
 179   # Standard day epochs, suitable for epoch_days.
 180   # ss_MJD = 94493
 181   # ss_POSIX = 135080
 182   ss_NTP = 109513
 183 }
 184
 185 function sstamp_to_ymdhMs(sstamp, epoch_days, \
 186                           quadcentury, century, quadyear, year, month, day)
 187 {
 188   ss_hour = int(sstamp / 3600) % 24
 189   ss_min = int(sstamp / 60) % 60
 190   ss_sec = sstamp % 60
 191
 192   # Start with a count of days since 1600-03-01 Gregorian.
 193   day = epoch_days + int(sstamp / (24 * 60 * 60))
 194
 195   # Compute a year-month-day date with days of the month numbered
 196   # 0-30, months (March-February) numbered 0-11, and years that start
 197   # start March 1 and end after the last day of February.  A quad-year
 198   # starts on March 1 of a year evenly divisible by 4 and ends after
 199   # the last day of February 4 years later.  A century starts on and
 200   # ends before March 1 in years evenly divisible by 100.
 201   # A quad-century starts on and ends before March 1 in years divisible
 202   # by 400.  While the number of days in a quad-century is a constant,
 203   # the number of days in each other time period can vary by 1.
 204   # Any variation is in the last day of the time period (there might
 205   # or might not be a February 29) where it is easy to deal with.
 206
 207   quadcentury = int(day / ss_quadcentury_days)
 208   day -= quadcentury * ss_quadcentury_days
 209   ss_wday = (day + 3) % 7
 210   century = int(day / ss_century_days)
 211   century -= century == 4
 212   day -= century * ss_century_days
 213   quadyear = int(day / ss_quadyear_days)
 214   day -= quadyear * ss_quadyear_days
 215   year = int(day / ss_year_days)
 216   year -= year == 4
 217   day -= year * ss_year_days
 218   for (month = 0; month < 11; month++) {
 219     if (day < ss_mon_days[month])
 220       break
 221     day -= ss_mon_days[month]
 222   }
 223
 224   # Convert the date to a conventional day of month (1-31),
 225   # month (1-12, January-December) and Gregorian year.
 226   ss_mday = day + 1
 227   if (month <= 9) {
 228     ss_month = month + 3
 229   } else {
 230     ss_month = month - 9
 231     year++
 232   }
 233   ss_year = 1600 + quadcentury * 400 + century * 100 + quadyear * 4 + year
 234 }