contrib/tzdata/zishrink.awk

   1 # Convert tzdata source into a smaller version of itself.
   2
   3 # Contributed by Paul Eggert.  This file is in the public domain.
   4
   5 # This is not a general-purpose converter; it is designed for current tzdata.
   6 # 'zic' should treat this script's output as if it were identical to
   7 # this script's input.
   8
   9 # Record a hash N for the new name NAME, checking for collisions.
  10
  11 function record_hash(n, name)
  12 {
  13   if (used_hashes[n]) {
  14     printf "# ! collision: %s %s\n", used_hashes[n], name
  15     exit 1
  16   }
  17   used_hashes[n] = name
  18 }
  19
  20 # Return a shortened rule name representing NAME,
  21 # and record this relationship to the hash table.
  22
  23 function gen_rule_name(name, \
  24                        n)
  25 {
  26   # Use a simple memonic: the first two letters.
  27   n = substr(name, 1, 2)
  28   record_hash(n, name)
  29   # printf "# %s = %s\n", n, name
  30   return n
  31 }
  32
  33 function prehash_rule_names( \
  34                             name)
  35 {
  36   # Rule names are not part of the tzdb API, so substitute shorter
  37   # ones.  Shortening them consistently from one release to the next
  38   # simplifies comparison of the output.  That being said, the
  39   # 1-letter names below are not standardized in any way, and can
  40   # change arbitrarily from one release to the next, as the main goal
  41   # here is compression not comparison.
  42
  43   # Abbreviating these rules names to one letter saved the most space
  44   # circa 2018e.
  45   rule["Arg"] = "A"
  46   rule["Brazil"] = "B"
  47   rule["Canada"] = "C"
  48   rule["Denmark"] = "D"
  49   rule["EU"] = "E"
  50   rule["France"] = "F"
  51   rule["GB-Eire"] = "G"
  52   rule["Halifax"] = "H"
  53   rule["Italy"] = "I"
  54   rule["Jordan"] = "J"
  55   rule["Egypt"] = "K" # "Kemet" in ancient Egyptian
  56   rule["Libya"] = "L"
  57   rule["Morocco"] = "M"
  58   rule["Neth"] = "N"
  59   rule["Poland"] = "O" # arbitrary
  60   rule["Palestine"] = "P"
  61   rule["Cuba"] = "Q" # Its start sounds like "Q".
  62   rule["Russia"] = "R"
  63   rule["Syria"] = "S"
  64   rule["Turkey"] = "T"
  65   rule["Uruguay"] = "U"
  66   rule["Vincennes"] = "V"
  67   rule["Winn"] = "W"
  68   rule["Mongol"] = "X" # arbitrary
  69   rule["NT_YK"] = "Y"
  70   rule["Zion"] = "Z"
  71   rule["Austria"] = "a"
  72   rule["Belgium"] = "b"
  73   rule["C-Eur"] = "c"
  74   rule["Algeria"] = "d" # country code DZ
  75   rule["E-Eur"] = "e"
  76   rule["Taiwan"] = "f" # Formosa
  77   rule["Greece"] = "g"
  78   rule["Hungary"] = "h"
  79   rule["Iran"] = "i"
  80   rule["StJohns"] = "j"
  81   rule["Chatham"] = "k" # arbitrary
  82   rule["Lebanon"] = "l"
  83   rule["Mexico"] = "m"
  84   rule["Tunisia"] = "n" # country code TN
  85   rule["Moncton"] = "o" # arbitrary
  86   rule["Port"] = "p"
  87   rule["Albania"] = "q" # arbitrary
  88   rule["Regina"] = "r"
  89   rule["Spain"] = "s"
  90   rule["Toronto"] = "t"
  91   rule["US"] = "u"
  92   rule["Louisville"] = "v" # ville
  93   rule["Iceland"] = "w" # arbitrary
  94   rule["Chile"] = "x" # arbitrary
  95   rule["Para"] = "y" # country code PY
  96   rule["Romania"] = "z" # arbitrary
  97   rule["Macau"] = "_" # arbitrary
  98
  99   # Use ISO 3166 alpha-2 country codes for remaining names that are countries.
 100   # This is more systematic, and avoids collisions (e.g., Malta and Moldova).
 101   rule["Armenia"] = "AM"
 102   rule["Aus"] = "AU"
 103   rule["Azer"] = "AZ"
 104   rule["Barb"] = "BB"
 105   rule["Dhaka"] = "BD"
 106   rule["Bulg"] = "BG"
 107   rule["Bahamas"] = "BS"
 108   rule["Belize"] = "BZ"
 109   rule["Swiss"] = "CH"
 110   rule["Cook"] = "CK"
 111   rule["PRC"] = "CN"
 112   rule["Cyprus"] = "CY"
 113   rule["Czech"] = "CZ"
 114   rule["Germany"] = "DE"
 115   rule["DR"] = "DO"
 116   rule["Ecuador"] = "EC"
 117   rule["Finland"] = "FI"
 118   rule["Fiji"] = "FJ"
 119   rule["Falk"] = "FK"
 120   rule["Ghana"] = "GH"
 121   rule["Guat"] = "GT"
 122   rule["Hond"] = "HN"
 123   rule["Haiti"] = "HT"
 124   rule["Eire"] = "IE"
 125   rule["Iraq"] = "IQ"
 126   rule["Japan"] = "JP"
 127   rule["Kyrgyz"] = "KG"
 128   rule["ROK"] = "KR"
 129   rule["Latvia"] = "LV"
 130   rule["Lux"] = "LX"
 131   rule["Moldova"] = "MD"
 132   rule["Malta"] = "MT"
 133   rule["Mauritius"] = "MU"
 134   rule["Namibia"] = "NA"
 135   rule["Nic"] = "NI"
 136   rule["Norway"] = "NO"
 137   rule["Peru"] = "PE"
 138   rule["Phil"] = "PH"
 139   rule["Pakistan"] = "PK"
 140   rule["Sudan"] = "SD"
 141   rule["Salv"] = "SV"
 142   rule["Tonga"] = "TO"
 143   rule["Vanuatu"] = "VU"
 144
 145   # Avoid collisions.
 146   rule["Detroit"] = "Dt" # De = Denver
 147
 148   for (name in rule) {
 149     record_hash(rule[name], name)
 150   }
 151 }
 152
 153 # Process the input line LINE and save it for later output.
 154
 155 function process_input_line(line, \
 156                             field, end, i, n, startdef, \
 157                             linkline, ruleline, zoneline)
 158 {
 159   # Remove comments, normalize spaces, and append a space to each line.
 160   sub(/#.*/, "", line)
 161   line = line " "
 162   gsub(/[\t ]+/, " ", line)
 163
 164   # Abbreviate keywords and determine line type.
 165   linkline = sub(/^Link /, "L ", line)
 166   ruleline = sub(/^Rule /, "R ", line)
 167   zoneline = sub(/^Zone /, "Z ", line)
 168
 169   # Replace FooAsia rules with the same rules without "Asia", as they
 170   # are duplicates.
 171   if (match(line, /[^ ]Asia /)) {
 172     if (ruleline) return
 173     line = substr(line, 1, RSTART) substr(line, RSTART + 5)
 174   }
 175
 176   # Abbreviate times.
 177   while (match(line, /[: ]0+[0-9]/))
 178     line = substr(line, 1, RSTART) substr(line, RSTART + RLENGTH - 1)
 179   while (match(line, /:0[^:]/))
 180     line = substr(line, 1, RSTART - 1) substr(line, RSTART + 2)
 181
 182   # Abbreviate weekday names.
 183   while (match(line, / (last)?(Mon|Wed|Fri)[ <>]/)) {
 184     end = RSTART + RLENGTH
 185     line = substr(line, 1, end - 4) substr(line, end - 1)
 186   }
 187   while (match(line, / (last)?(Sun|Tue|Thu|Sat)[ <>]/)) {
 188     end = RSTART + RLENGTH
 189     line = substr(line, 1, end - 3) substr(line, end - 1)
 190   }
 191
 192   # Abbreviate "max", "min", "only" and month names.
 193   gsub(/ max /, " ma ", line)
 194   gsub(/ min /, " mi ", line)
 195   gsub(/ only /, " o ", line)
 196   gsub(/ Jan /, " Ja ", line)
 197   gsub(/ Feb /, " F ", line)
 198   gsub(/ Apr /, " Ap ", line)
 199   gsub(/ Aug /, " Au ", line)
 200   gsub(/ Sep /, " S ", line)
 201   gsub(/ Oct /, " O ", line)
 202   gsub(/ Nov /, " N ", line)
 203   gsub(/ Dec /, " D ", line)
 204
 205   # Strip leading and trailing space.
 206   sub(/^ /, "", line)
 207   sub(/ $/, "", line)
 208
 209   # Remove unnecessary trailing zero fields.
 210   sub(/ 0+$/, "", line)
 211
 212   # Remove unnecessary trailing days-of-month "1".
 213   if (match(line, /[A-Za-z] 1$/))
 214     line = substr(line, 1, RSTART)
 215
 216   # Remove unnecessary trailing " Ja" (for January).
 217   sub(/ Ja$/, "", line)
 218
 219   n = split(line, field)
 220
 221   # Abbreviate rule names.
 222   i = zoneline ? 4 : linkline ? 0 : 2
 223   if (i && field[i] ~ /^[^-+0-9]/) {
 224     if (!rule[field[i]])
 225       rule[field[i]] = gen_rule_name(field[i])
 226     field[i] = rule[field[i]]
 227   }
 228
 229   # If this zone supersedes an earlier one, delete the earlier one
 230   # from the saved output lines.
 231   startdef = ""
 232   if (zoneline)
 233     zonename = startdef = field[2]
 234   else if (linkline)
 235     zonename = startdef = field[3]
 236   else if (ruleline)
 237     zonename = ""
 238   if (startdef) {
 239     i = zonedef[startdef]
 240     if (i) {
 241       do
 242         output_line[i - 1] = ""
 243       while (output_line[i++] ~ /^[-+0-9]/);
 244     }
 245   }
 246   zonedef[zonename] = nout + 1
 247
 248   # Save the line for later output.
 249   line = field[1]
 250   for (i = 2; i <= n; i++)
 251     line = line " " field[i]
 252   output_line[nout++] = line
 253 }
 254
 255 function output_saved_lines( \
 256                             i)
 257 {
 258   for (i = 0; i < nout; i++)
 259     if (output_line[i])
 260       print output_line[i]
 261 }
 262
 263 BEGIN {
 264   # Files that the output normally depends on.
 265   default_dep["africa"] = 1
 266   default_dep["antarctica"] = 1
 267   default_dep["asia"] = 1
 268   default_dep["australasia"] = 1
 269   default_dep["backward"] = 1
 270   default_dep["etcetera"] = 1
 271   default_dep["europe"] = 1
 272   default_dep["factory"] = 1
 273   default_dep["northamerica"] = 1
 274   default_dep["southamerica"] = 1
 275   default_dep["ziguard.awk"] = 1
 276   default_dep["zishrink.awk"] = 1
 277
 278   # Output a version string from 'version' and related configuration variables
 279   # supported by tzdb's Makefile.  If you change the makefile or any other files
 280   # that affect the output of this script, you should append '-SOMETHING'
 281   # to the contents of 'version', where SOMETHING identifies what was changed.
 282
 283   ndeps = split(deps, dep)
 284   ddeps = ""
 285   for (i = 1; i <= ndeps; i++) {
 286     if (default_dep[dep[i]]) {
 287       default_dep[dep[i]]++
 288     } else {
 289       ddeps = ddeps " " dep[i]
 290     }
 291   }
 292   for (d in default_dep) {
 293     if (default_dep[d] == 1) {
 294       ddeps = ddeps " !" d
 295     }
 296   }
 297   print "# version", version
 298   if (dataform != "main") {
 299     print "# dataform", dataform
 300   }
 301   if (redo != "posix_right") {
 302     print "# redo " redo
 303   }
 304   if (ddeps) {
 305     print "# ddeps" ddeps
 306   }
 307   print "# This zic input file is in the public domain."
 308
 309   prehash_rule_names()
 310 }
 311
 312 /^[\t ]*[^#\t ]/ {
 313   process_input_line($0)
 314 }
 315
 316 END {
 317   output_saved_lines()
 318 }