contrib/unbound/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[10])
  14 m4_define([VERSION_MICRO],[1])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl or https://github.com/NLnetLabs/unbound/issues, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=9
  21 LIBUNBOUND_REVISION=8
  22 LIBUNBOUND_AGE=1
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75 # 1.6.4 had 7:3:5
  76 # 1.6.5 had 7:4:5
  77 # 1.6.6 had 7:5:5
  78 # 1.6.7 had 7:6:5
  79 # 1.6.8 had 7:7:5
  80 # 1.7.0 had 7:8:5
  81 # 1.7.1 had 7:9:5
  82 # 1.7.2 had 7:10:5
  83 # 1.7.3 had 7:11:5
  84 # 1.8.0 had 8:0:0 # changes the event callback function signature
  85 # 1.8.1 had 8:1:0
  86 # 1.8.2 had 8:2:0
  87 # 1.8.3 had 8:3:0
  88 # 1.9.0 had 9:0:1 # add ub_ctx_set_tls
  89 # 1.9.1 had 9:1:1
  90 # 1.9.2 had 9:2:1
  91 # 1.9.3 had 9:3:1
  92 # 1.9.4 had 9:4:1
  93 # 1.9.5 had 9:5:1
  94 # 1.9.6 had 9:6:1
  95 # 1.10.0 had 9:7:1
  96 # 1.10.1 had 9:8:1
  97
  98 #   Current  -- the number of the binary API that we're implementing
  99 #   Revision -- which iteration of the implementation of the binary
 100 #               API are we supplying?
 101 #   Age      -- How many previous binary API versions do we also
 102 #               support?
 103 #
 104 # If we release a new version that does not change the binary API,
 105 # increment Revision.
 106 #
 107 # If we release a new version that changes the binary API, but does
 108 # not break programs compiled against the old binary API, increment
 109 # Current and Age.  Set Revision to 0, since this is the first
 110 # implementation of the new API.
 111 #
 112 # Otherwise, we're changing the binary API and breaking backward
 113 # compatibility with old binaries.  Increment Current.  Set Age to 0,
 114 # since we're backward compatible with no previous APIs.  Set Revision
 115 # to 0 too.
 116 AC_SUBST(LIBUNBOUND_CURRENT)
 117 AC_SUBST(LIBUNBOUND_REVISION)
 118 AC_SUBST(LIBUNBOUND_AGE)
 119
 120
 121 cmdln="`echo $@ | sed -e 's/\\\\/\\\\\\\\/g' | sed -e 's/"/\\\\"/'g`"
 122 AC_DEFINE_UNQUOTED(CONFCMDLINE, ["$cmdln"], [Command line arguments used with configure])
 123
 124 CFLAGS="$CFLAGS"
 125 AC_AIX
 126 if test "$ac_cv_header_minix_config_h" = "yes"; then
 127         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 128 fi
 129
 130 dnl
 131 dnl By default set prefix to /usr/local
 132 dnl
 133 case "$prefix" in
 134         NONE)
 135                 prefix="/usr/local"
 136         ;;
 137 esac
 138 case "$exec_prefix" in
 139         NONE)
 140                 exec_prefix="$prefix"
 141         ;;
 142 esac
 143
 144 # are we on MinGW?
 145 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 146 else
 147         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 148         else on_mingw="no"; fi
 149 fi
 150
 151 #
 152 # Determine configuration file
 153 # the eval is to evaluate shell expansion twice
 154 UNBOUND_SBIN_DIR=`eval echo "${sbindir}"`
 155 AC_SUBST(UNBOUND_SBIN_DIR)
 156 UNBOUND_SYSCONF_DIR=`eval echo "${sysconfdir}"`
 157 AC_SUBST(UNBOUND_SYSCONF_DIR)
 158 UNBOUND_LOCALSTATE_DIR=`eval echo "${localstatedir}"`
 159 AC_SUBST(UNBOUND_LOCALSTATE_DIR)
 160 if test $on_mingw = "no"; then
 161   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 162 else
 163   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 164 fi
 165 AC_ARG_WITH([conf_file],
 166         AC_HELP_STRING([--with-conf-file=path],
 167         [Pathname to the Unbound configuration file]),
 168         [ub_conf_file="$withval"])
 169 AC_SUBST(ub_conf_file)
 170 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 171 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 172 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 173 AC_SUBST(ub_conf_dir)
 174
 175 # Determine run, chroot directory and pidfile locations
 176 AC_ARG_WITH(run-dir,
 177     AC_HELP_STRING([--with-run-dir=path],
 178     [set default directory to chdir to (by default dir part of cfg file)]),
 179     UNBOUND_RUN_DIR="$withval",
 180 if test $on_mingw = no; then
 181     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 182 else
 183     UNBOUND_RUN_DIR=""
 184 fi
 185 )
 186 AC_SUBST(UNBOUND_RUN_DIR)
 187 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 188 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 189
 190 AC_ARG_WITH(chroot-dir,
 191     AC_HELP_STRING([--with-chroot-dir=path],
 192     [set default directory to chroot to (by default same as run-dir)]),
 193     UNBOUND_CHROOT_DIR="$withval",
 194 if test $on_mingw = no; then
 195     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 196 else
 197     UNBOUND_CHROOT_DIR=""
 198 fi
 199 )
 200 AC_SUBST(UNBOUND_CHROOT_DIR)
 201 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 202 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 203
 204 AC_ARG_WITH(share-dir,
 205     AC_HELP_STRING([--with-share-dir=path],
 206     [set default directory with shared data (by default same as share/unbound)]),
 207     UNBOUND_SHARE_DIR="$withval",
 208     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 209 AC_SUBST(UNBOUND_SHARE_DIR)
 210 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 211
 212 AC_ARG_WITH(pidfile,
 213     AC_HELP_STRING([--with-pidfile=filename],
 214     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 215     UNBOUND_PIDFILE="$withval",
 216 if test $on_mingw = no; then
 217     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 218 else
 219     UNBOUND_PIDFILE=""
 220 fi
 221 )
 222 AC_SUBST(UNBOUND_PIDFILE)
 223 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 224 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 225
 226 AC_ARG_WITH(rootkey-file,
 227     AC_HELP_STRING([--with-rootkey-file=filename],
 228     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 229     UNBOUND_ROOTKEY_FILE="$withval",
 230 if test $on_mingw = no; then
 231     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 232 else
 233     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 234 fi
 235 )
 236 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 237 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 238 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 239
 240 AC_ARG_WITH(rootcert-file,
 241     AC_HELP_STRING([--with-rootcert-file=filename],
 242     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 243     UNBOUND_ROOTCERT_FILE="$withval",
 244 if test $on_mingw = no; then
 245     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 246 else
 247     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 248 fi
 249 )
 250 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 251 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 252 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 253
 254 AC_ARG_WITH(username,
 255     AC_HELP_STRING([--with-username=user],
 256     [set default user that unbound changes to (default user is unbound)]),
 257     UNBOUND_USERNAME="$withval",
 258     UNBOUND_USERNAME="unbound")
 259 AC_SUBST(UNBOUND_USERNAME)
 260 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 261
 262 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 263 ACX_RSRC_VERSION(wnvs)
 264 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 265
 266 # Checks for typedefs, structures, and compiler characteristics.
 267 AC_C_CONST
 268 AC_LANG_C
 269 # allow user to override the -g -O2 flags.
 270 default_cflags=no
 271 if test "x$CFLAGS" = "x" ; then
 272 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 273 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 274 default_cflags=yes
 275 fi
 276 AC_PROG_CC
 277 ACX_DEPFLAG
 278 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 279
 280 # debug mode flags warnings
 281 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 282 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 283 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 284 else debug_enabled="$enable_checking"; fi
 285 AC_SUBST(debug_enabled)
 286 case "$debug_enabled" in
 287         yes)
 288                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 289                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 290                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 291                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 292                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 293                 ;;
 294         no|*)
 295                 # nothing to do.
 296                 ;;
 297 esac
 298 if test "$default_cflags" = "yes"; then
 299         # only when CFLAGS was "" at the start, if the users wants to
 300         # override we shouldn't add default cflags, because they wouldn't
 301         # be able to turn off these options and set the CFLAGS wanted.
 302         ACX_CHECK_FLTO
 303         ACX_CHECK_PIE
 304         ACX_CHECK_RELRO_NOW
 305 fi
 306
 307 AC_C_INLINE
 308 ACX_CHECK_FORMAT_ATTRIBUTE
 309 ACX_CHECK_UNUSED_ATTRIBUTE
 310
 311 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 312 [AC_REQUIRE([AC_PROG_CC])
 313 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 314 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 315 [ac_cv_c_weak_attribute=no
 316 AC_TRY_COMPILE(
 317 [ #include <stdio.h>
 318 __attribute__((weak)) void f(int x) { printf("%d", x); }
 319 ], [
 320    f(1);
 321 ],
 322 [ac_cv_c_weak_attribute="yes"],
 323 [ac_cv_c_weak_attribute="no"])
 324 ])
 325
 326 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 327 if test $ac_cv_c_weak_attribute = yes; then
 328   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 329   AC_DEFINE(ATTR_WEAK, [__attribute__((weak))], [apply the weak attribute to a symbol])
 330 fi
 331 ])dnl End of CHECK_WEAK_ATTRIBUTE
 332
 333 CHECK_WEAK_ATTRIBUTE
 334
 335 AC_DEFUN([CHECK_NORETURN_ATTRIBUTE],
 336 [AC_REQUIRE([AC_PROG_CC])
 337 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "noreturn" attribute)
 338 AC_CACHE_VAL(ac_cv_c_noreturn_attribute,
 339 [ac_cv_c_noreturn_attribute=no
 340 AC_TRY_COMPILE(
 341 [ #include <stdio.h>
 342 __attribute__((noreturn)) void f(int x) { printf("%d", x); }
 343 ], [
 344    f(1);
 345 ],
 346 [ac_cv_c_noreturn_attribute="yes"],
 347 [ac_cv_c_noreturn_attribute="no"])
 348 ])
 349
 350 AC_MSG_RESULT($ac_cv_c_noreturn_attribute)
 351 if test $ac_cv_c_noreturn_attribute = yes; then
 352   AC_DEFINE(HAVE_ATTR_NORETURN, 1, [Whether the C compiler accepts the "noreturn" attribute])
 353   AC_DEFINE(ATTR_NORETURN, [__attribute__((__noreturn__))], [apply the noreturn attribute to a function that exits the program])
 354 fi
 355 ])dnl End of CHECK_NORETURN_ATTRIBUTE
 356
 357 CHECK_NORETURN_ATTRIBUTE
 358
 359 if test "$srcdir" != "."; then
 360         CPPFLAGS="$CPPFLAGS -I$srcdir"
 361 fi
 362
 363 AC_DEFUN([ACX_YYLEX_DESTROY], [
 364         AC_MSG_CHECKING([for yylex_destroy])
 365         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 366                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 367                 AC_MSG_RESULT(yes)
 368         else AC_MSG_RESULT(no);
 369                 LEX=":"
 370         fi
 371 ])
 372
 373 AC_DEFUN([ACX_YYLEX_OPTION], [
 374         AC_MSG_CHECKING([for lex %option])
 375         if cat <<EOF | $LEX -t 2>&1 | grep yy_delete_buffer >/dev/null 2>&1; then
 376 %option nounput
 377 %%
 378 EOF
 379                 AC_MSG_RESULT(yes)
 380         else AC_MSG_RESULT(no);
 381                 LEX=":"
 382         fi
 383 ])
 384
 385 AC_PROG_LEX
 386 if test "$LEX" != "" -a "$LEX" != ":"; then
 387 ACX_YYLEX_DESTROY
 388 fi
 389 if test "$LEX" != "" -a "$LEX" != ":"; then
 390 ACX_YYLEX_OPTION
 391 fi
 392 AC_PROG_YACC
 393 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 394 AC_CHECK_TOOL(STRIP, strip)
 395 ACX_LIBTOOL_C_ONLY
 396
 397 PKG_PROG_PKG_CONFIG
 398
 399 # Checks for header files.
 400 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/endian.h libkern/OSByteOrder.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 401
 402 # check for types.
 403 # Using own tests for int64* because autoconf builtin only give 32bit.
 404 AC_CHECK_TYPE(int8_t, signed char)
 405 AC_CHECK_TYPE(int16_t, short)
 406 AC_CHECK_TYPE(int32_t, int)
 407 AC_CHECK_TYPE(int64_t, long long)
 408 AC_CHECK_TYPE(uint8_t, unsigned char)
 409 AC_CHECK_TYPE(uint16_t, unsigned short)
 410 AC_CHECK_TYPE(uint32_t, unsigned int)
 411 AC_CHECK_TYPE(uint64_t, unsigned long long)
 412 AC_TYPE_SIZE_T
 413 AC_CHECK_TYPE(ssize_t, int)
 414 AC_TYPE_UID_T
 415 AC_TYPE_PID_T
 416 AC_TYPE_OFF_T
 417 ACX_TYPE_U_CHAR
 418 ACX_TYPE_RLIM_T
 419 ACX_TYPE_SOCKLEN_T
 420 ACX_TYPE_IN_ADDR_T
 421 ACX_TYPE_IN_PORT_T
 422 ACX_CHECK_MEMCMP_SIGNED
 423
 424 AC_CHECK_SIZEOF(time_t,,[
 425 AC_INCLUDES_DEFAULT
 426 #ifdef TIME_WITH_SYS_TIME
 427 # include <sys/time.h>
 428 # include <time.h>
 429 #else
 430 # ifdef HAVE_SYS_TIME_H
 431 #  include <sys/time.h>
 432 # else
 433 #  include <time.h>
 434 # endif
 435 #endif
 436 ])
 437 AC_CHECK_SIZEOF(size_t)
 438
 439 # add option to disable the evil rpath
 440 ACX_ARG_RPATH
 441 AC_SUBST(RUNTIME_PATH)
 442
 443 # check to see if libraries are needed for these functions.
 444 AC_SEARCH_LIBS([inet_pton], [nsl])
 445 AC_SEARCH_LIBS([socket], [socket])
 446
 447 # check wether strptime also works
 448 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 449 [AC_REQUIRE([AC_PROG_CC])
 450 AC_MSG_CHECKING(whether strptime works)
 451 if test c${cross_compiling} = cno; then
 452 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 453 #define _XOPEN_SOURCE 600
 454 #include <time.h>
 455 int main(void) { struct tm tm; char *res;
 456 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 457 if (!res) return 2;
 458 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 459 if (!res) return 1; return 0; }
 460 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 461 else
 462 eval "ac_cv_c_strptime_works=maybe"
 463 fi
 464 AC_MSG_RESULT($ac_cv_c_strptime_works)
 465 if test $ac_cv_c_strptime_works = no; then
 466 AC_LIBOBJ(strptime)
 467 else
 468 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 469 fi
 470 ])dnl
 471
 472 # check some functions of the OS before linking libs (while still runnable).
 473 AC_FUNC_CHOWN
 474 AC_FUNC_FORK
 475 AC_TYPE_SIGNAL
 476 AC_FUNC_FSEEKO
 477 ACX_SYS_LARGEFILE
 478 ACX_CHECK_NONBLOCKING_BROKEN
 479 ACX_MKDIR_ONE_ARG
 480 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 481
 482 # check if we can use SO_REUSEPORT
 483 if echo "$host" | $GREP -i -e linux -e dragonfly >/dev/null; then
 484         AC_DEFINE(REUSEPORT_DEFAULT, 1, [if REUSEPORT is enabled by default])
 485 else
 486         AC_DEFINE(REUSEPORT_DEFAULT, 0, [if REUSEPORT is enabled by default])
 487 fi
 488
 489 # Include systemd.m4 - begin
 490 sinclude(systemd.m4)
 491 # Include systemd.m4 - end
 492
 493 # set memory allocation checking if requested
 494 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 495         [ enable to memory allocation statistics, for debug purposes ]),
 496         , )
 497 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 498         [ enable for lightweight alloc assertions, for debug purposes ]),
 499         , )
 500 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 501         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 502         , )
 503 if test x_$enable_alloc_nonregional = x_yes; then
 504         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 505 fi
 506 if test x_$enable_alloc_checks = x_yes; then
 507         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 508         SLDNS_ALLOCCHECK_EXTRA_OBJ="alloc.lo log.lo"
 509         AC_SUBST(SLDNS_ALLOCCHECK_EXTRA_OBJ)
 510         ASYNCLOOK_ALLOCCHECK_EXTRA_OBJ="alloc.lo"
 511         AC_SUBST(ASYNCLOOK_ALLOCCHECK_EXTRA_OBJ)
 512 else
 513         if test x_$enable_alloc_lite = x_yes; then
 514                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 515         else
 516                 ACX_FUNC_MALLOC([unbound])
 517         fi
 518 fi
 519
 520 # check windows threads (we use them, not pthreads, on windows).
 521 if test "$on_mingw" = "yes"; then
 522 # check windows threads
 523         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 524         AC_MSG_CHECKING([for CreateThread])
 525         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 526 #ifdef HAVE_WINDOWS_H
 527 #include <windows.h>
 528 #endif
 529 ], [
 530         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 531 ])],
 532         AC_MSG_RESULT(yes)
 533         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 534 ,
 535         AC_MSG_RESULT(no)
 536 )
 537
 538 else
 539 # not on mingw, check thread libraries.
 540
 541 # check for thread library.
 542 # check this first, so that the pthread lib does not get linked in via
 543 # libssl or libpython, and thus distorts the tests, and we end up using
 544 # the non-threadsafe C libraries.
 545 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 546  [use pthreads library, or --without-pthreads to disable threading support.]),
 547  [ ],[ withval="yes" ])
 548 ub_have_pthreads=no
 549 if test x_$withval != x_no; then
 550         AX_PTHREAD([
 551                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 552                 if test -n "$PTHREAD_LIBS"; then
 553                   LIBS="$PTHREAD_LIBS $LIBS"
 554                 fi
 555                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 556                 CC="$PTHREAD_CC"
 557                 ub_have_pthreads=yes
 558                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 559
 560                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 561                 AC_MSG_CHECKING([if -pthread unused during linking])
 562                 # catch clang warning 'argument unused during compilation'
 563                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 564 [[
 565 int main(void) {return 0;}
 566 ]])])
 567                 pthread_unused="yes"
 568                 # first compile
 569                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 570                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 571                 if test $? = 0; then
 572                         # then link
 573                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 574                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 575                         if test $? -ne 0; then
 576                                 AC_MSG_RESULT(yes)
 577                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 578                                 PTHREAD_CFLAGS_ONLY="-pthread"
 579                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 580                         else
 581                                 AC_MSG_RESULT(no)
 582                         fi
 583                 else
 584                         AC_MSG_RESULT(no)
 585                 fi # endif cc successful
 586                 rm -f conftest conftest.c conftest.o
 587                 fi # endif -pthread in CFLAGS
 588
 589                 ])
 590 fi
 591
 592 # check solaris thread library
 593 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 594         [use solaris native thread library.]), [ ],[ withval="no" ])
 595 ub_have_sol_threads=no
 596 if test x_$withval != x_no; then
 597         if test x_$ub_have_pthreads != x_no; then
 598             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 599         else
 600         AC_SEARCH_LIBS(thr_create, [thread],
 601         [
 602                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 603
 604                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 605                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 606                 ub_have_sol_threads=yes
 607         ] , [
 608                 AC_ERROR([no solaris threads found.])
 609         ])
 610         fi
 611 fi
 612
 613 fi # end of non-mingw check of thread libraries
 614
 615 # Check for SYSLOG_FACILITY
 616 AC_ARG_WITH(syslog-facility, AC_HELP_STRING([--with-syslog-facility=LOCAL0 - LOCAL7], [ set SYSLOG_FACILITY, default DAEMON ]),
 617         [ UNBOUND_SYSLOG_FACILITY="$withval" ], [])
 618 case "${UNBOUND_SYSLOG_FACILITY}" in
 619
 620   LOCAL[[0-7]]) UNBOUND_SYSLOG_FACILITY="LOG_${UNBOUND_SYSLOG_FACILITY}" ;;
 621
 622            *) UNBOUND_SYSLOG_FACILITY="LOG_DAEMON" ;;
 623
 624 esac
 625 AC_DEFINE_UNQUOTED(UB_SYSLOG_FACILITY,${UNBOUND_SYSLOG_FACILITY},[the SYSLOG_FACILITY to use, default LOG_DAEMON])
 626
 627 # Check for PyUnbound
 628 AC_ARG_WITH(pyunbound,
 629    AC_HELP_STRING([--with-pyunbound],
 630    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 631    [], [ withval="no" ])
 632
 633 ub_test_python=no
 634 ub_with_pyunbound=no
 635 if test x_$withval != x_no; then
 636    ub_with_pyunbound=yes
 637    ub_test_python=yes
 638 fi
 639
 640 # Check for Python module
 641 AC_ARG_WITH(pythonmodule,
 642    AC_HELP_STRING([--with-pythonmodule],
 643    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 644    [], [ withval="no" ])
 645
 646 ub_with_pythonmod=no
 647 if test x_$withval != x_no; then
 648    ub_with_pythonmod=yes
 649    ub_test_python=yes
 650 fi
 651
 652 # Check for Python & SWIG only on PyUnbound or PyModule
 653 if test x_$ub_test_python != x_no; then
 654
 655    # Check for Python
 656    ub_have_python=no
 657    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 658    AC_PYTHON_DEVEL
 659    if test ! -z "$PYTHON_VERSION"; then
 660         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 661                 AC_ERROR([Python version >= 2.4.0 is required])
 662         fi
 663
 664       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 665       AC_SUBST(PY_MAJOR_VERSION)
 666       # Have Python
 667       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 668       if test -n "$LIBS"; then
 669         LIBS="$PYTHON_LDFLAGS $LIBS"
 670       else
 671         LIBS="$PYTHON_LDFLAGS"
 672       fi
 673       if test -n "$CPPFLAGS"; then
 674         CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 675       else
 676         CPPFLAGS="$PYTHON_CPPFLAGS"
 677       fi
 678       ub_have_python=yes
 679       PKG_CHECK_EXISTS(["python${PY_MAJOR_VERSION}"],
 680                        [PC_PY_DEPENDENCY="python${PY_MAJOR_VERSION}"],
 681                        [PC_PY_DEPENDENCY="python"])
 682       AC_SUBST(PC_PY_DEPENDENCY)
 683
 684       # Check for SWIG
 685       ub_have_swig=no
 686       AC_ARG_ENABLE(swig-version-check, AC_HELP_STRING([--disable-swig-version-check], [Disable swig version check to build python modules with older swig even though that is unreliable]))
 687       if test "$enable_swig_version_check" = "yes"; then
 688         AC_PROG_SWIG(2.0.1)
 689       else
 690         AC_PROG_SWIG
 691       fi
 692       AC_MSG_CHECKING(SWIG)
 693       if test ! -x "$SWIG"; then
 694          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 695       else
 696          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 697          AC_SUBST(swig, "$SWIG")
 698          AC_MSG_RESULT(present)
 699
 700          # If have Python & SWIG
 701          # Declare PythonMod
 702          if test x_$ub_with_pythonmod != x_no; then
 703             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 704             WITH_PYTHONMODULE=yes
 705             AC_SUBST(WITH_PYTHONMODULE)
 706             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 707             AC_SUBST(PYTHONMOD_OBJ)
 708             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 709             AC_SUBST(PYTHONMOD_HEADER)
 710             PYTHONMOD_INSTALL=pythonmod-install
 711             AC_SUBST(PYTHONMOD_INSTALL)
 712             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 713             AC_SUBST(PYTHONMOD_UNINSTALL)
 714          fi
 715
 716          # Declare PyUnbound
 717          if test x_$ub_with_pyunbound != x_no; then
 718             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 719             WITH_PYUNBOUND=yes
 720             AC_SUBST(WITH_PYUNBOUND)
 721             PYUNBOUND_OBJ="libunbound_wrap.lo"
 722             AC_SUBST(PYUNBOUND_OBJ)
 723             PYUNBOUND_TARGET="_unbound.la"
 724             AC_SUBST(PYUNBOUND_TARGET)
 725             PYUNBOUND_INSTALL=pyunbound-install
 726             AC_SUBST(PYUNBOUND_INSTALL)
 727             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 728             AC_SUBST(PYUNBOUND_UNINSTALL)
 729          fi
 730       fi
 731    else
 732       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 733       ub_with_pyunbound=no
 734       ub_with_pythonmod=no
 735    fi
 736 fi
 737
 738 if test "`uname`" = "NetBSD"; then
 739         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 740         AC_SUBST(NETBSD_LINTFLAGS)
 741 fi
 742 CONFIG_DATE=`date +%Y%m%d`
 743 AC_SUBST(CONFIG_DATE)
 744
 745 # Checks for libraries.
 746
 747 # libnss
 748 USE_NSS="no"
 749 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 750         [use libnss instead of openssl, installed at path.]),
 751         [
 752         USE_NSS="yes"
 753         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 754         if test "$withval" != "" -a "$withval" != "yes"; then
 755                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 756                 LDFLAGS="$LDFLAGS -L$withval/lib"
 757                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 758                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 759         else
 760                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 761                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 762         fi
 763         LIBS="$LIBS -lnss3 -lnspr4"
 764         SSLLIB=""
 765         PC_CRYPTO_DEPENDENCY="nss nspr"
 766         AC_SUBST(PC_CRYPTO_DEPENDENCY)
 767         ]
 768 )
 769
 770 # libnettle
 771 USE_NETTLE="no"
 772 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 773         [use libnettle as crypto library, installed at path.]),
 774         [
 775         USE_NETTLE="yes"
 776         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 777         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 778         if test "$withval" != "" -a "$withval" != "yes"; then
 779                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 780                 LDFLAGS="$LDFLAGS -L$withval/lib"
 781                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 782         else
 783                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 784         fi
 785         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 786         SSLLIB=""
 787         PC_CRYPTO_DEPENDENCY="hogweed nettle"
 788         AC_SUBST(PC_CRYPTO_DEPENDENCY)
 789         ]
 790 )
 791
 792 # openssl
 793 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 794 ACX_WITH_SSL
 795 ACX_LIB_SSL
 796 SSLLIB="-lssl"
 797
 798 PC_CRYPTO_DEPENDENCY="libcrypto libssl"
 799 AC_SUBST(PC_CRYPTO_DEPENDENCY)
 800
 801 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 802 BAKLIBS="$LIBS"
 803 LIBS="-lssl $LIBS"
 804 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 805 AC_TRY_LINK_FUNC([HMAC_Update], [
 806         AC_MSG_RESULT([no])
 807         LIBS="$BAKLIBS"
 808 ], [
 809         AC_MSG_RESULT([yes])
 810         LIBS="$BAKLIBS"
 811         LIBS="$LIBS -lcrypt32"
 812 ])
 813
 814 AC_MSG_CHECKING([for LibreSSL])
 815 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 816         AC_MSG_RESULT([yes])
 817         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 818         # libressl provides these compat functions, but they may also be
 819         # declared by the OS in libc.  See if they have been declared.
 820         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform])
 821 else
 822         AC_MSG_RESULT([no])
 823 fi
 824 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h],,, [AC_INCLUDES_DEFAULT])
 825 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1 EVP_DigestVerify SSL_CTX_set_tlsext_ticket_key_cb EVP_aes_256_cbc EVP_EncryptInit_ex HMAC_Init_ex CRYPTO_THREADID_set_callback])
 826
 827 # these check_funcs need -lssl
 828 BAKLIBS="$LIBS"
 829 LIBS="-lssl $LIBS"
 830 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level SSL_set1_host SSL_get0_peername X509_VERIFY_PARAM_set1_host SSL_CTX_set_ciphersuites])
 831 LIBS="$BAKLIBS"
 832
 833 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 834 AC_INCLUDES_DEFAULT
 835 #ifdef HAVE_OPENSSL_ERR_H
 836 #include <openssl/err.h>
 837 #endif
 838
 839 #ifdef HAVE_OPENSSL_RAND_H
 840 #include <openssl/rand.h>
 841 #endif
 842
 843 #ifdef HAVE_OPENSSL_CONF_H
 844 #include <openssl/conf.h>
 845 #endif
 846
 847 #ifdef HAVE_OPENSSL_ENGINE_H
 848 #include <openssl/engine.h>
 849 #endif
 850 #include <openssl/ssl.h>
 851 #include <openssl/evp.h>
 852 ])
 853
 854 if test "$ac_cv_func_HMAC_Init_ex" = "yes"; then
 855 # check function return type.
 856 AC_MSG_CHECKING(the return type of HMAC_Init_ex)
 857 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 858 #ifdef HAVE_OPENSSL_ERR_H
 859 #include <openssl/err.h>
 860 #endif
 861
 862 #ifdef HAVE_OPENSSL_RAND_H
 863 #include <openssl/rand.h>
 864 #endif
 865
 866 #ifdef HAVE_OPENSSL_CONF_H
 867 #include <openssl/conf.h>
 868 #endif
 869
 870 #ifdef HAVE_OPENSSL_ENGINE_H
 871 #include <openssl/engine.h>
 872 #endif
 873 #include <openssl/ssl.h>
 874 #include <openssl/evp.h>
 875 ], [
 876         HMAC_CTX* hmac_ctx = NULL;
 877         void* hmac_key = NULL;
 878         const EVP_MD* digest = NULL;
 879         int x = HMAC_Init_ex(hmac_ctx, hmac_key, 32, digest, NULL);
 880         (void)x;
 881 ])], [
 882         AC_MSG_RESULT(int)
 883 ], [
 884         AC_MSG_RESULT(void)
 885         AC_DEFINE([HMAC_INIT_EX_RETURNS_VOID], 1, [If HMAC_Init_ex() returns void])
 886 ])
 887 fi
 888
 889 fi
 890 AC_SUBST(SSLLIB)
 891
 892 # libbsd
 893 AC_ARG_WITH([libbsd], AC_HELP_STRING([--with-libbsd], [Use portable libbsd functions]), [
 894         AC_CHECK_HEADERS([bsd/string.h bsd/stdlib.h],,, [AC_INCLUDES_DEFAULT])
 895         if test "x$ac_cv_header_bsd_string_h" = xyes -a "x$ac_cv_header_bsd_stdlib_h" = xyes; then
 896                 for func in strlcpy strlcat arc4random arc4random_uniform reallocarray; do
 897                         AC_SEARCH_LIBS([$func], [bsd], [
 898                                 AC_DEFINE(HAVE_LIBBSD, 1, [Use portable libbsd functions])
 899                                 PC_LIBBSD_DEPENDENCY=libbsd
 900                                 AC_SUBST(PC_LIBBSD_DEPENDENCY)
 901                         ])
 902                 done
 903         fi
 904 ])
 905
 906 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 907 case "$enable_sha1" in
 908         no)
 909         ;;
 910         yes|*)
 911         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 912         ;;
 913 esac
 914
 915
 916 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 917 case "$enable_sha2" in
 918         no)
 919         ;;
 920         yes|*)
 921         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 922         ;;
 923 esac
 924
 925 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 926 case "$enable_subnet" in
 927         yes)
 928         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 929         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 930         AC_SUBST(SUBNET_OBJ)
 931         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 932         AC_SUBST(SUBNET_HEADER)
 933         ;;
 934         no|*)
 935         ;;
 936 esac
 937
 938 # check wether gost also works
 939 AC_DEFUN([AC_CHECK_GOST_WORKS],
 940 [AC_REQUIRE([AC_PROG_CC])
 941 AC_MSG_CHECKING([if GOST works])
 942 if test c${cross_compiling} = cno; then
 943 BAKCFLAGS="$CFLAGS"
 944 if test -n "$ssldir"; then
 945         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 946 fi
 947 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 948 #include <string.h>
 949 #include <openssl/ssl.h>
 950 #include <openssl/evp.h>
 951 #include <openssl/engine.h>
 952 #include <openssl/conf.h>
 953 /* routine to load gost (from sldns) */
 954 int load_gost_id(void)
 955 {
 956         static int gost_id = 0;
 957         const EVP_PKEY_ASN1_METHOD* meth;
 958         ENGINE* e;
 959
 960         if(gost_id) return gost_id;
 961
 962         /* see if configuration loaded gost implementation from other engine*/
 963         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 964         if(meth) {
 965                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 966                 return gost_id;
 967         }
 968
 969         /* see if engine can be loaded already */
 970         e = ENGINE_by_id("gost");
 971         if(!e) {
 972                 /* load it ourself, in case statically linked */
 973                 ENGINE_load_builtin_engines();
 974                 ENGINE_load_dynamic();
 975                 e = ENGINE_by_id("gost");
 976         }
 977         if(!e) {
 978                 /* no gost engine in openssl */
 979                 return 0;
 980         }
 981         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 982                 ENGINE_finish(e);
 983                 ENGINE_free(e);
 984                 return 0;
 985         }
 986
 987         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 988         if(!meth) {
 989                 /* algo not found */
 990                 ENGINE_finish(e);
 991                 ENGINE_free(e);
 992                 return 0;
 993         }
 994         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 995         return gost_id;
 996 }
 997 int main(void) {
 998         EVP_MD_CTX* ctx;
 999         const EVP_MD* md;
1000         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
1001         const char* str = "Hello world";
1002         const unsigned char check[] = {
1003                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
1004                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
1005                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
1006                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
1007         };
1008         OPENSSL_config(NULL);
1009         (void)load_gost_id();
1010         md = EVP_get_digestbyname("md_gost94");
1011         if(!md) return 1;
1012         memset(digest, 0, sizeof(digest));
1013         ctx = EVP_MD_CTX_create();
1014         if(!ctx) return 2;
1015         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
1016         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
1017         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
1018         /* uncomment to see the hash calculated.
1019                 {int i;
1020                 for(i=0; i<32; i++)
1021                         printf(" %2.2x", (int)digest[i]);
1022                 printf("\n");}
1023         */
1024         if(memcmp(digest, check, sizeof(check)) != 0)
1025                 return 6;
1026         return 0;
1027 }
1028 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
1029 CFLAGS="$BAKCFLAGS"
1030 else
1031 eval "ac_cv_c_gost_works=maybe"
1032 fi
1033 AC_MSG_RESULT($ac_cv_c_gost_works)
1034 ])dnl
1035
1036 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
1037 use_gost="no"
1038 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1039 case "$enable_gost" in
1040         no)
1041         ;;
1042         *)
1043         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
1044         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
1045         AC_CHECK_GOST_WORKS
1046         if test "$ac_cv_c_gost_works" != no; then
1047                 use_gost="yes"
1048                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
1049         fi
1050         ;;
1051 esac
1052 fi dnl !USE_NSS && !USE_NETTLE
1053
1054 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
1055 use_ecdsa="no"
1056 case "$enable_ecdsa" in
1057     no)
1058       ;;
1059     *)
1060       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1061               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
1062               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
1063               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
1064 #include <openssl/evp.h>
1065               ])
1066               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
1067               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
1068               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
1069                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
1070                   AC_MSG_RESULT([no])
1071                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
1072                 else
1073                   AC_MSG_RESULT([yes])
1074                 fi
1075               else
1076                 # not OpenSSL, thus likely LibreSSL, which supports it
1077                 AC_MSG_RESULT([yes])
1078               fi
1079       fi
1080       # we now know we have ECDSA and the required curves.
1081       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
1082       use_ecdsa="yes"
1083       ;;
1084 esac
1085
1086 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
1087 use_dsa="no"
1088 case "$enable_dsa" in
1089     yes)
1090       # detect if DSA is supported, and turn it off if not.
1091       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1092       AC_CHECK_FUNC(DSA_SIG_new, [
1093       AC_CHECK_TYPE(DSA_SIG*, [
1094       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1095       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1096                fi ], [
1097 AC_INCLUDES_DEFAULT
1098 #ifdef HAVE_OPENSSL_ERR_H
1099 #include <openssl/err.h>
1100 #endif
1101
1102 #ifdef HAVE_OPENSSL_RAND_H
1103 #include <openssl/rand.h>
1104 #endif
1105
1106 #ifdef HAVE_OPENSSL_CONF_H
1107 #include <openssl/conf.h>
1108 #endif
1109
1110 #ifdef HAVE_OPENSSL_ENGINE_H
1111 #include <openssl/engine.h>
1112 #endif
1113       ])
1114       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1115                fi ])
1116       else
1117       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1118       fi
1119       ;;
1120     *)
1121       # disable dsa by default, RFC 8624 section 3.1, validators MUST NOT
1122       # support DSA for DNSSEC Validation.
1123       ;;
1124 esac
1125
1126 AC_ARG_ENABLE(ed25519, AC_HELP_STRING([--disable-ed25519], [Disable ED25519 support]))
1127 use_ed25519="no"
1128 case "$enable_ed25519" in
1129     no)
1130       ;;
1131     *)
1132       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1133               AC_CHECK_DECLS([NID_ED25519], [
1134                 use_ed25519="yes"
1135               ], [ if test "x$enable_ed25519" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED25519 and you used --enable-ed25519.])
1136                 fi ], [AC_INCLUDES_DEFAULT
1137 #include <openssl/evp.h>
1138               ])
1139       fi
1140       if test $USE_NETTLE = "yes"; then
1141                 AC_CHECK_HEADERS([nettle/eddsa.h], use_ed25519="yes",, [AC_INCLUDES_DEFAULT])
1142       fi
1143       if test $use_ed25519 = "yes"; then
1144                 AC_DEFINE_UNQUOTED([USE_ED25519], [1], [Define this to enable ED25519 support.])
1145       fi
1146       ;;
1147 esac
1148
1149 AC_ARG_ENABLE(ed448, AC_HELP_STRING([--disable-ed448], [Disable ED448 support]))
1150 use_ed448="no"
1151 case "$enable_ed448" in
1152     no)
1153       ;;
1154     *)
1155       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1156               AC_CHECK_DECLS([NID_ED448], [
1157                 use_ed448="yes"
1158               ], [ if test "x$enable_ed448" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED448 and you used --enable-ed448.])
1159                 fi ], [AC_INCLUDES_DEFAULT
1160 #include <openssl/evp.h>
1161               ])
1162       fi
1163       if test $use_ed448 = "yes"; then
1164                 AC_DEFINE_UNQUOTED([USE_ED448], [1], [Define this to enable ED448 support.])
1165       fi
1166       ;;
1167 esac
1168
1169 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
1170 case "$enable_event_api" in
1171     yes)
1172       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
1173       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
1174       ;;
1175     *)
1176       ;;
1177 esac
1178
1179 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
1180 case "$enable_tfo_client" in
1181         yes)
1182                 case `uname` in
1183                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1184                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1185                                              [AC_INCLUDES_DEFAULT
1186 #include <netinet/tcp.h>
1187 ])
1188                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1189                           ;;
1190                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1191                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1192                                               [AC_INCLUDES_DEFAULT
1193 #include <sys/socket.h>
1194 ])
1195                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1196                           ;;
1197                 esac
1198         ;;
1199         no|*)
1200                 ;;
1201 esac
1202
1203 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
1204 case "$enable_tfo_server" in
1205         yes)
1206               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
1207 #include <netinet/tcp.h>
1208               ])
1209                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
1210                 ;;
1211         no|*)
1212                 ;;
1213 esac
1214
1215 # check for libevent
1216 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
1217     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
1218     [ ],[ withval="no" ])
1219 if test x_$withval = x_yes -o x_$withval != x_no; then
1220         AC_MSG_CHECKING(for libevent)
1221         if test x_$withval = x_ -o x_$withval = x_yes; then
1222             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1223         fi
1224         for dir in $withval; do
1225             thedir="$dir"
1226             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
1227                 found_libevent="yes"
1228                 dnl assume /usr is in default path.
1229                 if test "$thedir" != "/usr"; then
1230                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
1231                 fi
1232                 break;
1233             fi
1234         done
1235         if test x_$found_libevent != x_yes; then
1236                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
1237                         # libevent source directory
1238                         AC_MSG_RESULT(found in $thedir)
1239                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
1240                         BAK_LDFLAGS_SET="1"
1241                         BAK_LDFLAGS="$LDFLAGS"
1242                         # remove evdns from linking
1243                         mkdir build >/dev/null 2>&1
1244                         mkdir build/libevent >/dev/null 2>&1
1245                         mkdir build/libevent/.libs >/dev/null 2>&1
1246                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1247                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
1248                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1249                         cp $ev_files_o build/libevent
1250                         cp $ev_files_lo build/libevent
1251                         cp $ev_files_libso build/libevent/.libs
1252                         LATE_LDFLAGS="build/libevent/*.lo -lm"
1253                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
1254                 else
1255                         AC_MSG_ERROR([Cannot find the libevent library in $withval
1256 You can restart ./configure --with-libevent=no to use a builtin alternative.
1257 Please note that this alternative is not as capable as libevent when using
1258 large outgoing port ranges.  ])
1259                 fi
1260         else
1261             AC_MSG_RESULT(found in $thedir)
1262             dnl if event2 exists and no event lib in dir itself, use subdir
1263             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1264                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1265                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1266             else
1267                     dnl assume /usr is in default path, do not add "".
1268                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1269                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1270                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1271                     fi
1272             fi
1273         fi
1274         # check for library used by libevent after 1.3c
1275         AC_SEARCH_LIBS([clock_gettime], [rt])
1276
1277         # is the event.h header libev or libevent?
1278         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1279         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1280                 AC_SEARCH_LIBS(event_set, [ev])
1281         ],[
1282                 AC_SEARCH_LIBS(event_set, [event])
1283         ],[AC_INCLUDES_DEFAULT
1284 #include <event.h>
1285         ])
1286         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1287         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1288         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1289         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1290         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1291         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1292         AC_CHECK_FUNCS([event_assign]) # in libevent, for thread-safety
1293         AC_CHECK_DECLS([evsignal_assign], [], [], [AC_INCLUDES_DEFAULT
1294 #ifdef HAVE_EVENT_H
1295 #  include <event.h>
1296 #else
1297 #  include "event2/event.h"
1298 #endif
1299         ])
1300         PC_LIBEVENT_DEPENDENCY="libevent"
1301         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1302         if test -n "$BAK_LDFLAGS_SET"; then
1303                 LDFLAGS="$BAK_LDFLAGS"
1304         fi
1305 else
1306         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1307 fi
1308
1309 # check for libexpat
1310 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1311     [specify explicit path for libexpat.]),
1312     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1313 AC_MSG_CHECKING(for libexpat)
1314 found_libexpat="no"
1315 for dir in $withval ; do
1316             if test -f "$dir/include/expat.h"; then
1317                 found_libexpat="yes"
1318                 dnl assume /usr is in default path.
1319                 if test "$dir" != "/usr"; then
1320                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1321                     LDFLAGS="$LDFLAGS -L$dir/lib"
1322                 fi
1323                 AC_MSG_RESULT(found in $dir)
1324                 break;
1325             fi
1326 done
1327 if test x_$found_libexpat != x_yes; then
1328         AC_ERROR([Could not find libexpat, expat.h])
1329 fi
1330 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1331 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1332 #include <expat.h>
1333 ])
1334
1335 # hiredis (redis C client for cachedb)
1336 AC_ARG_WITH(libhiredis, AC_HELP_STRING([--with-libhiredis=path],
1337     [specify explicit path for libhiredis.]),
1338     [ ],[ withval="no" ])
1339 found_libhiredis="no"
1340 if test x_$withval = x_yes -o x_$withval != x_no; then
1341    AC_MSG_CHECKING(for libhiredis)
1342    if test x_$withval = x_ -o x_$withval = x_yes; then
1343             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1344    fi
1345    for dir in $withval ; do
1346             if test -f "$dir/include/hiredis/hiredis.h"; then
1347                 found_libhiredis="yes"
1348                 dnl assume /usr is in default path.
1349                 if test "$dir" != "/usr"; then
1350                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1351                     LDFLAGS="$LDFLAGS -L$dir/lib"
1352                 fi
1353                 AC_MSG_RESULT(found in $dir)
1354                 AC_DEFINE([USE_REDIS], [1], [Define this to use hiredis client.])
1355                 LIBS="$LIBS -lhiredis"
1356                 break;
1357             fi
1358     done
1359     if test x_$found_libhiredis != x_yes; then
1360         AC_ERROR([Could not find libhiredis, hiredis.h])
1361     fi
1362     AC_CHECK_HEADERS([hiredis/hiredis.h],,, [AC_INCLUDES_DEFAULT])
1363     AC_CHECK_DECLS([redisConnect], [], [], [AC_INCLUDES_DEFAULT
1364     #include <hiredis/hiredis.h>
1365     ])
1366 fi
1367
1368 # set static linking for uninstalled libraries if requested
1369 AC_SUBST(staticexe)
1370 staticexe=""
1371 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1372         [ enable to compile executables statically against (event) uninstalled libs, for debug purposes ]),
1373         , )
1374 if test x_$enable_static_exe = x_yes; then
1375         staticexe="-static"
1376         if test "$on_mingw" = yes; then
1377                 staticexe="-all-static"
1378                 # for static compile, include gdi32 and zlib here.
1379                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1380                         :
1381                 else
1382                         LIBS="$LIBS -lgdi32"
1383                 fi
1384                 LIBS="$LIBS -lz"
1385         fi
1386 fi
1387
1388 # set full static linking if requested
1389 AC_ARG_ENABLE(fully-static, AC_HELP_STRING([--enable-fully-static],
1390         [ enable to compile fully static ]),
1391         , )
1392 if test x_$enable_fully_static = x_yes; then
1393         staticexe="-all-static"
1394         if test "$on_mingw" = yes; then
1395                 # for static compile, include gdi32 and zlib here.
1396                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1397                         :
1398                 else
1399                         LIBS="$LIBS -lgdi32"
1400                 fi
1401                 LIBS="$LIBS -lz"
1402         fi
1403 fi
1404
1405 # set lock checking if requested
1406 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1407         [ enable to check lock and unlock calls, for debug purposes ]),
1408         , )
1409 if test x_$enable_lock_checks = x_yes; then
1410         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1411         CHECKLOCK_OBJ="checklocks.lo"
1412         AC_SUBST(CHECKLOCK_OBJ)
1413 fi
1414
1415 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1416 if test "$USE_WINSOCK" = 1; then
1417         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1418         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1419 #include <windows.h>
1420         ])
1421         AC_CHECK_TOOL(WINDRES, windres)
1422         LIBS="$LIBS -liphlpapi -lcrypt32"
1423         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1424         AC_SUBST(WINAPPS)
1425         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1426         AC_SUBST(WIN_DAEMON_SRC)
1427         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1428         AC_SUBST(WIN_DAEMON_OBJ)
1429         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1430         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1431         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1432         AC_SUBST(WIN_HOST_OBJ_LINK)
1433         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1434         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1435         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1436         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1437         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1438         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1439 fi
1440 if test $ac_cv_func_getaddrinfo = no; then
1441         AC_LIBOBJ([fake-rfc2553])
1442 fi
1443 # check after getaddrinfo for its libraries
1444 ACX_FUNC_IOCTLSOCKET
1445
1446 # see if daemon(3) exists, and if it is deprecated.
1447 AC_CHECK_FUNCS([daemon])
1448 if test $ac_cv_func_daemon = yes; then
1449         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1450 #include <stdlib.h>
1451 ])
1452 fi
1453
1454 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1455 AC_INCLUDES_DEFAULT
1456 #ifdef HAVE_SYS_UN_H
1457 #include <sys/un.h>
1458 #endif
1459 ])
1460 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1461 AC_INCLUDES_DEFAULT
1462 #if HAVE_SYS_PARAM_H
1463 #include <sys/param.h>
1464 #endif
1465
1466 #ifdef HAVE_SYS_SOCKET_H
1467 #include <sys/socket.h>
1468 #endif
1469
1470 #ifdef HAVE_SYS_UIO_H
1471 #include <sys/uio.h>
1472 #endif
1473
1474 #ifdef HAVE_NETINET_IN_H
1475 #include <netinet/in.h>
1476 #endif
1477
1478 #ifdef HAVE_NETINET_TCP_H
1479 #include <netinet/tcp.h>
1480 #endif
1481
1482 #ifdef HAVE_ARPA_INET_H
1483 #include <arpa/inet.h>
1484 #endif
1485
1486 #ifdef HAVE_WINSOCK2_H
1487 #include <winsock2.h>
1488 #endif
1489
1490 #ifdef HAVE_WS2TCPIP_H
1491 #include <ws2tcpip.h>
1492 #endif
1493 ])
1494
1495 AC_MSG_CHECKING([for htobe64])
1496 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1497 #include <stdio.h>
1498 #ifdef HAVE_ENDIAN_H
1499 #  include <endian.h>
1500 #endif
1501 #ifdef HAVE_SYS_ENDIAN_H
1502 #  include <sys/endian.h>
1503 #endif
1504 ], [unsigned long long x = htobe64(0); printf("%u", (unsigned)x);])],
1505   AC_MSG_RESULT(yes)
1506   AC_DEFINE(HAVE_HTOBE64, 1, [If we have htobe64]),
1507   AC_MSG_RESULT(no))
1508
1509 AC_MSG_CHECKING([for be64toh])
1510 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1511 #include <stdio.h>
1512 #ifdef HAVE_ENDIAN_H
1513 #  include <endian.h>
1514 #endif
1515 #ifdef HAVE_SYS_ENDIAN_H
1516 #  include <sys/endian.h>
1517 #endif
1518 ], [unsigned long long x = be64toh(0); printf("%u", (unsigned)x);])],
1519   AC_MSG_RESULT(yes)
1520   AC_DEFINE(HAVE_BE64TOH, 1, [If we have be64toh]),
1521   AC_MSG_RESULT(no))
1522
1523 AC_SEARCH_LIBS([setusercontext], [util])
1524 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget accept4])
1525 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1526 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1527
1528 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1529 if echo $target_os | grep darwin8 > /dev/null; then
1530         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1531 fi
1532 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1533 AC_INCLUDES_DEFAULT
1534 #ifdef HAVE_NETINET_IN_H
1535 #include <netinet/in.h>
1536 #endif
1537
1538 #ifdef HAVE_NETINET_TCP_H
1539 #include <netinet/tcp.h>
1540 #endif
1541
1542 #ifdef HAVE_ARPA_INET_H
1543 #include <arpa/inet.h>
1544 #endif
1545
1546 #ifdef HAVE_WINSOCK2_H
1547 #include <winsock2.h>
1548 #endif
1549
1550 #ifdef HAVE_WS2TCPIP_H
1551 #include <ws2tcpip.h>
1552 #endif
1553 ])
1554 AC_REPLACE_FUNCS(inet_aton)
1555 AC_REPLACE_FUNCS(inet_pton)
1556 AC_REPLACE_FUNCS(inet_ntop)
1557 AC_REPLACE_FUNCS(snprintf)
1558 # test if snprintf return the proper length
1559 if test "x$ac_cv_func_snprintf" = xyes; then
1560     if test c${cross_compiling} = cno; then
1561         AC_MSG_CHECKING([for correct snprintf return value])
1562         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1563 [[
1564 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1565 ]])], [AC_MSG_RESULT(yes)], [
1566                 AC_MSG_RESULT(no)
1567                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1568                 AC_LIBOBJ(snprintf)
1569           ])
1570     fi
1571 fi
1572 AC_REPLACE_FUNCS(strlcat)
1573 AC_REPLACE_FUNCS(strlcpy)
1574 AC_REPLACE_FUNCS(memmove)
1575 AC_REPLACE_FUNCS(gmtime_r)
1576 AC_REPLACE_FUNCS(isblank)
1577 AC_REPLACE_FUNCS(explicit_bzero)
1578 dnl without CTIME, ARC4-functions and without reallocarray.
1579 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1580 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1581 AC_MSG_CHECKING([for reallocarray])
1582 AC_LINK_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1583 [[
1584 #ifndef _OPENBSD_SOURCE
1585 #define _OPENBSD_SOURCE 1
1586 #endif
1587 #include <stdlib.h>
1588 int main(void) {
1589         void* p = reallocarray(NULL, 10, 100);
1590         free(p);
1591         return 0;
1592 }
1593 ]])], [AC_MSG_RESULT(yes)
1594         AC_DEFINE(HAVE_REALLOCARRAY, 1, [If we have reallocarray(3)])
1595 ], [
1596         AC_MSG_RESULT(no)
1597         AC_LIBOBJ(reallocarray)
1598 ])
1599 AC_CHECK_DECLS([reallocarray])
1600 if test "$USE_NSS" = "no"; then
1601         AC_REPLACE_FUNCS(arc4random)
1602         AC_REPLACE_FUNCS(arc4random_uniform)
1603         if test "$ac_cv_func_arc4random" = "no"; then
1604                 AC_LIBOBJ(arc4_lock)
1605                 AC_CHECK_FUNCS([getentropy],,[
1606                     if test "$USE_WINSOCK" = 1; then
1607                         AC_LIBOBJ(getentropy_win)
1608                     else
1609                         case "$host" in
1610                         Darwin|*darwin*)
1611                                 AC_LIBOBJ(getentropy_osx)
1612                         ;;
1613                         *solaris*|*sunos*|SunOS)
1614                                 AC_LIBOBJ(getentropy_solaris)
1615                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1616                                         AC_CHECK_FUNCS([SHA512_Update],,[
1617                                                 AC_LIBOBJ(sha512)
1618                                         ])
1619                                 ], [AC_INCLUDES_DEFAULT])
1620                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1621                                         # this lib needed for sha2 on solaris
1622                                         LIBS="$LIBS -lmd"
1623                                 fi
1624                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1625                         ;;
1626                         *freebsd*|*FreeBSD)
1627                                 AC_LIBOBJ(getentropy_freebsd)
1628                         ;;
1629                         *linux*|Linux|*)
1630                                 AC_LIBOBJ(getentropy_linux)
1631                                 AC_CHECK_FUNCS([SHA512_Update],,[
1632                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1633                                         AC_LIBOBJ(sha512)
1634                                 ])
1635                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1636                                 AC_CHECK_FUNCS([getauxval])
1637                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1638                         ;;
1639                         esac
1640                     fi
1641                 ])
1642         fi
1643 fi
1644 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1645 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1646 AC_REPLACE_FUNCS(ctime_r)
1647 AC_REPLACE_FUNCS(strsep)
1648
1649 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1650 case "$enable_allsymbols" in
1651         yes)
1652         COMMON_OBJ_ALL_SYMBOLS=""
1653         UBSYMS=""
1654         EXTRALINK="-L. -L.libs -lunbound"
1655         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1656         ;;
1657         no|*)
1658         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1659         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1660         EXTRALINK=""
1661         ;;
1662 esac
1663 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1664 AC_SUBST(EXTRALINK)
1665 AC_SUBST(UBSYMS)
1666 if test x_$enable_lock_checks = x_yes; then
1667         UBSYMS="-export-symbols clubsyms.def"
1668         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1669         echo lock_protect >> clubsyms.def
1670         echo lock_unprotect >> clubsyms.def
1671         echo lock_get_mem >> clubsyms.def
1672         echo checklock_start >> clubsyms.def
1673         echo checklock_stop >> clubsyms.def
1674         echo checklock_lock >> clubsyms.def
1675         echo checklock_unlock >> clubsyms.def
1676         echo checklock_init >> clubsyms.def
1677         echo checklock_thrcreate >> clubsyms.def
1678         echo checklock_thrjoin >> clubsyms.def
1679 fi
1680
1681 # check for dnstap if requested
1682 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1683     [
1684         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1685         AC_SUBST([ENABLE_DNSTAP], [1])
1686
1687         AC_SUBST([opt_dnstap_socket_path])
1688         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1689         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1690             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1691
1692         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1693         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1694     ],
1695     [
1696         AC_SUBST([ENABLE_DNSTAP], [0])
1697     ]
1698 )
1699
1700 # check for dnscrypt if requested
1701 dnsc_DNSCRYPT([
1702         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1703         AC_SUBST([ENABLE_DNSCRYPT], [1])
1704
1705         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1706         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1707     ],
1708     [
1709         AC_SUBST([ENABLE_DNSCRYPT], [0])
1710     ]
1711 )
1712
1713 # check for cachedb if requested
1714 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1715 # turn on cachedb when hiredis support is enabled.
1716 if test "$found_libhiredis" = "yes"; then enable_cachedb="yes"; fi
1717 case "$enable_cachedb" in
1718     yes)
1719         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1720         ;;
1721     no|*)
1722         # nothing
1723         ;;
1724 esac
1725
1726 # check for ipsecmod if requested
1727 AC_ARG_ENABLE(ipsecmod, AC_HELP_STRING([--enable-ipsecmod], [Enable ipsecmod module that facilitates opportunistic IPsec]))
1728 case "$enable_ipsecmod" in
1729         yes)
1730                 AC_DEFINE([USE_IPSECMOD], [1], [Define to 1 to use ipsecmod support.])
1731                 IPSECMOD_OBJ="ipsecmod.lo ipsecmod-whitelist.lo"
1732                 AC_SUBST(IPSECMOD_OBJ)
1733                 IPSECMOD_HEADER='$(srcdir)/ipsecmod/ipsecmod.h $(srcdir)/ipsecmod/ipsecmod-whitelist.h'
1734                 AC_SUBST(IPSECMOD_HEADER)
1735                 ;;
1736         no|*)
1737                 # nothing
1738                 ;;
1739 esac
1740
1741 # check for ipset if requested
1742 AC_ARG_ENABLE(ipset, AC_HELP_STRING([--enable-ipset], [enable ipset module]))
1743 case "$enable_ipset" in
1744     yes)
1745                 AC_DEFINE([USE_IPSET], [1], [Define to 1 to use ipset support])
1746                 IPSET_SRC="ipset/ipset.c"
1747                 AC_SUBST(IPSET_SRC)
1748                 IPSET_OBJ="ipset.lo"
1749                 AC_SUBST(IPSET_OBJ)
1750
1751                 # mnl
1752                 AC_ARG_WITH(libmnl, AC_HELP_STRING([--with-libmnl=path],
1753                         [specify explicit path for libmnl.]),
1754                         [ ],[ withval="yes" ])
1755                 found_libmnl="no"
1756                 AC_MSG_CHECKING(for libmnl)
1757                 if test x_$withval = x_ -o x_$withval = x_yes; then
1758                         withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1759                 fi
1760                 for dir in $withval ; do
1761                         if test -f "$dir/include/libmnl/libmnl.h"; then
1762                                 found_libmnl="yes"
1763                                 dnl assume /usr is in default path.
1764                                 if test "$dir" != "/usr"; then
1765                                         CPPFLAGS="$CPPFLAGS -I$dir/include"
1766                                         LDFLAGS="$LDFLAGS -L$dir/lib"
1767                                 fi
1768                                 AC_MSG_RESULT(found in $dir)
1769                                 LIBS="$LIBS -lmnl"
1770                                 break;
1771                         fi
1772                 done
1773                 if test x_$found_libmnl != x_yes; then
1774                         AC_ERROR([Could not find libmnl, libmnl.h])
1775                 fi
1776                 ;;
1777     no|*)
1778         # nothing
1779                 ;;
1780 esac
1781
1782 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1783 # on openBSD, the implicit rule make $< work.
1784 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1785 # gmake works.
1786 cat >conftest.make <<EOF
1787 all:    conftest.lo
1788
1789 conftest.lo foo.lo bla.lo:
1790         if test -f "\$<"; then touch \$@; fi
1791
1792 .SUFFIXES: .lo
1793 .c.lo:
1794         if test -f "\$<"; then touch \$@; fi
1795
1796 conftest.lo:        conftest.dir/conftest.c
1797 EOF
1798 mkdir conftest.dir
1799 touch conftest.dir/conftest.c
1800 rm -f conftest.lo conftest.c
1801 ${MAKE:-make} -f conftest.make >/dev/null
1802 rm -f conftest.make conftest.c conftest.dir/conftest.c
1803 rm -rf conftest.dir
1804 if test ! -f conftest.lo; then
1805         AC_MSG_RESULT(no)
1806         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1807         SOURCEFILE='`cat .source`'
1808 else
1809         AC_MSG_RESULT(yes)
1810         SOURCEDETERMINE=':'
1811         SOURCEFILE='$<'
1812 fi
1813 rm -f conftest.lo
1814 AC_SUBST(SOURCEDETERMINE)
1815 AC_SUBST(SOURCEFILE)
1816
1817 # see if we want to build the library or everything
1818 ALLTARGET="alltargets"
1819 INSTALLTARGET="install-all"
1820 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1821         [do not build daemon and tool programs]),
1822         [
1823         if test "$withval" = "yes"; then
1824                 ALLTARGET="lib"
1825                 INSTALLTARGET="install-lib"
1826         fi
1827 ])
1828 if test $ALLTARGET = "alltargets"; then
1829         if test $USE_NSS = "yes"; then
1830                 AC_ERROR([--with-nss can only be used in combination with --with-libunbound-only.])
1831         fi
1832         if test $USE_NETTLE = "yes"; then
1833                 AC_ERROR([--with-nettle can only be used in combination with --with-libunbound-only.])
1834         fi
1835 fi
1836
1837 AC_SUBST(ALLTARGET)
1838 AC_SUBST(INSTALLTARGET)
1839
1840 ACX_STRIP_EXT_FLAGS
1841 if test -n "$LATE_LDFLAGS"; then
1842   LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1843 fi
1844 # remove start spaces
1845 LDFLAGS=`echo "$LDFLAGS"|sed -e 's/^ *//'`
1846 LIBS=`echo "$LIBS"|sed -e 's/^ *//'`
1847
1848 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1849
1850 AH_BOTTOM(
1851 dnl this must be first AH_CONFIG, to define the flags before any includes.
1852 AHX_CONFIG_EXT_FLAGS
1853
1854 dnl includes
1855 [
1856 #ifndef _OPENBSD_SOURCE
1857 #define _OPENBSD_SOURCE 1
1858 #endif
1859
1860 #ifndef UNBOUND_DEBUG
1861 # ifndef NDEBUG
1862 #  define NDEBUG
1863 # endif
1864 #endif
1865
1866 /** Use small-ldns codebase */
1867 #define USE_SLDNS 1
1868 #ifdef HAVE_SSL
1869 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1870 #endif
1871
1872 #include <stdio.h>
1873 #include <string.h>
1874 #include <unistd.h>
1875 #include <assert.h>
1876
1877 #if STDC_HEADERS
1878 #include <stdlib.h>
1879 #include <stddef.h>
1880 #endif
1881
1882 #ifdef HAVE_STDARG_H
1883 #include <stdarg.h>
1884 #endif
1885
1886 #ifdef HAVE_STDINT_H
1887 #include <stdint.h>
1888 #endif
1889
1890 #include <errno.h>
1891
1892 #if HAVE_SYS_PARAM_H
1893 #include <sys/param.h>
1894 #endif
1895
1896 #ifdef HAVE_SYS_SOCKET_H
1897 #include <sys/socket.h>
1898 #endif
1899
1900 #ifdef HAVE_SYS_UIO_H
1901 #include <sys/uio.h>
1902 #endif
1903
1904 #ifdef HAVE_NETINET_IN_H
1905 #include <netinet/in.h>
1906 #endif
1907
1908 #ifdef HAVE_NETINET_TCP_H
1909 #include <netinet/tcp.h>
1910 #endif
1911
1912 #ifdef HAVE_ARPA_INET_H
1913 #include <arpa/inet.h>
1914 #endif
1915
1916 #ifdef HAVE_WINSOCK2_H
1917 #include <winsock2.h>
1918 #endif
1919
1920 #ifdef HAVE_WS2TCPIP_H
1921 #include <ws2tcpip.h>
1922 #endif
1923
1924 #ifndef USE_WINSOCK
1925 #define ARG_LL "%ll"
1926 #else
1927 #define ARG_LL "%I64"
1928 #endif
1929
1930 #ifndef AF_LOCAL
1931 #define AF_LOCAL AF_UNIX
1932 #endif
1933 ]
1934
1935 AHX_CONFIG_FORMAT_ATTRIBUTE
1936 AHX_CONFIG_UNUSED_ATTRIBUTE
1937 AHX_CONFIG_FSEEKO
1938 AHX_CONFIG_MAXHOSTNAMELEN
1939 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1940 #define snprintf snprintf_unbound
1941 #define vsnprintf vsnprintf_unbound
1942 #include <stdarg.h>
1943 int snprintf (char *str, size_t count, const char *fmt, ...);
1944 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1945 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1946 AHX_CONFIG_INET_PTON(unbound)
1947 AHX_CONFIG_INET_NTOP(unbound)
1948 AHX_CONFIG_INET_ATON(unbound)
1949 AHX_CONFIG_MEMMOVE(unbound)
1950 AHX_CONFIG_STRLCAT(unbound)
1951 AHX_CONFIG_STRLCPY(unbound)
1952 AHX_CONFIG_GMTIME_R(unbound)
1953 AHX_CONFIG_REALLOCARRAY(unbound)
1954 AHX_CONFIG_W32_SLEEP
1955 AHX_CONFIG_W32_USLEEP
1956 AHX_CONFIG_W32_RANDOM
1957 AHX_CONFIG_W32_SRANDOM
1958 AHX_CONFIG_W32_FD_SET_T
1959 AHX_CONFIG_IPV6_MIN_MTU
1960 AHX_MEMCMP_BROKEN(unbound)
1961
1962 [
1963 #ifndef HAVE_CTIME_R
1964 #define ctime_r unbound_ctime_r
1965 char *ctime_r(const time_t *timep, char *buf);
1966 #endif
1967
1968 #ifndef HAVE_STRSEP
1969 #define strsep unbound_strsep
1970 char *strsep(char **stringp, const char *delim);
1971 #endif
1972
1973 #ifndef HAVE_ISBLANK
1974 #define isblank unbound_isblank
1975 int isblank(int c);
1976 #endif
1977
1978 #ifndef HAVE_EXPLICIT_BZERO
1979 #define explicit_bzero unbound_explicit_bzero
1980 void explicit_bzero(void* buf, size_t len);
1981 #endif
1982
1983 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
1984 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
1985 #endif
1986
1987 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
1988 int inet_pton(int af, const char* src, void* dst);
1989 #endif
1990
1991 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1992 #define strptime unbound_strptime
1993 struct tm;
1994 char *strptime(const char *s, const char *format, struct tm *tm);
1995 #endif
1996
1997 #if !HAVE_DECL_REALLOCARRAY
1998 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1999 #endif
2000
2001 #ifdef HAVE_LIBBSD
2002 #include <bsd/string.h>
2003 #include <bsd/stdlib.h>
2004 #endif
2005
2006 #ifdef HAVE_LIBRESSL
2007 #  if !HAVE_DECL_STRLCPY
2008 size_t strlcpy(char *dst, const char *src, size_t siz);
2009 #  endif
2010 #  if !HAVE_DECL_STRLCAT
2011 size_t strlcat(char *dst, const char *src, size_t siz);
2012 #  endif
2013 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
2014 uint32_t arc4random(void);
2015 #  endif
2016 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
2017 uint32_t arc4random_uniform(uint32_t upper_bound);
2018 #  endif
2019 #endif /* HAVE_LIBRESSL */
2020 #ifndef HAVE_ARC4RANDOM
2021 int getentropy(void* buf, size_t len);
2022 uint32_t arc4random(void);
2023 void arc4random_buf(void* buf, size_t n);
2024 void _ARC4_LOCK(void);
2025 void _ARC4_UNLOCK(void);
2026 void _ARC4_LOCK_DESTROY(void);
2027 #endif
2028 #ifndef HAVE_ARC4RANDOM_UNIFORM
2029 uint32_t arc4random_uniform(uint32_t upper_bound);
2030 #endif
2031 #ifdef COMPAT_SHA512
2032 #ifndef SHA512_DIGEST_LENGTH
2033 #define SHA512_BLOCK_LENGTH             128
2034 #define SHA512_DIGEST_LENGTH            64
2035 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
2036 typedef struct _SHA512_CTX {
2037         uint64_t        state[8];
2038         uint64_t        bitcount[2];
2039         uint8_t buffer[SHA512_BLOCK_LENGTH];
2040 } SHA512_CTX;
2041 #endif /* SHA512_DIGEST_LENGTH */
2042 void SHA512_Init(SHA512_CTX*);
2043 void SHA512_Update(SHA512_CTX*, void*, size_t);
2044 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
2045 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
2046 #endif /* COMPAT_SHA512 */
2047
2048
2049
2050 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
2051    /* using version of libevent that is not threadsafe. */
2052 #  define LIBEVENT_SIGNAL_PROBLEM 1
2053 #endif
2054
2055 #ifndef CHECKED_INET6
2056 #  define CHECKED_INET6
2057 #  ifdef AF_INET6
2058 #    define INET6
2059 #  else
2060 #    define AF_INET6        28
2061 #  endif
2062 #endif /* CHECKED_INET6 */
2063
2064 #ifndef HAVE_GETADDRINFO
2065 struct sockaddr_storage;
2066 #include "compat/fake-rfc2553.h"
2067 #endif
2068
2069 #ifdef UNBOUND_ALLOC_STATS
2070 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
2071 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
2072 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
2073 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
2074 void *unbound_stat_malloc(size_t size);
2075 void *unbound_stat_calloc(size_t nmemb, size_t size);
2076 void unbound_stat_free(void *ptr);
2077 void *unbound_stat_realloc(void *ptr, size_t size);
2078 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
2079         const char* func);
2080 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
2081         int line, const char* func);
2082 void unbound_stat_free_log(void *ptr, const char* file, int line,
2083         const char* func);
2084 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
2085         int line, const char* func);
2086 #elif defined(UNBOUND_ALLOC_LITE)
2087 #  include "util/alloc.h"
2088 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
2089
2090 /** default port for DNS traffic. */
2091 #define UNBOUND_DNS_PORT 53
2092 /** default port for DNS over TLS traffic. */
2093 #define UNBOUND_DNS_OVER_TLS_PORT 853
2094 /** default port for unbound control traffic, registered port with IANA,
2095     ub-dns-control  8953/tcp    unbound dns nameserver control */
2096 #define UNBOUND_CONTROL_PORT 8953
2097 /** the version of unbound-control that this software implements */
2098 #define UNBOUND_CONTROL_VERSION 1
2099
2100 ])
2101
2102 dnl if we build from source tree, the man pages need @date@ and @version@
2103 dnl if this is a distro tarball, that was already done by makedist.sh
2104 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
2105 AC_SUBST(date, [`date +'%b %e, %Y'`])
2106
2107 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service contrib/unbound_portable.service])
2108 AC_CONFIG_HEADER([config.h])
2109 AC_OUTPUT