cddl/contrib/dtracetoolkit/Ruby/rb_flowinfo.d

   1 #!/usr/sbin/dtrace -Zs
   2 /*
   3  * rb_flowinfo.d - snoop Ruby function (method) flow with info using DTrace.
   4  *                 Written for the Ruby DTrace provider.
   5  *
   6  * $Id: rb_flowinfo.d 41 2007-09-17 02:20:10Z brendan $
   7  *
   8  * This traces activity from all Ruby programs on the system that are
   9  * running with Ruby provider support.
  10  *
  11  * USAGE: rb_flowinfo.d         # hit Ctrl-C to end
  12  *
  13  * FIELDS:
  14  *              C               CPU-id
  15  *              PID             Process ID
  16  *              DELTA(us)       Elapsed time from previous line to this line
  17  *              FILE            Filename of the Ruby program
  18  *              LINE            Line number of filename
  19  *              TYPE            Type of call (method)
  20  *              NAME            Ruby class and method name
  21  *
  22  * LEGEND:
  23  *              ->              method entry
  24  *              <-              method return
  25  *
  26  * Filename and method names are printed if available.
  27  *
  28  * WARNING: Watch the first column carefully, it prints the CPU-id. If it
  29  * changes, then it is very likely that the output has been shuffled.
  30  *
  31  * COPYRIGHT: Copyright (c) 2007 Brendan Gregg.
  32  *
  33  * CDDL HEADER START
  34  *
  35  *  The contents of this file are subject to the terms of the
  36  *  Common Development and Distribution License, Version 1.0 only
  37  *  (the "License").  You may not use this file except in compliance
  38  *  with the License.
  39  *
  40  *  You can obtain a copy of the license at Docs/cddl1.txt
  41  *  or http://www.opensolaris.org/os/licensing.
  42  *  See the License for the specific language governing permissions
  43  *  and limitations under the License.
  44  *
  45  * CDDL HEADER END
  46  *
  47  * 09-Sep-2007  Brendan Gregg   Created this.
  48  */
  49
  50 #pragma D option quiet
  51 #pragma D option switchrate=10
  52
  53 self int depth;
  54
  55 dtrace:::BEGIN
  56 {
  57         printf("%s %6s %10s  %16s:%-4s %-8s -- %s\n", "C", "PID", "DELTA(us)",
  58             "FILE", "LINE", "TYPE", "NAME");
  59 }
  60
  61 ruby*:::function-entry,
  62 ruby*:::function-return
  63 /self->last == 0/
  64 {
  65         self->last = timestamp;
  66 }
  67
  68 ruby*:::function-entry
  69 {
  70         this->delta = (timestamp - self->last) / 1000;
  71         this->name = strjoin(strjoin(copyinstr(arg0), "::"), copyinstr(arg1));
  72         printf("%d %6d %10d  %16s:%-4d %-8s %*s-> %s\n", cpu, pid, this->delta,
  73             basename(copyinstr(arg2)), arg3, "method", self->depth * 2, "",
  74             this->name);
  75         self->depth++;
  76         self->last = timestamp;
  77 }
  78
  79 ruby*:::function-return
  80 {
  81         this->delta = (timestamp - self->last) / 1000;
  82         self->depth -= self->depth > 0 ? 1 : 0;
  83         this->name = strjoin(strjoin(copyinstr(arg0), "::"), copyinstr(arg1));
  84         printf("%d %6d %10d  %16s:%-4d %-8s %*s<- %s\n", cpu, pid, this->delta,
  85             basename(copyinstr(arg2)), arg3, "method", self->depth * 2, "",
  86             this->name);
  87         self->last = timestamp;
  88 }