contrib/binutils/gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 AC_ARG_ENABLE(targets,
  26 [  --enable-targets        alternative target configurations besides the primary],
  27 [case "${enableval}" in
  28   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  29             ;;
  30   no)       enable_targets= ;;
  31   *)        enable_targets=$enableval ;;
  32 esac])dnl
  33
  34 AC_ARG_ENABLE(commonbfdlib,
  35 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  36 [case "${enableval}" in
  37   yes) commonbfdlib=true ;;
  38   no)  commonbfdlib=false ;;
  39   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  40 esac])dnl
  41
  42 ac_checking=yes
  43 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  44   ac_checking=
  45 fi
  46 AC_ARG_ENABLE(checking,
  47 [  --enable-checking       enable run-time checks],
  48 [case "${enableval}" in
  49   no|none)  ac_checking= ;;
  50   *)        ac_checking=yes ;;
  51 esac])dnl
  52 if test x$ac_checking != x ; then
  53   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  54 fi
  55
  56 using_cgen=no
  57
  58 AM_BINUTILS_WARNINGS
  59
  60 # Generate a header file
  61 AM_CONFIG_HEADER(config.h:config.in)
  62
  63 # If we are on a DOS filesystem, we must use gdb.ini rather than
  64 # .gdbinit.
  65 case "${host}" in
  66   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  67     GDBINIT="gdb.ini"
  68     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  69     ;;
  70   *)
  71     GDBINIT=".gdbinit"
  72     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  73     ;;
  74 esac
  75 AC_SUBST(GDBINIT)
  76
  77 #We need this for the host.  BOUT header is in host order.
  78 AC_C_BIGENDIAN
  79
  80 te_file=generic
  81
  82 # Makefile target for installing gas in $(tooldir)/bin.
  83 install_tooldir=install-exec-tooldir
  84
  85 canon_targets=""
  86 all_targets=no
  87 if test -n "$enable_targets" ; then
  88   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  89     if test $t = "all"; then
  90       all_targets=yes
  91       continue
  92     fi
  93     result=`$ac_config_sub $t 2>/dev/null`
  94     if test -n "$result" ; then
  95       canon_targets="$canon_targets $result"
  96 #    else
  97 #      # Permit "all", etc.  We don't support it yet though.
  98 #      canon_targets="$canon_targets $t"
  99     fi
 100   done
 101   GAS_UNIQ(canon_targets)
 102 fi
 103
 104 emulations=""
 105
 106 for this_target in $target $canon_targets ; do
 107
 108     targ=${this_target}
 109     . ${srcdir}/configure.tgt
 110
 111     case ${target_cpu} in
 112       crisv32)
 113         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 114                            [Default CRIS architecture.])
 115         ;;
 116     esac
 117
 118     if test ${this_target} = $target ; then
 119       target_cpu_type=${cpu_type}
 120     elif test ${target_cpu_type} != ${cpu_type} ; then
 121       continue
 122     fi
 123
 124     generic_target=${cpu_type}-${target_vendor}-${target_os}
 125     case ${generic_target} in
 126       i386-*-sco3.2v5*)
 127         if test ${this_target} = $target; then
 128           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 129         fi
 130         ;;
 131
 132       i386-*-msdosdjgpp* \
 133       | i386-*-go32* \
 134       | i386-go32-rtems*)
 135         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 136         ;;
 137
 138       i860-*-*)
 139         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 140         ;;
 141
 142       mips-sony-bsd*)
 143         ;;
 144       mips-*-bsd*)
 145         AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.)
 146         ;;
 147
 148       ppc-*-aix5.*)
 149         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 150                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 151         ;;
 152       ppc-*-linux-*)
 153         case "$endian" in
 154           big)  ;;
 155           *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 156         esac
 157         ;;
 158       ppc-*-solaris*)
 159         if test ${this_target} = $target; then
 160           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 161                     [Define if default target is PowerPC Solaris.])
 162         fi
 163         if test x${endian} = xbig; then
 164           AC_MSG_ERROR(Solaris must be configured little endian)
 165         fi
 166         ;;
 167
 168       sh*-*-symbianelf*)
 169         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 170         ;;
 171     esac
 172
 173     if test ${this_target} = $target ; then
 174       endian_def=
 175       if test x${endian} = xbig; then
 176         endian_def=1
 177       elif test x${endian} = xlittle; then
 178         endian_def=0
 179       fi
 180       if test x${endian_def} != x; then
 181         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 182                            [Define as 1 if big endian.])
 183       fi
 184     fi
 185
 186 # Other random stuff.
 187
 188     case ${cpu_type} in
 189       mips)
 190         # Set mips_cpu to the name of the default CPU.
 191         case ${target_cpu} in
 192           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 193             mips_cpu=from-abi
 194             ;;
 195           mipsisa32 | mipsisa32el)
 196             mips_cpu=mips32
 197             ;;
 198           mipsisa32r2 | mipsisa32r2el)
 199             mips_cpu=mips32r2
 200             ;;
 201           mipsisa64 | mipsisa64el)
 202             mips_cpu=mips64
 203             ;;
 204           mipsisa64r2 | mipsisa64r2el)
 205             mips_cpu=mips64r2
 206             ;;
 207           mipstx39 | mipstx39el)
 208             mips_cpu=r3900
 209             ;;
 210           mips64vr | mips64vrel)
 211             mips_cpu=vr4100
 212             ;;
 213           mipsisa32r2* | mipsisa64r2*)
 214 changequote(,)dnl
 215             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 216 changequote([,])dnl
 217             ;;
 218           mips64* | mipsisa64* | mipsisa32*)
 219 changequote(,)dnl
 220             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 221 changequote([,])dnl
 222             ;;
 223           *)
 224             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 225             ;;
 226         esac
 227         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 228         # binaries.  It's a GNU extension that some OSes don't understand.
 229         # The value only matters on ELF targets.
 230         case ${target} in
 231           *-*-irix*)
 232             use_e_mips_abi_o32=0
 233             ;;
 234           *)
 235             use_e_mips_abi_o32=1
 236             ;;
 237         esac
 238         # Decide whether to generate 32-bit or 64-bit code by default.
 239         # Used to resolve -march=from-abi when an embedded ABI is selected.
 240         case ${target} in
 241           mips64*-*-* | mipsisa64*-*-*)
 242             mips_default_64bit=1
 243             ;;
 244           *)
 245             mips_default_64bit=0
 246             ;;
 247         esac
 248         # Decide which ABI to target by default.
 249         case ${target} in
 250           mips64*-linux* | mips-sgi-irix6*)
 251             mips_default_abi=N32_ABI
 252             ;;
 253           mips*-linux*)
 254             mips_default_abi=O32_ABI
 255             ;;
 256           mips64*-openbsd*)
 257             mips_default_abi=N64_ABI
 258             ;;
 259           *)
 260             mips_default_abi=NO_ABI
 261             ;;
 262         esac
 263         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 264                            [Default CPU for MIPS targets. ])
 265         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 266                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 267         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 268                            [Generate 64-bit code by default on MIPS targets. ])
 269         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 270                            [Choose a default ABI for MIPS targets. ])
 271         ;;
 272     esac
 273
 274     # Do we need the opcodes library?
 275     case ${cpu_type} in
 276       vax | tic30)
 277         ;;
 278
 279       *)
 280         need_opcodes=yes
 281
 282         case "${enable_shared}" in
 283         yes) shared_opcodes=true ;;
 284         *opcodes*) shared_opcodes=true ;;
 285         *) shared_opcodes=false ;;
 286         esac
 287         ;;
 288     esac
 289
 290     # Any other special object files needed ?
 291     case ${cpu_type} in
 292
 293       bfin)
 294         echo ${extra_objects} | grep -s "bfin-parse.o"
 295         if test $? -ne 0 ; then
 296           extra_objects="$extra_objects bfin-parse.o"
 297         fi
 298
 299         echo ${extra_objects} | grep -s "bfin-lex.o"
 300         if test $? -ne 0 ; then
 301           extra_objects="$extra_objects bfin-lex.o"
 302         fi
 303         ;;
 304
 305       fr30 | ip2k | iq2000 | m32r | openrisc)
 306         using_cgen=yes
 307         ;;
 308
 309       m32c)
 310         using_cgen=yes
 311         ;;
 312       frv)
 313         using_cgen=yes
 314         ;;
 315       m68k)
 316         case ${extra_objects} in
 317         *m68k-parse.o*) ;;
 318         *) extra_objects="$extra_objects m68k-parse.o" ;;
 319         esac
 320         ;;
 321
 322       mep)
 323         using_cgen=yes
 324         ;;
 325
 326       mips)
 327         echo ${extra_objects} | grep -s "itbl-parse.o"
 328         if test $? -ne 0 ; then
 329           extra_objects="$extra_objects itbl-parse.o"
 330         fi
 331
 332         echo ${extra_objects} | grep -s "itbl-lex.o"
 333         if test $? -ne 0 ; then
 334           extra_objects="$extra_objects itbl-lex.o"
 335         fi
 336
 337         echo ${extra_objects} | grep -s "itbl-ops.o"
 338         if test $? -ne 0 ; then
 339           extra_objects="$extra_objects itbl-ops.o"
 340         fi
 341         ;;
 342
 343       mt)
 344         using_cgen=yes
 345         ;;
 346
 347       i386 | s390 | sparc)
 348         if test $this_target = $target ; then
 349           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 350         fi
 351         ;;
 352
 353       xstormy16)
 354         using_cgen=yes
 355         ;;
 356
 357       xc16x)
 358         using_cgen=yes
 359         ;;
 360
 361       xtensa)
 362         echo ${extra_objects} | grep -s "xtensa-relax.o"
 363         if test $? -ne 0 ; then
 364           extra_objects="$extra_objects xtensa-relax.o"
 365         fi
 366         ;;
 367
 368       *)
 369         ;;
 370     esac
 371
 372     if test $using_cgen = yes ; then
 373         case "x${extra_objects}" in
 374         *cgen.o*) ;;
 375         *) extra_objects="$extra_objects cgen.o" ;;
 376         esac
 377     fi
 378
 379 # See if we really can support this configuration with the emulation code.
 380
 381     if test $this_target = $target ; then
 382       obj_format=$fmt
 383       te_file=$em
 384     fi
 385
 386 # From target name and format, produce a list of supported emulations.
 387
 388     case ${generic_target}-${fmt} in
 389       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 390       mips*-*-linux*-*) case "$endian" in
 391                         big)    emulation="mipsbelf mipslelf mipself" ;;
 392                         *)      emulation="mipslelf mipsbelf mipself" ;;
 393                         esac ;;
 394       mips-*-lnews*-ecoff) ;;
 395       mips-*-*-ecoff)   case "$endian" in
 396                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 397                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 398                         esac ;;
 399       mips-*-*-elf)     case "$endian" in
 400                         big)    emulation="mipsbelf mipslelf mipself" ;;
 401                         *)      emulation="mipslelf mipsbelf mipself" ;;
 402                         esac ;;
 403       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 404       # i386-pc-pe-coff != i386-pc-coff.
 405       i386-*-pe-coff)   ;;
 406       # Uncommenting the next line will turn on support for i386 AOUT
 407       # for the default linux configuration
 408       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 409       #
 410       i386-*-aout)      emulation="i386aout" ;;
 411       i386-*-coff)      emulation="i386coff" ;;
 412       i386-*-elf)       emulation="i386elf" ;;
 413
 414       # Always all formats.  The first stated emulation becomes the default.
 415       cris-*-*aout*)    emulation="crisaout criself" ;;
 416       cris-*-*)         emulation="criself crisaout" ;;
 417     esac
 418
 419     emulations="$emulations $emulation"
 420
 421 done
 422
 423 # Turn on all targets if possible
 424 if test ${all_targets} = "yes"; then
 425   case ${target_cpu_type} in
 426   i386)
 427     case ${obj_format} in
 428     aout)
 429       emulations="$emulations i386coff i386elf"
 430       ;;
 431     coff)
 432       emulations="$emulations i386aout i386elf"
 433     ;;
 434     elf)
 435       emulations="$emulations i386aout i386coff"
 436       ;;
 437     esac
 438   ;;
 439   x86_64)
 440     case ${obj_format} in
 441     aout)
 442       emulations="$emulations i386coff i386elf"
 443       ;;
 444     coff)
 445       emulations="$emulations i386aout i386elf"
 446     ;;
 447     elf)
 448       emulations="$emulations i386aout i386coff"
 449       ;;
 450     esac
 451   ;;
 452   esac
 453 fi
 454
 455 # Assign floating point type.  Most processors with FP support
 456 # IEEE FP.  On those that don't support FP at all, usually IEEE
 457 # is emulated.
 458 case ${target_cpu} in
 459   vax | pdp11 ) atof=vax ;;
 460   *)            atof=ieee ;;
 461 esac
 462
 463 case "${obj_format}" in
 464   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 465 esac
 466
 467 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 468 cgen_cpu_prefix=""
 469 if test $using_cgen = yes ; then
 470   case ${target_cpu} in
 471     *) cgen_cpu_prefix=${target_cpu} ;;
 472   esac
 473   AC_SUBST(cgen_cpu_prefix)
 474   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 475 fi
 476
 477 dnl
 478 dnl Make sure the desired support files exist.
 479 dnl
 480
 481 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 482   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 483 fi
 484
 485 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 486   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 487 fi
 488
 489 # Some COFF configurations want these random other flags set.
 490 case ${obj_format} in
 491   coff)
 492     case ${target_cpu_type} in
 493       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 494       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 495       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 496       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 497     esac
 498     ;;
 499 esac
 500
 501 # Getting this done right is going to be a bitch.  Each configuration specified
 502 # with --enable-targets=... should be checked for environment, format, cpu
 503 # setting.
 504 #
 505 # For each configuration, the necessary object file support code must be linked
 506 # in.  This might be only one, it might be up to four.  The necessary emulation
 507 # code needs to be provided, too.
 508 #
 509 # And then there's "--enable-targets=all"....
 510 #
 511 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 512
 513 formats="${obj_format}"
 514 emfiles=""
 515 EMULATIONS=""
 516 GAS_UNIQ(emulations)
 517 for em in . $emulations ; do
 518   case $em in
 519     .)  continue ;;
 520     mipsbelf | mipslelf | mipself)
 521         fmt=elf   file=mipself ;;
 522     mipsbecoff | mipslecoff | mipsecoff)
 523         fmt=ecoff file=mipsecoff ;;
 524     *coff)
 525         fmt=coff  file=$em ;;
 526     *aout)
 527         fmt=aout file=$em ;;
 528     *elf)
 529         fmt=elf file=$em ;;
 530   esac
 531   formats="$formats $fmt"
 532   emfiles="$emfiles e-$file.o"
 533   EMULATIONS="$EMULATIONS &$em,"
 534 done
 535 GAS_UNIQ(formats)
 536 GAS_UNIQ(emfiles)
 537 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 538   for fmt in $formats ; do
 539     case $fmt in
 540       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 541       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 542       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 543       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 544       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 545       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 546       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 547     esac
 548     extra_objects="$extra_objects obj-$fmt.o"
 549   done
 550   obj_format=multi
 551 fi
 552 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 553   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 554   # e-mips* has more than one emulation per file, e-i386* has just one at the
 555   # moment.  If only one emulation is specified, then don't define
 556   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 557   case "${obj_format}${emfiles}" in
 558     multi* | *mips*)
 559       extra_objects="$extra_objects $emfiles"
 560       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 561   esac
 562 fi
 563 AC_SUBST(extra_objects)
 564 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 565 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 566                    [Default emulation.])
 567
 568 reject_dev_configs=yes
 569
 570 case ${reject_dev_configs}-${dev} in
 571   yes-yes) # Oops.
 572     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 573     ;;
 574 esac
 575
 576 AC_SUBST(target_cpu_type)
 577 AC_SUBST(obj_format)
 578 AC_SUBST(te_file)
 579 AC_SUBST(install_tooldir)
 580 AC_SUBST(atof)
 581 dnl AC_SUBST(emulation)
 582
 583 # do we need the opcodes library?
 584 case "${need_opcodes}" in
 585 yes)
 586   OPCODES_LIB=../opcodes/libopcodes.la
 587   ;;
 588 esac
 589
 590 AC_SUBST(OPCODES_LIB)
 591
 592 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 593 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 594 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 595 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 596 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 597
 598 AC_PROG_CC
 599
 600 AC_PROG_YACC
 601 AM_PROG_LEX
 602
 603 ALL_LINGUAS="fr tr es rw"
 604 ZW_GNU_GETTEXT_SISTER_DIR
 605 AM_PO_SUBDIRS
 606
 607 AM_MAINTAINER_MODE
 608 AM_CONDITIONAL(GENINSRC_NEVER, false)
 609 AC_EXEEXT
 610
 611 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 612
 613 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 614 # people who are not cross-compiling but are compiling cross-assemblers.
 615 AC_MSG_CHECKING(whether compiling a cross-assembler)
 616 if test "${host}" = "${target}"; then
 617   cross_gas=no
 618 else
 619   cross_gas=yes
 620   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 621 fi
 622 AC_MSG_RESULT($cross_gas)
 623
 624 dnl ansidecl.h will deal with const
 625 dnl AC_CONST
 626 AC_FUNC_ALLOCA
 627 AC_C_INLINE
 628
 629 # VMS doesn't have unlink.
 630 AC_CHECK_FUNCS(unlink remove, break)
 631
 632 # Some systems don't have sbrk().
 633 AC_CHECK_FUNCS(sbrk)
 634
 635 # do we need the math library?
 636 case "${need_libm}" in
 637 yes)
 638   AC_CHECK_LIBM
 639   AC_SUBST(LIBM)
 640   ;;
 641 esac
 642
 643 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 644 # enough, but on some of those systems, the assert macro relies on requoting
 645 # working properly!
 646 GAS_WORKING_ASSERT
 647
 648 # On some systems, the system header files may not declare malloc, realloc,
 649 # and free.  There are places where gas needs these functions to have been
 650 # declared -- such as when taking their addresses.
 651 gas_test_headers="
 652 #ifdef HAVE_MEMORY_H
 653 #include <memory.h>
 654 #endif
 655 #ifdef HAVE_STRING_H
 656 #include <string.h>
 657 #else
 658 #ifdef HAVE_STRINGS_H
 659 #include <strings.h>
 660 #endif
 661 #endif
 662 #ifdef HAVE_STDLIB_H
 663 #include <stdlib.h>
 664 #endif
 665 #ifdef HAVE_UNISTD_H
 666 #include <unistd.h>
 667 #endif
 668 "
 669
 670 # Does errno.h declare errno, or do we have to add a separate declaration
 671 # for it?
 672 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 673 #ifdef HAVE_ERRNO_H
 674 #include <errno.h>
 675 #endif
 676 ])
 677
 678 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 679 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 680 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 681 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 682 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 683 if test $gas_cv_decl_getopt_unistd_h = yes; then
 684   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 685             [Is the prototype for getopt in <unistd.h> in the expected format?])
 686 fi
 687
 688 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 689 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 690 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 691 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 692 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 693 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 694
 695 AC_CHECK_DECLS([vsnprintf])
 696
 697 BFD_BINARY_FOPEN
 698
 699 dnl Required for html and install-html targets.
 700 AC_SUBST(datarootdir)
 701 AC_SUBST(docdir)
 702 AC_SUBST(htmldir)
 703
 704 dnl This must come last.
 705
 706 dnl We used to make symlinks to files in the source directory, but now
 707 dnl we just use the right name for .c files, and create .h files in
 708 dnl the build directory which include the right .h file.  Make sure
 709 dnl the old symlinks don't exist, so that a reconfigure in an existing
 710 dnl directory behaves reasonably.
 711
 712 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 713 AC_CONFIG_COMMANDS([default],
 714 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 715  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 716  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 717  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 718  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 719  if test "x$cgen_cpu_prefix" != x ; then
 720    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 721  fi],
 722 [target_cpu_type=${target_cpu_type}
 723  cgen_cpu_prefix=${cgen_cpu_prefix}
 724  obj_format=${obj_format}
 725  te_file=${te_file}])
 726
 727 AC_OUTPUT