contrib/llvm/include/llvm/Option/OptParser.td

   1 //===--- OptParser.td - Common Option Parsing Interfaces ------------------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //  This file defines the common interfaces used by the option parsing TableGen
  11 //  backend.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 // Define the kinds of options.
  16
  17 class OptionKind<string name, int predecence = 0, bit sentinel = 0> {
  18   string Name = name;
  19   // The kind precedence, kinds with lower precedence are matched first.
  20   int Precedence = predecence;
  21   // Indicate a sentinel option.
  22   bit Sentinel = sentinel;
  23 }
  24
  25 // An option group.
  26 def KIND_GROUP : OptionKind<"Group">;
  27 // The input option kind.
  28 def KIND_INPUT : OptionKind<"Input", 1, 1>;
  29 // The unknown option kind.
  30 def KIND_UNKNOWN : OptionKind<"Unknown", 2, 1>;
  31 // A flag with no values.
  32 def KIND_FLAG : OptionKind<"Flag">;
  33 // An option which prefixes its (single) value.
  34 def KIND_JOINED : OptionKind<"Joined", 1>;
  35 // An option which is followed by its value.
  36 def KIND_SEPARATE : OptionKind<"Separate">;
  37 // An option followed by its values, which are separated by commas.
  38 def KIND_COMMAJOINED : OptionKind<"CommaJoined">;
  39 // An option which is which takes multiple (separate) arguments.
  40 def KIND_MULTIARG : OptionKind<"MultiArg">;
  41 // An option which is either joined to its (non-empty) value, or followed by its
  42 // value.
  43 def KIND_JOINED_OR_SEPARATE : OptionKind<"JoinedOrSeparate">;
  44 // An option which is both joined to its (first) value, and followed by its
  45 // (second) value.
  46 def KIND_JOINED_AND_SEPARATE : OptionKind<"JoinedAndSeparate">;
  47
  48 // Define the option flags.
  49
  50 class OptionFlag {}
  51
  52 // HelpHidden - The option should not be displayed in --help, even if it has
  53 // help text. Clients *can* use this in conjunction with the OptTable::PrintHelp
  54 // arguments to implement hidden help groups.
  55 def HelpHidden : OptionFlag;
  56
  57 // RenderAsInput - The option should not render the name when rendered as an
  58 // input (i.e., the option is rendered as values).
  59 def RenderAsInput : OptionFlag;
  60
  61 // RenderJoined - The option should be rendered joined, even if separate (only
  62 // sensible on single value separate options).
  63 def RenderJoined : OptionFlag;
  64
  65 // RenderSeparate - The option should be rendered separately, even if joined
  66 // (only sensible on joined options).
  67 def RenderSeparate : OptionFlag;
  68
  69 // Define the option group class.
  70
  71 class OptionGroup<string name> {
  72   string EnumName = ?; // Uses the def name if undefined.
  73   string Name = name;
  74   string HelpText = ?;
  75   OptionGroup Group = ?;
  76 }
  77
  78 // Define the option class.
  79
  80 class Option<list<string> prefixes, string name, OptionKind kind> {
  81   string EnumName = ?; // Uses the def name if undefined.
  82   list<string> Prefixes = prefixes;
  83   string Name = name;
  84   OptionKind Kind = kind;
  85   // Used by MultiArg option kind.
  86   int NumArgs = 0;
  87   string HelpText = ?;
  88   string MetaVarName = ?;
  89   list<OptionFlag> Flags = [];
  90   OptionGroup Group = ?;
  91   Option Alias = ?;
  92 }
  93
  94 // Helpers for defining options.
  95
  96 class Flag<list<string> prefixes, string name>
  97   : Option<prefixes, name, KIND_FLAG>;
  98 class Joined<list<string> prefixes, string name>
  99   : Option<prefixes, name, KIND_JOINED>;
 100 class Separate<list<string> prefixes, string name>
 101   : Option<prefixes, name, KIND_SEPARATE>;
 102 class CommaJoined<list<string> prefixes, string name>
 103   : Option<prefixes, name, KIND_COMMAJOINED>;
 104 class MultiArg<list<string> prefixes, string name, int numargs>
 105   : Option<prefixes, name, KIND_MULTIARG> {
 106   int NumArgs = numargs;
 107 }
 108 class JoinedOrSeparate<list<string> prefixes, string name>
 109   : Option<prefixes, name, KIND_JOINED_OR_SEPARATE>;
 110 class JoinedAndSeparate<list<string> prefixes, string name>
 111   : Option<prefixes, name, KIND_JOINED_AND_SEPARATE>;
 112
 113 // Mix-ins for adding optional attributes.
 114
 115 class Alias<Option alias> { Option Alias = alias; }
 116 class EnumName<string name> { string EnumName = name; }
 117 class Flags<list<OptionFlag> flags> { list<OptionFlag> Flags = flags; }
 118 class Group<OptionGroup group> { OptionGroup Group = group; }
 119 class HelpText<string text> { string HelpText = text; }
 120 class MetaVarName<string name> { string MetaVarName = name; }
 121
 122 // Predefined options.
 123
 124 // FIXME: Have generator validate that these appear in correct position (and
 125 // aren't duplicated).
 126 def INPUT : Option<[], "<input>", KIND_INPUT>;
 127 def UNKNOWN : Option<[], "<unknown>", KIND_UNKNOWN>;