lib/libc/i386/gen/sigsetjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 4. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  *
  32  *      @(#)setjmp.s    5.1 (Berkeley) 4/23/90"
  33  */
  34
  35 #if defined(LIBC_SCCS) && !defined(lint)
  36         .text
  37         .asciz "$Id: sigsetjmp.S,v 1.1 1993/12/05 13:01:05 ats Exp $"
  38 #endif /* LIBC_SCCS and not lint */
  39 #include <machine/asm.h>
  40 __FBSDID("$FreeBSD$");
  41
  42 #include "SYS.h"
  43
  44 /*-
  45  * TODO:
  46  *      Rename sigsetjmp to __sigsetjmp and siglongjmp to __siglongjmp,
  47  *      remove the other *jmp functions and define everything in terms
  48  *      of the renamed functions.  This requires compiler support for
  49  *      the renamed functions (introduced in gcc-2.5.3; previous versions
  50  *      only supported *jmp with 0 or 1 leading underscores).
  51  *
  52  *      Restore _all_ the registers and the signal mask atomically.  Can
  53  *      use sigreturn() if sigreturn() works.
  54  */
  55
  56 ENTRY(sigsetjmp)
  57         movl    8(%esp),%eax
  58         movl    4(%esp),%ecx
  59         movl    %eax,44(%ecx)
  60         testl   %eax,%eax
  61         jz      2f
  62         PIC_PROLOGUE
  63 #ifdef PIC
  64         subl    $12,%esp                /* make the stack 16-byte aligned */
  65 #endif
  66         leal    28(%ecx), %eax
  67         pushl   %eax                    /* (sigset_t*)oset */
  68         pushl   $0                      /* (sigset_t*)set  */
  69         pushl   $1                      /* SIG_BLOCK       */
  70         call    PIC_PLT(CNAME(_sigprocmask))
  71 #ifdef PIC
  72         addl    $24,%esp
  73 #else
  74         addl    $12,%esp
  75 #endif
  76         PIC_EPILOGUE
  77         movl    4(%esp),%ecx
  78 2:      movl    0(%esp),%edx
  79         movl    %edx, 0(%ecx)
  80         movl    %ebx, 4(%ecx)
  81         movl    %esp, 8(%ecx)
  82         movl    %ebp,12(%ecx)
  83         movl    %esi,16(%ecx)
  84         movl    %edi,20(%ecx)
  85         fnstcw  24(%ecx)
  86         xorl    %eax,%eax
  87         ret
  88 END(sigsetjmp)
  89
  90         .weak CNAME(siglongjmp);
  91         .set CNAME(siglongjmp),CNAME(__siglongjmp)
  92 ENTRY(__siglongjmp)
  93         movl    4(%esp),%edx
  94         cmpl    $0,44(%edx)
  95         jz      2f
  96         PIC_PROLOGUE
  97 #ifdef PIC
  98         subl    $12,%esp                /* make the stack 16-byte aligned */
  99 #endif
 100         pushl   $0                      /* (sigset_t*)oset */
 101         leal    28(%edx), %eax
 102         pushl   %eax                    /* (sigset_t*)set  */
 103         pushl   $3                      /* SIG_SETMASK     */
 104         call    PIC_PLT(CNAME(_sigprocmask))
 105 #ifdef PIC
 106         addl    $24,%esp
 107 #else
 108         addl    $12,%esp
 109 #endif
 110         PIC_EPILOGUE
 111         movl    4(%esp),%edx
 112 2:      movl    8(%esp),%eax
 113         movl    0(%edx),%ecx
 114         movl    4(%edx),%ebx
 115         movl    8(%edx),%esp
 116         movl    12(%edx),%ebp
 117         movl    16(%edx),%esi
 118         movl    20(%edx),%edi
 119         fninit
 120         fldcw   24(%edx)
 121         testl   %eax,%eax
 122         jnz     1f
 123         incl    %eax
 124 1:      movl    %ecx,0(%esp)
 125         ret
 126 END(__siglongjmp)
 127
 128         .section .note.GNU-stack,"",%progbits