lib/libc/i386/string/memset.S

   1 /*
   2  * Copyright (c) 1993 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  */
  30
  31 #include <machine/asm.h>
  32 __FBSDID("$FreeBSD$");
  33
  34 /*
  35  * memset(void *b, int c, size_t len)
  36  *      write len bytes of value c (converted to an unsigned char) to
  37  *      the string b.
  38  *
  39  * Written by:
  40  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  41  */
  42
  43 ENTRY(memset)
  44         pushl   %edi
  45         pushl   %ebx
  46         movl    12(%esp),%edi
  47         movzbl  16(%esp),%eax           /* unsigned char, zero extend */
  48         movl    20(%esp),%ecx
  49         pushl   %edi                    /* push address of buffer */
  50
  51         cld                             /* set fill direction forward */
  52
  53         /*
  54          * if the string is too short, it's really not worth the overhead
  55          * of aligning to word boundries, etc.  So we jump to a plain
  56          * unaligned set.
  57          */
  58         cmpl    $0x0f,%ecx
  59         jle     L1
  60
  61         movb    %al,%ah                 /* copy char to all bytes in word */
  62         movl    %eax,%edx
  63         sall    $16,%eax
  64         orl     %edx,%eax
  65
  66         movl    %edi,%edx               /* compute misalignment */
  67         negl    %edx
  68         andl    $3,%edx
  69         movl    %ecx,%ebx
  70         subl    %edx,%ebx
  71
  72         movl    %edx,%ecx               /* set until word aligned */
  73         rep
  74         stosb
  75
  76         movl    %ebx,%ecx
  77         shrl    $2,%ecx                 /* set by words */
  78         rep
  79         stosl
  80
  81         movl    %ebx,%ecx               /* set remainder by bytes */
  82         andl    $3,%ecx
  83 L1:     rep
  84         stosb
  85
  86         popl    %eax                    /* pop address of buffer */
  87         popl    %ebx
  88         popl    %edi
  89         ret
  90 END(memset)
  91
  92         .section .note.GNU-stack,"",%progbits