lib/libc/i386/string/strcat.S

   1 /*
   2  * Copyright (c) 1993 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  */
  30
  31 #include <machine/asm.h>
  32 __FBSDID("$FreeBSD$");
  33
  34 /*
  35  * strcat(s, append)
  36  *      append a copy of the null-terminated string "append" to the end
  37  *      of the null-terminated string s, then add a terminating `\0'.
  38  *
  39  * Written by:
  40  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  41  */
  42
  43 /*
  44  * I've unrolled the loop eight times: large enough to make a
  45  * significant difference, and small enough not to totally trash the
  46  * cache.
  47  */
  48
  49 ENTRY(strcat)
  50         pushl   %edi                    /* save edi */
  51         movl    8(%esp),%edi            /* dst address */
  52         movl    12(%esp),%edx           /* src address */
  53         pushl   %edi                    /* push destination address */
  54
  55         cld                             /* set search forward */
  56         xorl    %eax,%eax               /* set search for null terminator */
  57         movl    $-1,%ecx                /* set search for lots of characters */
  58         repne                           /* search! */
  59         scasb
  60
  61         leal    -1(%edi),%ecx           /* correct dst address */
  62
  63         .align 2,0x90
  64 L1:     movb    (%edx),%al              /* unroll loop, but not too much */
  65         movb    %al,(%ecx)
  66         testb   %al,%al
  67         je      L2
  68         movb    1(%edx),%al
  69         movb    %al,1(%ecx)
  70         testb   %al,%al
  71         je      L2
  72         movb    2(%edx),%al
  73         movb    %al,2(%ecx)
  74         testb   %al,%al
  75         je      L2
  76         movb    3(%edx),%al
  77         movb    %al,3(%ecx)
  78         testb   %al,%al
  79         je      L2
  80         movb    4(%edx),%al
  81         movb    %al,4(%ecx)
  82         testb   %al,%al
  83         je      L2
  84         movb    5(%edx),%al
  85         movb    %al,5(%ecx)
  86         testb   %al,%al
  87         je      L2
  88         movb    6(%edx),%al
  89         movb    %al,6(%ecx)
  90         testb   %al,%al
  91         je      L2
  92         movb    7(%edx),%al
  93         movb    %al,7(%ecx)
  94         addl    $8,%edx
  95         addl    $8,%ecx
  96         testb   %al,%al
  97         jne     L1
  98 L2:     popl    %eax                    /* pop destination address */
  99         popl    %edi                    /* restore edi */
 100         ret
 101 END(strcat)
 102
 103         .section .note.GNU-stack,"",%progbits