lib/libc/ia64/gen/__divdf3.S

   1 //
   2 // Copyright (c) 2000, Intel Corporation
   3 // All rights reserved.
   4 //
   5 // Contributed 2/15/2000 by Marius Cornea, John Harrison, Cristina Iordache,
   6 // Ted Kubaska, Bob Norin, and Shane Story of the Computational Software Lab,
   7 // Intel Corporation.
   8 //
   9 // WARRANTY DISCLAIMER
  10 //
  11 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  12 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  13 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  14 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  15 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  16 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  17 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  18 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  19 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  20 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  21 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  22 //
  23 // Intel Corporation is the author of this code, and requests that all
  24 // problem reports or change requests be submitted to it directly at
  25 // http://developer.intel.com/opensource.
  26 //
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31   .section .text
  32
  33 ENTRY(__divdf3, 0)
  34 { .mfi
  35   // a is in f8
  36   // b is in f9
  37
  38   // predicate registers used: p6
  39   // floating-point registers used: f6, f7, f8, f9, f10, f11
  40
  41   // load a, the first argument, in f6
  42   nop.m 0
  43   mov f6=f8
  44   nop.i 0
  45 } { .mfi
  46   // load b, the second argument, in f7
  47   nop.m 0
  48   mov f7=f9
  49   nop.i 0;;
  50 } { .mfi
  51
  52   // BEGIN DOUBLE PRECISION LATENCY-OPTIMIZED DIVIDE ALGORITHM
  53
  54   nop.m 0
  55   // Step (1)
  56   // y0 = 1 / b in f8
  57   frcpa.s0 f8,p6=f6,f7
  58   nop.i 0;;
  59 } { .mfi
  60   nop.m 0
  61   // Step (2)
  62   // q0 = a * y0 in f9
  63   (p6) fma.s1 f9=f6,f8,f0
  64   nop.i 0
  65 } { .mfi
  66   nop.m 0
  67   // Step (3)
  68   // e0 = 1 - b * y0 in f10
  69   (p6) fnma.s1 f10=f7,f8,f1
  70   nop.i 0;;
  71 } { .mfi
  72   nop.m 0
  73   // Step (4)
  74   // q1 = q0 + e0 * q0 in f9
  75   (p6) fma.s1 f9=f10,f9,f9
  76   nop.i 0
  77 } { .mfi
  78   nop.m 0
  79   // Step (5)
  80   // e1 = e0 * e0 in f11
  81   (p6) fma.s1 f11=f10,f10,f0
  82   nop.i 0
  83 } { .mfi
  84   nop.m 0
  85   // Step (6)
  86   // y1 = y0 + e0 * y0 in f8
  87   (p6) fma.s1 f8=f10,f8,f8
  88   nop.i 0;;
  89 } { .mfi
  90   nop.m 0
  91   // Step (7)
  92   // q2 = q1 + e1 * q1 in f9
  93   (p6) fma.s1 f9=f11,f9,f9
  94   nop.i 0
  95 } { .mfi
  96   nop.m 0
  97   // Step (8)
  98   // e2 = e1 * e1 in f10
  99   (p6) fma.s1 f10=f11,f11,f0
 100   nop.i 0
 101 } { .mfi
 102   nop.m 0
 103   // Step (9)
 104   // y2 = y1 + e1 * y1 in f8
 105   (p6) fma.s1 f8=f11,f8,f8
 106   nop.i 0;;
 107 } { .mfi
 108   nop.m 0
 109   // Step (10)
 110   // q3 = q2 + e2 * q2 in f9
 111   (p6) fma.d.s1 f9=f10,f9,f9
 112   nop.i 0;;
 113 } { .mfi
 114   nop.m 0
 115   // Step (11)
 116   // y3 = y2 + e2 * y2 in f8
 117   (p6) fma.s1 f8=f10,f8,f8
 118   nop.i 0;;
 119 } { .mfi
 120   nop.m 0
 121   // Step (12)
 122   // r0 = a - b * q3 in f6
 123   (p6) fnma.d.s1 f6=f7,f9,f6
 124   nop.i 0;;
 125 } { .mfi
 126   nop.m 0
 127   // Step (13)
 128   // q4 = q3 + r0 * y3 in f8
 129   (p6) fma.d.s0 f8=f6,f8,f9
 130   nop.i 0;;
 131
 132   // END DOUBLE PRECISION LATENCY-OPTIMIZED DIVIDE ALGORITHM
 133
 134 } { .mib
 135   nop.m 0
 136   nop.i 0
 137   // return
 138   br.ret.sptk b0;;
 139 }
 140
 141 END(__divdf3)
 142