lib/libc/ia64/string/ffs.S

   1 /*      $NetBSD: ffs.S,v 1.3 1996/10/17 03:08:13 cgd Exp $      */
   2
   3 /*
   4  * Copyright (c) 1995 Christopher G. Demetriou
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. All advertising materials mentioning features or use of this software
  16  *    must display the following acknowledgement:
  17  *      This product includes software developed by Christopher G. Demetriou
  18  *      for the NetBSD Project.
  19  * 4. The name of the author may not be used to endorse or promote products
  20  *    derived from this software without specific prior written permission
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  23  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  24  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  25  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  26  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  27  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  28  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  29  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  30  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  31  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  32  */
  33
  34 #include <machine/asm.h>
  35 __FBSDID("$FreeBSD$");
  36
  37 ENTRY(ffs, 1)
  38         sxt4    r14=in0 ;;
  39         cmp.eq  p6,p0=r14,r0
  40 (p6)    br.dpnt.few Lallzero
  41
  42         /*
  43          * Initialize return value (ret0), and set up r15 so that it
  44          * contains the mask with only the lowest bit set.
  45          */
  46         sub     r15=r0,r14
  47         mov     ret0=1 ;;
  48         and     r15=r14,r15 ;;
  49
  50         extr.u  r16=r15,0,8 ;;
  51         cmp.ne  p6,p0=r0,r16
  52 (p6)    br.dptk.few Ldo8
  53
  54         /*
  55          * If lower 16 bits empty, add 16 to result and use upper 16.
  56          */
  57         extr.u  r16=r15,0,16 ;;
  58         cmp.ne  p6,p0=r0,r16
  59 (p6)    br.dptk.few Ldo16
  60         extr.u  r15=r15,16,16
  61         add     ret0=16,ret0 ;;
  62
  63 Ldo16:
  64         /*
  65          * If lower 8 bits empty, add 8 to result and use upper 8.
  66          */
  67         extr.u  r16=r15,0,8 ;;
  68         cmp.ne  p6,p0=r0,r16
  69 (p6)    br.dptk.few Ldo8
  70         extr.u  r15=r15,8,24
  71         add     ret0=8,ret0 ;;
  72
  73 Ldo8:
  74         and     r16=0x0f,r15            /* lower 4 of 8 empty? */
  75         and     r17=0x33,r15            /* lower 2 of each 4 empty? */
  76         and     r18=0x55,r15 ;;         /* lower 1 of each 2 empty? */
  77         cmp.ne  p6,p0=r16,r0
  78         cmp.ne  p7,p0=r17,r0
  79         cmp.ne  p8,p0=r18,r0
  80
  81         /* If lower 4 bits empty, add 4 to result. */
  82 (p6)    br.dptk.few Ldo4
  83         add     ret0=4,ret0 ;;
  84
  85 Ldo4:   /* If lower 2 bits of each 4 empty, add 2 to result. */
  86 (p7)    br.dptk.few Ldo2
  87         add     ret0=2,ret0 ;;
  88
  89 Ldo2:   /* If lower bit of each 2 empty, add 1 to result. */
  90 (p8)    br.dptk.few Ldone
  91         add     ret0=1,ret0
  92
  93 Ldone:
  94         br.ret.sptk.few rp
  95
  96 Lallzero:
  97         mov     ret0=0
  98         br.ret.sptk.few rp
  99 END(ffs)