lib/libc/mips/string/bcmp.S

   1 /*      $NetBSD: bcmp.S,v 1.9 2009/12/14 01:07:42 matt Exp $    */
   2
   3 /*-
   4  * Copyright (c) 1991, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * Ralph Campbell.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/asm.h>
  36 __FBSDID("$FreeBSD$");
  37
  38 #define _LOCORE         /* XXX not really, just assembly-code source */
  39 #include <machine/endian.h>     /* LWLO/LWHI, SWLO/SWHI */
  40
  41 #if defined(LIBC_SCCS) && !defined(lint)
  42 #if 0
  43         ASMSTR("from: @(#)bcmp.s        8.1 (Berkeley) 6/4/93")
  44 #else
  45         ASMSTR("$NetBSD: bcmp.S,v 1.9 2009/12/14 01:07:42 matt Exp $")
  46 #endif
  47 #endif /* LIBC_SCCS and not lint */
  48
  49 #ifdef __ABICALLS__
  50         .abicalls
  51 #endif
  52
  53 /* bcmp(s1, s2, n) */
  54
  55
  56 LEAF(bcmp)
  57         .set    noreorder
  58         blt             a2, 16, small   # is it worth any trouble?
  59         xor             v0, a0, a1      # compare low two bits of addresses
  60         and             v0, v0, 3
  61         PTR_SUBU        a3, zero, a1    # compute # bytes to word align address
  62         bne             v0, zero, unaligned # not possible to align addresses
  63         and             a3, a3, 3
  64
  65         beq             a3, zero, 1f
  66         PTR_SUBU        a2, a2, a3      # subtract from remaining count
  67         move            v0, v1          # init v0,v1 so unmodified bytes match
  68         LWHI            v0, 0(a0)       # read 1, 2, or 3 bytes
  69         LWHI            v1, 0(a1)
  70         PTR_ADDU        a1, a1, a3
  71         bne             v0, v1, nomatch
  72         PTR_ADDU        a0, a0, a3
  73 1:
  74         and             a3, a2, ~3      # compute number of whole words left
  75         PTR_SUBU        a2, a2, a3      #   which has to be >= (16-3) & ~3
  76         PTR_ADDU        a3, a3, a0      # compute ending address
  77 2:
  78         lw              v0, 0(a0)       # compare words
  79         lw              v1, 0(a1)
  80         PTR_ADDU        a0, a0, 4
  81         bne             v0, v1, nomatch
  82         PTR_ADDU        a1, a1, 4
  83         bne             a0, a3, 2b
  84         nop
  85         b               small           # finish remainder
  86         nop
  87 unaligned:
  88         beq             a3, zero, 2f
  89         PTR_SUBU        a2, a2, a3      # subtract from remaining count
  90         PTR_ADDU        a3, a3, a0      # compute ending address
  91 1:
  92         lbu             v0, 0(a0)       # compare bytes until a1 word aligned
  93         lbu             v1, 0(a1)
  94         PTR_ADDU        a0, a0, 1
  95         bne             v0, v1, nomatch
  96         PTR_ADDU        a1, a1, 1
  97         bne             a0, a3, 1b
  98         nop
  99 2:
 100         and             a3, a2, ~3      # compute number of whole words left
 101         PTR_SUBU        a2, a2, a3      #   which has to be >= (16-3) & ~3
 102         PTR_ADDU        a3, a3, a0      # compute ending address
 103 3:
 104         LWHI            v0, 0(a0)       # compare words a0 unaligned, a1 aligned
 105         LWLO            v0, 3(a0)
 106         lw              v1, 0(a1)
 107         PTR_ADDU        a0, a0, 4
 108         bne             v0, v1, nomatch
 109         PTR_ADDU        a1, a1, 4
 110         bne             a0, a3, 3b
 111         nop
 112 small:
 113         ble             a2, zero, match
 114         PTR_ADDU        a3, a2, a0              # compute ending address
 115 1:
 116         lbu             v0, 0(a0)
 117         lbu             v1, 0(a1)
 118         PTR_ADDU        a0, a0, 1
 119         bne             v0, v1, nomatch
 120         PTR_ADDU        a1, a1, 1
 121         bne             a0, a3, 1b
 122         nop
 123 match:
 124         j               ra
 125         move            v0, zero
 126 nomatch:
 127         j               ra
 128         li              v0, 1
 129         .set    reorder
 130 END(bcmp)