lib/libc/net/nslexer.l

   1 %{
   2 /*      $NetBSD: nslexer.l,v 1.3 1999/01/25 00:16:17 lukem Exp $        */
   3
   4 /*-
   5  * Copyright (c) 1997, 1998, 1999 The NetBSD Foundation, Inc.
   6  * All rights reserved.
   7  *
   8  * This code is derived from software contributed to The NetBSD Foundation
   9  * by Luke Mewburn.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  21  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  22  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  23  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  24  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  25  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  26  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  27  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  28  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  29  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  30  * POSSIBILITY OF SUCH DAMAGE.
  31  */
  32
  33 #include <sys/cdefs.h>
  34 #if defined(LIBC_SCCS) && !defined(lint)
  35 static char *rcsid =
  36   "$FreeBSD$";
  37 #endif /* LIBC_SCCS and not lint */
  38
  39 #include "namespace.h"
  40 #include <ctype.h>
  41 #define _NS_PRIVATE
  42 #include <nsswitch.h>
  43 #include <string.h>
  44 #include <syslog.h>
  45 #include "un-namespace.h"
  46
  47 #include "nsparser.h"
  48
  49 %}
  50
  51 %option noinput
  52 %option nounput
  53 %option yylineno
  54
  55 BLANK           [ \t]
  56 CR              \n
  57 STRING          [a-zA-Z][a-zA-Z0-9_]*
  58
  59 %%
  60
  61 {BLANK}+        ;                       /* skip whitespace */
  62
  63 #.*             ;                       /* skip comments */
  64
  65 \\{CR}          ;                       /* allow continuation */
  66
  67 {CR}            return NL;
  68
  69 [sS][uU][cC][cC][eE][sS][sS]            return SUCCESS;
  70 [uU][nN][aA][vV][aA][iI][lL]            return UNAVAIL;
  71 [nN][oO][tT][fF][oO][uU][nN][dD]        return NOTFOUND;
  72 [tT][rR][yY][aA][gG][aA][iI][nN]        return TRYAGAIN;
  73
  74 [rR][eE][tT][uU][rR][nN]                return RETURN;
  75 [cC][oO][nN][tT][iI][nN][uU][eE]        return CONTINUE;
  76
  77 {STRING}        {
  78                         char *p;
  79                         int i;
  80
  81                         if ((p = strdup(yytext)) == NULL) {
  82                                 syslog(LOG_ERR,
  83                                "NSSWITCH(nslexer): memory allocation failure");
  84                                 return ERRORTOKEN;
  85                         }
  86                         for (i = 0; i < strlen(p); i++) {
  87                                 if (isupper((unsigned char)p[i]))
  88                                         p[i] = tolower((unsigned char)p[i]);
  89                         }
  90                         _nsyylval.str = p;
  91                         return STRING;
  92                 }
  93
  94 .               return yytext[0];
  95
  96 %%
  97
  98 #undef _nsyywrap
  99 int
 100 _nsyywrap()
 101 {
 102         return 1;
 103 } /* _nsyywrap */
 104
 105 void
 106 _nsyyerror(msg)
 107         const char *msg;
 108 {
 109
 110          syslog(LOG_ERR, "NSSWITCH(nslexer): %s line %d: %s at '%s'",
 111              _PATH_NS_CONF, yylineno, msg, yytext);
 112 } /* _nsyyerror */