lib/libc/net/nsparser.y

   1 %{
   2 /*      $NetBSD: nsparser.y,v 1.3 1999/01/25 00:16:18 lukem Exp $       */
   3
   4 /*-
   5  * Copyright (c) 1997, 1998, 1999 The NetBSD Foundation, Inc.
   6  * All rights reserved.
   7  *
   8  * This code is derived from software contributed to The NetBSD Foundation
   9  * by Luke Mewburn.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  21  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  22  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  23  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  24  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  25  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  26  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  27  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  28  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  29  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  30  * POSSIBILITY OF SUCH DAMAGE.
  31  */
  32
  33 #include <sys/cdefs.h>
  34 __FBSDID("$FreeBSD$");
  35
  36 #include "namespace.h"
  37 #define _NS_PRIVATE
  38 #include <nsswitch.h>
  39 #include <stdio.h>
  40 #include <stdlib.h>
  41 #include <string.h>
  42 #include <syslog.h>
  43 #include "un-namespace.h"
  44
  45 static  void    _nsaddsrctomap(const char *);
  46
  47 static  ns_dbt          curdbt;
  48 static  ns_src          cursrc;
  49 %}
  50
  51 %union {
  52         char *str;
  53         int   mapval;
  54 }
  55
  56 %token  NL
  57 %token  SUCCESS UNAVAIL NOTFOUND TRYAGAIN
  58 %token  RETURN CONTINUE
  59 %token  ERRORTOKEN
  60 %token  <str> STRING
  61
  62 %type   <mapval> Status Action
  63
  64 %%
  65
  66 File
  67         :       /* empty */
  68         | Lines
  69         ;
  70
  71 Lines
  72         : Entry
  73         | Lines Entry
  74         ;
  75
  76 Entry
  77         : NL
  78         | Database ':' NL
  79                 {
  80                         free((char*)curdbt.name);
  81                 }
  82         | Database ':' Srclist NL
  83                 {
  84                         _nsdbtput(&curdbt);
  85                 }
  86         | error NL
  87                 {
  88                         yyerrok;
  89                 }
  90         ;
  91
  92 Database
  93         : STRING
  94                 {
  95                         curdbt.name = yylval.str;
  96                         curdbt.srclist = NULL;
  97                         curdbt.srclistsize = 0;
  98                 }
  99         ;
 100
 101 Srclist
 102         : Item
 103         | Srclist Item
 104         ;
 105
 106 Item
 107         : STRING
 108                 {
 109                         cursrc.flags = NS_TERMINATE;
 110                         _nsaddsrctomap($1);
 111                 }
 112         | STRING '[' { cursrc.flags = NS_SUCCESS; } Criteria ']'
 113                 {
 114                         _nsaddsrctomap($1);
 115                 }
 116         ;
 117
 118 Criteria
 119         : Criterion
 120         | Criteria Criterion
 121         ;
 122
 123 Criterion
 124         : Status '=' Action
 125                 {
 126                         if ($3)      /* if action == RETURN set RETURN bit */
 127                                 cursrc.flags |= $1;
 128                         else         /* else unset it */
 129                                 cursrc.flags &= ~$1;
 130                 }
 131         ;
 132
 133 Status
 134         : SUCCESS       { $$ = NS_SUCCESS; }
 135         | UNAVAIL       { $$ = NS_UNAVAIL; }
 136         | NOTFOUND      { $$ = NS_NOTFOUND; }
 137         | TRYAGAIN      { $$ = NS_TRYAGAIN; }
 138         ;
 139
 140 Action
 141         : RETURN        { $$ = NS_ACTION_RETURN; }
 142         | CONTINUE      { $$ = NS_ACTION_CONTINUE; }
 143         ;
 144
 145 %%
 146
 147 static void
 148 _nsaddsrctomap(elem)
 149         const char *elem;
 150 {
 151         int             i, lineno;
 152         extern int      _nsyylineno;
 153         extern char *   _nsyytext;
 154
 155         lineno = _nsyylineno - (*_nsyytext == '\n' ? 1 : 0);
 156         if (curdbt.srclistsize > 0) {
 157                 if (((strcasecmp(elem, NSSRC_COMPAT) == 0) &&
 158                     (strcasecmp(curdbt.srclist[0].name, NSSRC_CACHE) != 0)) ||
 159                     (strcasecmp(curdbt.srclist[0].name, NSSRC_COMPAT) == 0)) {
 160                         syslog(LOG_ERR,
 161             "NSSWITCH(nsparser): %s line %d: 'compat' used with sources, other than 'cache'",
 162                             _PATH_NS_CONF, lineno);
 163                         free((void*)elem);
 164                         return;
 165                 }
 166         }
 167         for (i = 0; i < curdbt.srclistsize; i++) {
 168                 if (strcasecmp(curdbt.srclist[i].name, elem) == 0) {
 169                         syslog(LOG_ERR,
 170                        "NSSWITCH(nsparser): %s line %d: duplicate source '%s'",
 171                             _PATH_NS_CONF, lineno, elem);
 172                         free((void*)elem);
 173                         return;
 174                 }
 175         }
 176         cursrc.name = elem;
 177         _nsdbtaddsrc(&curdbt, &cursrc);
 178 }