lib/libc/powerpc/gen/setjmp.S

   1 /*-
   2  * Copyright (c) 2002 Peter Grehan.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  */
  26 /*      $NetBSD: setjmp.S,v 1.3 1998/10/03 12:30:38 tsubai Exp $        */
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 #include <sys/syscall.h>
  32
  33 /*
  34  * C library -- setjmp, longjmp
  35  *
  36  *      longjmp(a,v)
  37  * will generate a "return(v?v:1)" from the last call to
  38  *      setjmp(a)
  39  * by restoring registers from the stack.
  40  * The previous signal state is restored.
  41  *
  42  * jmpbuf layout:
  43  *     +------------+
  44  *     |   unused   |
  45  *     +------------+
  46  *     | sig state  |
  47  *     |            |
  48  *     | (4 words)  |
  49  *     |            |
  50  *     +------------+
  51  *     | saved regs |
  52  *     |    ...     |
  53  */
  54
  55 ENTRY(setjmp)
  56         mr      %r6,%r3
  57         li      %r3,1                   /* SIG_BLOCK, but doesn't matter */
  58                                         /*            since set == NULL  */
  59         li      %r4,0                   /* set = NULL */
  60         mr      %r5,%r6                 /* &oset */
  61         addi    %r5,%r5,4
  62         li      %r0, SYS_sigprocmask    /*sigprocmask(SIG_BLOCK, NULL, &oset)*/
  63         sc                              /*assume no error       XXX */
  64         mflr    %r11                    /* r11 <- link reg */
  65         mfcr    %r12                    /* r12 <- condition reg */
  66         mr      %r10,%r1                /* r10 <- stackptr */
  67         mr      %r9,%r2                 /*  r9 <- global ptr */
  68         stmw    %r9,20(%r6)
  69         li      %r3,0                   /* return (0) */
  70         blr
  71
  72         WEAK_REFERENCE(CNAME(__longjmp), longjmp)
  73 ENTRY(__longjmp)
  74         lmw     %r9,20(%r3)             /* restore regs */
  75         mr      %r6,%r4                 /* save val param */
  76         mtlr    %r11                    /* r11 -> link reg */
  77         mtcr    %r12                    /* r12 -> condition reg */
  78         mr      %r1,%r10                /* r10 -> stackptr */
  79         mr      %r4,%r3
  80         li      %r3,3                   /* SIG_SETMASK */
  81         addi    %r4,%r4,4               /* &set */
  82         li      %r5,0                   /* oset = NULL */
  83         li      %r0,SYS_sigprocmask     /* sigprocmask(SIG_SET, &set, NULL) */
  84         sc                              /* assume no error       XXX */
  85         or.     %r3,%r6,%r6
  86         bnelr
  87         li      %r3,1
  88         blr
  89
  90         .section .note.GNU-stack,"",%progbits