lib/libc/powerpc64/gen/_setjmp.S

   1 /*-
   2  * Copyright (c) 2002 Peter Grehan.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  */
  26 /*      $NetBSD: _setjmp.S,v 1.1 1997/03/29 20:55:53 thorpej Exp $      */
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 /*
  32  * C library -- _setjmp, _longjmp
  33  *
  34  *      _longjmp(a,v)
  35  * will generate a "return(v?v:1)" from the last call to
  36  *      _setjmp(a)
  37  * by restoring registers from the stack.
  38  * The previous signal state is NOT restored.
  39  *
  40  * jmpbuf layout:
  41  *     +------------+
  42  *     |   unused   |
  43  *     +------------+
  44  *     |   unused   |
  45  *     |            |
  46  *     | (4 words)  |
  47  *     |            |
  48  *     +------------+
  49  *     | saved regs |
  50  *     |    ...     |
  51  */
  52
  53 ENTRY(_setjmp)
  54         mflr    %r11
  55         mfcr    %r12
  56         mr      %r10,%r1
  57         mr      %r9,%r2
  58         std     %r9,40 + 0*8(%r3)
  59         std     %r10,40 + 1*8(%r3)
  60         std     %r11,40 + 2*8(%r3)
  61         std     %r12,40 + 3*8(%r3)
  62         std     %r13,40 + 4*8(%r3)
  63         std     %r14,40 + 5*8(%r3)
  64         std     %r15,40 + 6*8(%r3)
  65         std     %r16,40 + 7*8(%r3)
  66         std     %r17,40 + 8*8(%r3)
  67         std     %r18,40 + 9*8(%r3)
  68         std     %r19,40 + 10*8(%r3)
  69         std     %r20,40 + 11*8(%r3)
  70         std     %r21,40 + 12*8(%r3)
  71         std     %r22,40 + 13*8(%r3)
  72         std     %r23,40 + 14*8(%r3)
  73         std     %r24,40 + 15*8(%r3)
  74         std     %r25,40 + 16*8(%r3)
  75         std     %r26,40 + 17*8(%r3)
  76         std     %r27,40 + 18*8(%r3)
  77         std     %r28,40 + 19*8(%r3)
  78         std     %r29,40 + 20*8(%r3)
  79         std     %r30,40 + 21*8(%r3)
  80         std     %r31,40 + 22*8(%r3)
  81         li      %r3,0
  82         blr
  83
  84 ENTRY(_longjmp)
  85         ld      %r9,40 + 0*8(%r3)
  86         ld      %r10,40 + 1*8(%r3)
  87         ld      %r11,40 + 2*8(%r3)
  88         ld      %r12,40 + 3*8(%r3)
  89         ld      %r14,40 + 5*8(%r3)
  90         ld      %r15,40 + 6*8(%r3)
  91         ld      %r16,40 + 7*8(%r3)
  92         ld      %r17,40 + 8*8(%r3)
  93         ld      %r18,40 + 9*8(%r3)
  94         ld      %r19,40 + 10*8(%r3)
  95         ld      %r20,40 + 11*8(%r3)
  96         ld      %r21,40 + 12*8(%r3)
  97         ld      %r22,40 + 13*8(%r3)
  98         ld      %r23,40 + 14*8(%r3)
  99         ld      %r24,40 + 15*8(%r3)
 100         ld      %r25,40 + 16*8(%r3)
 101         ld      %r26,40 + 17*8(%r3)
 102         ld      %r27,40 + 18*8(%r3)
 103         ld      %r28,40 + 19*8(%r3)
 104         ld      %r29,40 + 20*8(%r3)
 105         ld      %r30,40 + 21*8(%r3)
 106         ld      %r31,40 + 22*8(%r3)
 107
 108         mtlr    %r11
 109         mtcr    %r12
 110         mr      %r2,%r9
 111         mr      %r1,%r10
 112         or.     %r3,%r4,%r4
 113         bnelr
 114         li      %r3,1
 115         blr
 116
 117         .section .note.GNU-stack,"",%progbits