lib/libc/powerpc64/gen/sigsetjmp.S

   1 /*-
   2  * Copyright (c) 2002 Peter Grehan.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  */
  26 /*      $NetBSD: sigsetjmp.S,v 1.4 1998/10/03 12:30:38 tsubai Exp $     */
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 /*
  32  * C library -- sigsetjmp, siglongjmp
  33  *
  34  *      siglongjmp(a,v)
  35  * will generate a "return(v?v:1)" from the last call to
  36  *      sigsetjmp(a, savemask)
  37  * by restoring registers from the stack.
  38  * The previous signal state is restored if savemask is non-zero
  39  *
  40  * jmpbuf layout:
  41  *     +------------+
  42  *     |  savemask  |
  43  *     +------------+
  44  *     | sig state  |
  45  *     |            |
  46  *     | (4 words)  |
  47  *     |            |
  48  *     +------------+
  49  *     | saved regs |
  50  *     |    ...     |
  51  */
  52
  53
  54 #include <sys/syscall.h>
  55
  56 ENTRY(sigsetjmp)
  57         mr      %r6,%r3
  58         stw     %r4,0(%r3)
  59         or.     %r7,%r4,%r4
  60         beq     1f
  61         li      %r3,1                   /* SIG_BLOCK, but doesn't matter */
  62                                         /*            since set == NULL  */
  63         li      %r4,0                   /* set = NULL */
  64         mr      %r5,%r6                 /* &oset */
  65         addi    %r5,%r5,4
  66         li      %r0, SYS_sigprocmask   /* sigprocmask(SIG_BLOCK, NULL, &oset)*/
  67         sc                              /* assume no error       XXX */
  68 1:
  69         mflr    %r11
  70         mfcr    %r12
  71         mr      %r10,%r1
  72         mr      %r9,%r2
  73
  74         std     %r9,40 + 0*8(%r6)
  75         std     %r10,40 + 1*8(%r6)
  76         std     %r11,40 + 2*8(%r6)
  77         std     %r12,40 + 3*8(%r6)
  78         std     %r13,40 + 4*8(%r6)
  79         std     %r14,40 + 5*8(%r6)
  80         std     %r15,40 + 6*8(%r6)
  81         std     %r16,40 + 7*8(%r6)
  82         std     %r17,40 + 8*8(%r6)
  83         std     %r18,40 + 9*8(%r6)
  84         std     %r19,40 + 10*8(%r6)
  85         std     %r20,40 + 11*8(%r6)
  86         std     %r21,40 + 12*8(%r6)
  87         std     %r22,40 + 13*8(%r6)
  88         std     %r23,40 + 14*8(%r6)
  89         std     %r24,40 + 15*8(%r6)
  90         std     %r25,40 + 16*8(%r6)
  91         std     %r26,40 + 17*8(%r6)
  92         std     %r27,40 + 18*8(%r6)
  93         std     %r28,40 + 19*8(%r6)
  94         std     %r29,40 + 20*8(%r6)
  95         std     %r30,40 + 21*8(%r6)
  96         std     %r31,40 + 22*8(%r6)
  97
  98         li      %r3,0
  99         blr
 100
 101 ENTRY(siglongjmp)
 102         ld      %r9,40 + 0*8(%r3)
 103         ld      %r10,40 + 1*8(%r3)
 104         ld      %r11,40 + 2*8(%r3)
 105         ld      %r12,40 + 3*8(%r3)
 106         ld      %r14,40 + 5*8(%r3)
 107         ld      %r15,40 + 6*8(%r3)
 108         ld      %r16,40 + 7*8(%r3)
 109         ld      %r17,40 + 8*8(%r3)
 110         ld      %r18,40 + 9*8(%r3)
 111         ld      %r19,40 + 10*8(%r3)
 112         ld      %r20,40 + 11*8(%r3)
 113         ld      %r21,40 + 12*8(%r3)
 114         ld      %r22,40 + 13*8(%r3)
 115         ld      %r23,40 + 14*8(%r3)
 116         ld      %r24,40 + 15*8(%r3)
 117         ld      %r25,40 + 16*8(%r3)
 118         ld      %r26,40 + 17*8(%r3)
 119         ld      %r27,40 + 18*8(%r3)
 120         ld      %r28,40 + 19*8(%r3)
 121         ld      %r29,40 + 20*8(%r3)
 122         ld      %r30,40 + 21*8(%r3)
 123         ld      %r31,40 + 22*8(%r3)
 124
 125         lwz     %r7,0(%r3)
 126         mr      %r6,%r4
 127         mtlr    %r11
 128         mtcr    %r12
 129         mr      %r2,%r9
 130         mr      %r1,%r10
 131         or.     %r7,%r7,%r7
 132         beq     1f
 133         mr      %r4,%r3
 134         li      %r3,3                   /* SIG_SETMASK */
 135         addi    %r4,%r4,4               /* &set */
 136         li      %r5,0                   /* oset = NULL */
 137         li      %r0,SYS_sigprocmask     /* sigprocmask(SIG_SET, &set, NULL) */
 138         sc                              /* assume no error       XXX */
 139 1:
 140         or.     %r3,%r6,%r6
 141         bnelr
 142         li      %r3,1
 143         blr
 144
 145         .section .note.GNU-stack,"",%progbits