lib/msun/amd64/s_remquo.S

   1 /*-
   2  * Copyright (c) 2005 David Schultz <das@FreeBSD.ORG>
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  */
  26
  27 /*
  28  * Based on public-domain remainder routine by J.T. Conklin <jtc@NetBSD.org>.
  29  */
  30
  31 #include <machine/asm.h>
  32 __FBSDID("$FreeBSD$");
  33
  34 ENTRY(remquo)
  35         movsd   %xmm0,-8(%rsp)
  36         movsd   %xmm1,-16(%rsp)
  37         fldl    -16(%rsp)
  38         fldl    -8(%rsp)
  39 1:      fprem1
  40         fstsw   %ax
  41         btw     $10,%ax
  42         jc      1b
  43         fstp    %st(1)
  44 /* Extract the three low-order bits of the quotient from C0,C3,C1. */
  45         shrl    $6,%eax
  46         movl    %eax,%ecx
  47         andl    $0x108,%eax
  48         rorl    $7,%eax
  49         orl     %eax,%ecx
  50         roll    $4,%eax
  51         orl     %ecx,%eax
  52         andl    $7,%eax
  53 /* Negate the quotient bits if x*y<0.  Avoid using an unpredictable branch. */
  54         movl    -12(%rsp),%ecx
  55         xorl    -4(%rsp),%ecx
  56         sarl    $16,%ecx
  57         sarl    $16,%ecx
  58         xorl    %ecx,%eax
  59         andl    $1,%ecx
  60         addl    %ecx,%eax
  61 /* Store the quotient and return. */
  62         movl    %eax,(%rdi)
  63         fstpl   -8(%rsp)
  64         movsd   -8(%rsp),%xmm0
  65         ret
  66 END(remquo)
  67
  68         .section .note.GNU-stack,"",%progbits