lib/msun/amd64/s_remquol.S

   1 /*-
   2  * Copyright (c) 2005-2008 David Schultz <das@FreeBSD.ORG>
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  */
  26
  27 /*
  28  * Based on public-domain remainder routine by J.T. Conklin <jtc@NetBSD.org>.
  29  */
  30
  31 #include <machine/asm.h>
  32 __FBSDID("$FreeBSD$");
  33
  34 ENTRY(remquol)
  35         fldt    24(%rsp)
  36         fldt    8(%rsp)
  37 1:      fprem1
  38         fstsw   %ax
  39         btw     $10,%ax
  40         jc      1b
  41         fstp    %st(1)
  42 /* Extract the three low-order bits of the quotient from C0,C3,C1. */
  43         shrl    $6,%eax
  44         movl    %eax,%ecx
  45         andl    $0x108,%eax
  46         rorl    $7,%eax
  47         orl     %eax,%ecx
  48         roll    $4,%eax
  49         orl     %ecx,%eax
  50         andl    $7,%eax
  51 /* Negate the quotient bits if x*y<0.  Avoid using an unpredictable branch. */
  52         movl    32(%rsp),%ecx
  53         xorl    16(%rsp),%ecx
  54         movsx   %cx,%ecx
  55         sarl    $16,%ecx
  56         sarl    $16,%ecx
  57         xorl    %ecx,%eax
  58         andl    $1,%ecx
  59         addl    %ecx,%eax
  60 /* Store the quotient and return. */
  61         movl    %eax,(%rdi)
  62         ret
  63
  64         .section .note.GNU-stack,"",%progbits