libexec/rtld-elf/amd64/rtld_start.S

   1 /*-
   2  * Copyright 1996-1998 John D. Polstra.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  15  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  16  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  17  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  18  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  19  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  20  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  21  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  22  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  23  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  24  *
  25  * $FreeBSD$
  26  */
  27
  28         .text
  29         .align  4
  30         .globl  .rtld_start
  31         .type   .rtld_start,@function
  32 .rtld_start:
  33         xorq    %rbp,%rbp               # Clear frame pointer for good form
  34         subq    $24,%rsp                # A place to store exit procedure addr
  35         movq    %rdi,%r12
  36         movq    %rsp,%rsi               # save address of exit proc
  37         movq    %rsp,%rdx               # construct address of obj_main
  38         addq    $8,%rdx
  39         call    _rtld@PLT               # Call rtld(sp); returns entry point
  40         popq    %rsi                    # Get exit procedure address
  41         movq    %r12,%rdi               # *ap
  42 /*
  43  * At this point, %rax contains the entry point of the main program, and
  44  * %rdx contains a pointer to a termination function that should be
  45  * registered with atexit().  (crt1.o registers it.)
  46  */
  47 .globl .rtld_goto_main
  48 .rtld_goto_main:        # This symbol exists just to make debugging easier.
  49         jmp     *%rax                   # Enter main program
  50
  51
  52 /*
  53  * Binder entry point.  Control is transferred to here by code in the PLT.
  54  * On entry, there are two arguments on the stack.  In ascending address
  55  * order, they are (1) "obj", a pointer to the calling object's Obj_Entry,
  56  * and (2) "reloff", the byte offset of the appropriate relocation entry
  57  * in the PLT relocation table.
  58  *
  59  * We are careful to preserve all registers, even the caller-save
  60  * registers.  That is because this code may be invoked by low-level
  61  * assembly-language code that is not ABI-compliant.
  62  *
  63  * Stack map:
  64  * reloff       0x60
  65  * obj          0x58
  66  * spare        0x50
  67  * rflags       0x48
  68  * rax          0x40
  69  * rdx          0x38
  70  * rcx          0x30
  71  * rsi          0x28
  72  * rdi          0x20
  73  * r8           0x18
  74  * r9           0x10
  75  * r10          0x8
  76  * r11          0x0
  77  */
  78         .align  4
  79         .globl  _rtld_bind_start
  80         .type   _rtld_bind_start,@function
  81 _rtld_bind_start:
  82         subq    $8,%rsp
  83         pushfq                          # Save rflags
  84         pushq   %rax                    # Save %rax
  85         pushq   %rdx                    # Save %rdx
  86         pushq   %rcx                    # Save %rcx
  87         pushq   %rsi                    # Save %rsi
  88         pushq   %rdi                    # Save %rdi
  89         pushq   %r8                     # Save %r8
  90         pushq   %r9                     # Save %r9
  91         pushq   %r10                    # Save %r10
  92         pushq   %r11                    # Save %r11
  93
  94         movq    0x58(%rsp),%rdi         # Fetch obj argument
  95         movq    0x60(%rsp),%rsi         # Fetch reloff argument
  96         leaq    (%rsi,%rsi,2),%rsi      # multiply by 3
  97         leaq    (,%rsi,8),%rsi          # now 8, for 24 (sizeof Elf_Rela)
  98
  99         call    _rtld_bind@PLT          # Transfer control to the binder
 100         /* Now %rax contains the entry point of the function being called. */
 101
 102         movq    %rax,0x60(%rsp)         # Store target over reloff argument
 103         popq    %r11                    # Restore %r11
 104         popq    %r10                    # Restore %r10
 105         popq    %r9                     # Restore %r9
 106         popq    %r8                     # Restore %r8
 107         popq    %rdi                    # Restore %rdi
 108         popq    %rsi                    # Restore %rsi
 109         popq    %rcx                    # Restore %rcx
 110         popq    %rdx                    # Restore %rdx
 111         popq    %rax                    # Restore %rax
 112         popfq                           # Restore rflags
 113         leaq    16(%rsp),%rsp           # Discard spare, obj, do not change rflags
 114         ret                             # "Return" to target address
 115
 116         .section .note.GNU-stack,"",%progbits