sys/boot/i386/boot2/boot1.S

   1 /*
   2  * Copyright (c) 1998 Robert Nordier
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms are freely
   6  * permitted provided that the above copyright notice and this
   7  * paragraph and the following disclaimer are duplicated in all
   8  * such forms.
   9  *
  10  * This software is provided "AS IS" and without any express or
  11  * implied warranties, including, without limitation, the implied
  12  * warranties of merchantability and fitness for a particular
  13  * purpose.
  14  *
  15  * $FreeBSD$
  16  */
  17
  18 /* Memory Locations */
  19                 .set MEM_REL,0x700              # Relocation address
  20                 .set MEM_ARG,0x900              # Arguments
  21                 .set MEM_ORG,0x7c00             # Origin
  22                 .set MEM_BUF,0x8c00             # Load area
  23                 .set MEM_BTX,0x9000             # BTX start
  24                 .set MEM_JMP,0x9010             # BTX entry point
  25                 .set MEM_USR,0xa000             # Client start
  26                 .set BDA_BOOT,0x472             # Boot howto flag
  27
  28 /* Partition Constants */
  29                 .set PRT_OFF,0x1be              # Partition offset
  30                 .set PRT_NUM,0x4                # Partitions
  31                 .set PRT_BSD,0xa5               # Partition type
  32
  33 /* Flag Bits */
  34                 .set FL_PACKET,0x80             # Packet mode
  35
  36 /* Misc. Constants */
  37                 .set SIZ_PAG,0x1000             # Page size
  38                 .set SIZ_SEC,0x200              # Sector size
  39
  40                 .set NSECT,0x10
  41                 .globl start
  42                 .globl xread
  43                 .code16
  44
  45 start:          jmp main                        # Start recognizably
  46
  47 /*
  48  * This is the start of a standard BIOS Parameter Block (BPB). Most bootable
  49  * FAT disks have this at the start of their MBR. While normal BIOS's will
  50  * work fine without this section, IBM's El Torito emulation "fixes" up the
  51  * BPB by writing into the memory copy of the MBR. Rather than have data
  52  * written into our xread routine, we'll define a BPB to work around it.
  53  * The data marked with (T) indicates a field required for a ThinkPad to
  54  * recognize the disk and (W) indicates fields written from IBM BIOS code.
  55  * The use of the BPB is based on what OpenBSD and NetBSD implemented in
  56  * their boot code but the required fields were determined by trial and error.
  57  *
  58  * Note: If additional space is needed in boot1, one solution would be to
  59  * move the "prompt" message data (below) to replace the OEM ID.
  60  */
  61                 .org 0x03, 0x00
  62 oemid:          .space 0x08, 0x00       # OEM ID
  63
  64                 .org 0x0b, 0x00
  65 bpb:            .word   512             # sector size (T)
  66                 .byte   0               # sectors/clustor
  67                 .word   0               # reserved sectors
  68                 .byte   0               # number of FATs
  69                 .word   0               # root entries
  70                 .word   0               # small sectors
  71                 .byte   0               # media type (W)
  72                 .word   0               # sectors/fat
  73                 .word   18              # sectors per track (T)
  74                 .word   2               # number of heads (T)
  75                 .long   0               # hidden sectors (W)
  76                 .long   0               # large sectors
  77
  78                 .org 0x24, 0x00
  79 ebpb:           .byte   0               # BIOS physical drive number (W)
  80
  81                 .org 0x25,0x90
  82 /*
  83  * Trampoline used by boot2 to call read to read data from the disk via
  84  * the BIOS.  Call with:
  85  *
  86  * %cx:%ax      - long    - LBA to read in
  87  * %es:(%bx)    - caddr_t - buffer to read data into
  88  * %dl          - byte    - drive to read from
  89  * %dh          - byte    - num sectors to read
  90  */
  91
  92 xread:          push %ss                        # Address
  93                 pop %ds                         #  data
  94 /*
  95  * Setup an EDD disk packet and pass it to read
  96  */
  97 xread.1:                                        # Starting
  98                 pushl $0x0                      #  absolute
  99                 push %cx                        #  block
 100                 push %ax                        #  number
 101                 push %es                        # Address of
 102                 push %bx                        #  transfer buffer
 103                 xor %ax,%ax                     # Number of
 104                 movb %dh,%al                    #  blocks to
 105                 push %ax                        #  transfer
 106                 push $0x10                      # Size of packet
 107                 mov %sp,%bp                     # Packet pointer
 108                 callw read                      # Read from disk
 109                 lea 0x10(%bp),%sp               # Clear stack
 110                 lret                            # To far caller
 111 /*
 112  * Load the rest of boot2 and BTX up, copy the parts to the right locations,
 113  * and start it all up.
 114  */
 115
 116 /*
 117  * Setup the segment registers to flat addressing (segment 0) and setup the
 118  * stack to end just below the start of our code.
 119  */
 120 main:           cld                             # String ops inc
 121                 xor %cx,%cx                     # Zero
 122                 mov %cx,%es                     # Address
 123                 mov %cx,%ds                     #  data
 124                 mov %cx,%ss                     # Set up
 125                 mov $start,%sp                  #  stack
 126 /*
 127  * Relocate ourself to MEM_REL.  Since %cx == 0, the inc %ch sets
 128  * %cx == 0x100.  Note that boot1 does not use this relocated copy
 129  * of itself while loading boot2; however, BTX reclaims the memory
 130  * used by boot1 during its initialization.  As a result, boot2 uses
 131  * xread from the relocated copy.
 132  */
 133                 mov %sp,%si                     # Source
 134                 mov $MEM_REL,%di                # Destination
 135                 incb %ch                        # Word count
 136                 rep                             # Copy
 137                 movsw                           #  code
 138 /*
 139  * If we are on a hard drive, then load the MBR and look for the first
 140  * FreeBSD slice.  We use the fake partition entry below that points to
 141  * the MBR when we call nread.  The first pass looks for the first active
 142  * FreeBSD slice.  The second pass looks for the first non-active FreeBSD
 143  * slice if the first one fails.
 144  */
 145                 mov $part4,%si                  # Partition
 146                 cmpb $0x80,%dl                  # Hard drive?
 147                 jb main.4                       # No
 148                 movb $0x1,%dh                   # Block count
 149                 callw nread                     # Read MBR
 150                 mov $0x1,%cx                    # Two passes
 151 main.1:         mov $MEM_BUF+PRT_OFF,%si        # Partition table
 152                 movb $0x1,%dh                   # Partition
 153 main.2:         cmpb $PRT_BSD,0x4(%si)          # Our partition type?
 154                 jne main.3                      # No
 155                 jcxz main.5                     # If second pass
 156                 testb $0x80,(%si)               # Active?
 157                 jnz main.5                      # Yes
 158 main.3:         add $0x10,%si                   # Next entry
 159                 incb %dh                        # Partition
 160                 cmpb $0x1+PRT_NUM,%dh           # In table?
 161                 jb main.2                       # Yes
 162                 dec %cx                         # Do two
 163                 jcxz main.1                     #  passes
 164 /*
 165  * If we get here, we didn't find any FreeBSD slices at all, so print an
 166  * error message and die.
 167  */
 168                 mov $msg_part,%si               # Message
 169                 jmp error                       # Error
 170 /*
 171  * Floppies use partition 0 of drive 0.
 172  */
 173 main.4:         xor %dx,%dx                     # Partition:drive
 174 /*
 175  * Ok, we have a slice and drive in %dx now, so use that to locate and load
 176  * boot2.  %si references the start of the slice we are looking for, so go
 177  * ahead and load up the first 16 sectors (boot1 + boot2) from that.  When
 178  * we read it in, we conveniently use 0x8c00 as our transfer buffer.  Thus,
 179  * boot1 ends up at 0x8c00, and boot2 starts at 0x8c00 + 0x200 = 0x8e00.
 180  * The first part of boot2 is the disklabel, which is 0x200 bytes long.
 181  * The second part is BTX, which is thus loaded into 0x9000, which is where
 182  * it also runs from.  The boot2.bin binary starts right after the end of
 183  * BTX, so we have to figure out where the start of it is and then move the
 184  * binary to 0xc000.  Normally, BTX clients start at MEM_USR, or 0xa000, but
 185  * when we use btxld to create boot2, we use an entry point of 0x2000.  That
 186  * entry point is relative to MEM_USR; thus boot2.bin starts at 0xc000.
 187  */
 188 main.5:         mov %dx,MEM_ARG                 # Save args
 189                 movb $NSECT,%dh                 # Sector count
 190                 callw nread                     # Read disk
 191                 mov $MEM_BTX,%bx                # BTX
 192                 mov 0xa(%bx),%si                # Get BTX length and set
 193                 add %bx,%si                     #  %si to start of boot2.bin
 194                 mov $MEM_USR+SIZ_PAG*2,%di      # Client page 2
 195                 mov $MEM_BTX+(NSECT-1)*SIZ_SEC,%cx # Byte
 196                 sub %si,%cx                     #  count
 197                 rep                             # Relocate
 198                 movsb                           #  client
 199
 200 /*
 201  * Enable A20 so we can access memory above 1 meg.
 202  * Use the zero-valued %cx as a timeout for embedded hardware which do not
 203  * have a keyboard controller.
 204  */
 205 seta20:         cli                             # Disable interrupts
 206 seta20.1:       dec %cx                         # Timeout?
 207                 jz seta20.3                     # Yes
 208                 inb $0x64,%al                   # Get status
 209                 testb $0x2,%al                  # Busy?
 210                 jnz seta20.1                    # Yes
 211                 movb $0xd1,%al                  # Command: Write
 212                 outb %al,$0x64                  #  output port
 213 seta20.2:       inb $0x64,%al                   # Get status
 214                 testb $0x2,%al                  # Busy?
 215                 jnz seta20.2                    # Yes
 216                 movb $0xdf,%al                  # Enable
 217                 outb %al,$0x60                  #  A20
 218 seta20.3:       sti                             # Enable interrupts
 219
 220                 jmp start+MEM_JMP-MEM_ORG       # Start BTX
 221
 222
 223 /*
 224  * Trampoline used to call read from within boot1.
 225  */
 226 nread:          mov $MEM_BUF,%bx                # Transfer buffer
 227                 mov 0x8(%si),%ax                # Get
 228                 mov 0xa(%si),%cx                #  LBA
 229                 push %cs                        # Read from
 230                 callw xread.1                   #  disk
 231                 jnc return                      # If success, return
 232                 mov $msg_read,%si               # Otherwise, set the error
 233                                                 #  message and fall through to
 234                                                 #  the error routine
 235 /*
 236  * Print out the error message pointed to by %ds:(%si) followed
 237  * by a prompt, wait for a keypress, and then reboot the machine.
 238  */
 239 error:          callw putstr                    # Display message
 240                 mov $prompt,%si                 # Display
 241                 callw putstr                    #  prompt
 242                 xorb %ah,%ah                    # BIOS: Get
 243                 int $0x16                       #  keypress
 244                 movw $0x1234, BDA_BOOT          # Do a warm boot
 245                 ljmp $0xf000,$0xfff0            # reboot the machine
 246 /*
 247  * Display a null-terminated string using the BIOS output.
 248  */
 249 putstr.0:       mov $0x7,%bx                    # Page:attribute
 250                 movb $0xe,%ah                   # BIOS: Display
 251                 int $0x10                       #  character
 252 putstr:         lodsb                           # Get char
 253                 testb %al,%al                   # End of string?
 254                 jne putstr.0                    # No
 255
 256 /*
 257  * Overused return code.  ereturn is used to return an error from the
 258  * read function.  Since we assume putstr succeeds, we (ab)use the
 259  * same code when we return from putstr.
 260  */
 261 ereturn:        movb $0x1,%ah                   # Invalid
 262                 stc                             #  argument
 263 return:         retw                            # To caller
 264 /*
 265  * Reads sectors from the disk.  If EDD is enabled, then check if it is
 266  * installed and use it if it is.  If it is not installed or not enabled, then
 267  * fall back to using CHS.  Since we use a LBA, if we are using CHS, we have to
 268  * fetch the drive parameters from the BIOS and divide it out ourselves.
 269  * Call with:
 270  *
 271  * %dl  - byte     - drive number
 272  * stack - 10 bytes - EDD Packet
 273  */
 274 read:           testb $FL_PACKET,%cs:MEM_REL+flags-start # LBA support enabled?
 275                 jz read.1                       # No, use CHS
 276                 cmpb $0x80,%dl                  # Hard drive?
 277                 jb read.1                       # No, use CHS
 278                 mov $0x55aa,%bx                 # Magic
 279                 push %dx                        # Save
 280                 movb $0x41,%ah                  # BIOS: Check
 281                 int $0x13                       #  extensions present
 282                 pop %dx                         # Restore
 283                 jc read.1                       # If error, use CHS
 284                 cmp $0xaa55,%bx                 # Magic?
 285                 jne read.1                      # No, so use CHS
 286                 testb $0x1,%cl                  # Packet interface?
 287                 jz read.1                       # No, so use CHS
 288                 mov %bp,%si                     # Disk packet
 289                 movb $0x42,%ah                  # BIOS: Extended
 290                 int $0x13                       #  read
 291                 retw                            # To caller
 292 read.1:         push %dx                        # Save
 293                 movb $0x8,%ah                   # BIOS: Get drive
 294                 int $0x13                       #  parameters
 295                 movb %dh,%ch                    # Max head number
 296                 pop %dx                         # Restore
 297                 jc return                       # If error
 298                 andb $0x3f,%cl                  # Sectors per track
 299                 jz ereturn                      # If zero
 300                 cli                             # Disable interrupts
 301                 mov 0x8(%bp),%eax               # Get LBA
 302                 push %dx                        # Save
 303                 movzbl %cl,%ebx                 # Divide by
 304                 xor %edx,%edx                   #  sectors
 305                 div %ebx                        #  per track
 306                 movb %ch,%bl                    # Max head number
 307                 movb %dl,%ch                    # Sector number
 308                 inc %bx                         # Divide by
 309                 xorb %dl,%dl                    #  number
 310                 div %ebx                        #  of heads
 311                 movb %dl,%bh                    # Head number
 312                 pop %dx                         # Restore
 313                 cmpl $0x3ff,%eax                # Cylinder number supportable?
 314                 sti                             # Enable interrupts
 315                 ja ereturn                      # No, return an error
 316                 xchgb %al,%ah                   # Set up cylinder
 317                 rorb $0x2,%al                   #  number
 318                 orb %ch,%al                     # Merge
 319                 inc %ax                         #  sector
 320                 xchg %ax,%cx                    #  number
 321                 movb %bh,%dh                    # Head number
 322                 subb %ah,%al                    # Sectors this track
 323                 mov 0x2(%bp),%ah                # Blocks to read
 324                 cmpb %ah,%al                    # To read
 325                 jb read.2                       #  this
 326 #ifdef  TRACK_AT_A_TIME
 327                 movb %ah,%al                    #  track
 328 #else
 329                 movb $1,%al                     #  one sector
 330 #endif
 331 read.2:         mov $0x5,%di                    # Try count
 332 read.3:         les 0x4(%bp),%bx                # Transfer buffer
 333                 push %ax                        # Save
 334                 movb $0x2,%ah                   # BIOS: Read
 335                 int $0x13                       #  from disk
 336                 pop %bx                         # Restore
 337                 jnc read.4                      # If success
 338                 dec %di                         # Retry?
 339                 jz read.6                       # No
 340                 xorb %ah,%ah                    # BIOS: Reset
 341                 int $0x13                       #  disk system
 342                 xchg %bx,%ax                    # Block count
 343                 jmp read.3                      # Continue
 344 read.4:         movzbw %bl,%ax                  # Sectors read
 345                 add %ax,0x8(%bp)                # Adjust
 346                 jnc read.5                      #  LBA,
 347                 incw 0xa(%bp)                   #  transfer
 348 read.5:         shlb %bl                        #  buffer
 349                 add %bl,0x5(%bp)                #  pointer,
 350                 sub %al,0x2(%bp)                #  block count
 351                 ja read.1                       # If not done
 352 read.6:         retw                            # To caller
 353
 354 /* Messages */
 355
 356 msg_read:       .asciz "Read"
 357 msg_part:       .asciz "Boot"
 358
 359 prompt:         .asciz " error\r\n"
 360
 361 flags:          .byte FLAGS                     # Flags
 362
 363                 .org PRT_OFF,0x90
 364
 365 /* Partition table */
 366
 367                 .fill 0x30,0x1,0x0
 368 part4:          .byte 0x80, 0x00, 0x01, 0x00
 369                 .byte 0xa5, 0xfe, 0xff, 0xff
 370                 .byte 0x00, 0x00, 0x00, 0x00
 371                 .byte 0x50, 0xc3, 0x00, 0x00    # 50000 sectors long, bleh
 372
 373                 .word 0xaa55                    # Magic number