sys/boot/i386/efi/ldscript.i386

   1 /* $FreeBSD$ */
   2 OUTPUT_FORMAT("elf32-i386-freebsd", "elf32-i386-freebsd", "elf32-i386-freebsd")
   3 OUTPUT_ARCH(i386)
   4 ENTRY(_start)
   5 SECTIONS
   6 {
   7   /* Read-only sections, merged into text segment: */
   8   . = 0;
   9   ImageBase = .;
  10   . = SIZEOF_HEADERS;
  11   . = ALIGN(4096);
  12   .text         : {
  13     *(.text .stub .text.* .gnu.linkonce.t.*)
  14     /* .gnu.warning sections are handled specially by elf32.em. */
  15     *(.gnu.warning)
  16     *(.plt)
  17   } =0x00300000010070000002000001000400
  18   . = ALIGN(4096);
  19   .data         : {
  20     *(.rodata .rodata.* .gnu.linkonce.r.*)
  21     *(.rodata1)
  22     *(.sdata2 .sdata2.* .gnu.linkonce.s2.*)
  23     *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*)
  24     *(.opd)
  25     *(.data .data.* .gnu.linkonce.d.*)
  26     *(.data1)
  27     *(.plabel)
  28     *(.dynbss)
  29     *(.bss .bss.* .gnu.linkonce.b.*)
  30     *(COMMON)
  31   }
  32   . = ALIGN(4096);
  33   set_Xcommand_set      : {
  34     __start_set_Xcommand_set = .;
  35     *(set_Xcommand_set)
  36     __stop_set_Xcommand_set = .;
  37   }
  38   . = ALIGN(4096);
  39   __gp = .;
  40   .sdata        : {
  41     *(.got.plt .got)
  42     *(.sdata .sdata.* .gnu.linkonce.s.*)
  43     *(dynsbss)
  44     *(.sbss .sbss.* .gnu.linkonce.sb.*)
  45     *(.scommon)
  46   }
  47   . = ALIGN(4096);
  48   .dynamic      : { *(.dynamic) }
  49   . = ALIGN(4096);
  50   .rel.dyn      : {
  51     *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*)
  52     *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*)
  53     *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*)
  54     *(.rel.got)
  55     *(.rel.sdata .rel.sdata.* .rel.gnu.linkonce.s.*)
  56     *(.rel.sbss .rel.sbss.* .rel.gnu.linkonce.sb.*)
  57     *(.rel.sdata2 .rel.sdata2.* .rel.gnu.linkonce.s2.*)
  58     *(.rel.sbss2 .rel.sbss2.* .rel.gnu.linkonce.sb2.*)
  59     *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*)
  60     *(.rel.plt)
  61     *(.relset_*)
  62     *(.rel.dyn .rel.dyn.*)
  63   }
  64   . = ALIGN(4096);
  65   .reloc        : { *(.reloc) }
  66   . = ALIGN(4096);
  67   .hash         : { *(.hash) }
  68   . = ALIGN(4096);
  69   .dynsym       : { *(.dynsym) }
  70   . = ALIGN(4096);
  71   .dynstr       : { *(.dynstr) }
  72 }